Cursore Video - Applicazioni Software ["Dentro il Computer" di Giobe®2000]

		Come Funziona Area Comunicaz. Bios Registri Livello Hardware Livello BIOS Livello DOS Applicazioni Software Download INDICE
Cursore

Applicazioni Software

PROGETTO nÂ° 05 - 3/6 [37 di 42]

Analisi del Problema · Analisi del Codice · Procedure importanti

Gestione dimensione del Cursore - Selezione guidata del cursore

Analisi del Codice Sorgente [1 di 3]

L'obiettivo del progetto è quello di modificare da programma la dimensione del Cursore

Il codice assembly del programma è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella:

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM   (maggio 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME        : CambiaCu.ASM                                                ³
;³ AUTORE      : Giorgio OBER                                                ³
;³ VERSIONE    : maggio 2003                                                 ³
;³ DESCRIZIONE : Programma per la modifica delle dimensioni del cursore.     ³
;³               PoichŠ la dimensione del cursore dipende  dall'adattatore  e³
;³               dal Modo Video corrente, il programma suppone di disporre di³
;³               adattatore VGA, con 16 linee di scansione disponibili  nella³
;³               matrice di punti destinata ad  ospitare  ciascun  carattere;³
;³               la Griglia di selezione sar… dunque tarata con 16 numeri sia³
;³               sulle ordinate y che sulle ascisse x, in modo da  consentire³
;³               la predisposizione e la scelta  della dimensione  desiderata³
;³               per il cursore.                                             ³
;³                                                                           ³
;³               La dimensione desiderata pu• essere selezionata con facilit…³
;³               muovendosi sulla Griglia con frecce di direzione:           ³
;³               1) in senso orizzontale le linee  di scansione  aumentano da³
;³                  sinistra verso destra, e viceversa                       ³
;³               2) in senso verticale le linee di  scansione  aumentano  dal³
;³                  basso verso l'alto, e viceversa                          ³
;³                                                                           ³
;³               La massima dimensione ("Û", 16 linee di scansione) si ha nel³
;³               punto 1-1 (angolo in alto a  sinistra  della Griglia)  e  la³
;³               minima nei punti 1-16 (in alto a destra,  solo  trattino  in³
;³               alto) e 16-1 (in basso a sinistra, solo trattino in basso). ³
;³                                                                           ³
;³               Con <Invio> si torna al DOS con il nuovo cursore.           ³
;³               La Barra Spaziatrice mostra l'effetto delle nuove dimensioni³
;³               del Cursore su di un testo predisposto appositamente.       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
; COSTANTI DEFINITE PER IL PROGRAMMA:
        FrDn    EQU   50H     ;Codice Scansione tasto Funzionale <Freccia Gi—>
        FrUp    EQU   48H     ;Codice Scansione tasto Funzionale <Freccia Su>
        FrSn    EQU   4BH     ;Codice Scansione tasto Funzionale <Fr.Sinistra>
        FrDx    EQU   4DH     ;Codice Scansione tasto Funzionale <Fr.Destra>
        LF      EQU   10
        CR      EQU   13

if1     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
         include  GIOBE.MAC ;(C:\ARCH-LAB\BIN\GIOBE.MAC);³
        endif   ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÚÄÄÄÄ¿ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE ESTERNE³NEAR³UTILIZZATE dal PROGRAMMA (dalla LIBRERIA GIOBE.LIB~)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÀÄÄÄÄÙÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN      BIOScls:NEAR
        EXTRN        STAsp:NEAR
        EXTRN       RamCur:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN      BIOchr1:NEAR
        EXTRN      Byt2Dec:NEAR

PUBLIC  CambiaCu
        PUBLIC  ATTRIB        ;Attributo di colore

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³DEFINIZIONE DEL SEGMENTO DEL CODICE                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog
        ORG     0100H
INIZIO: JMP     CambiaCu

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³AREA DESTINATA AI DATI DEL PROGRAMMA                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ATTRIB  DB      0FH
Rig     DB      20
Col     DB      18
Testo0  DB 'Controllo della Dimensione del Cursore',00H
Testo1  DB "TUTORIAL ASSEMBLY  --- www.Giobe2000.it  ---  Copyright 2003",00H

Griglia0 DB '  Cambia la Dimensione spostandoti con le Frecce     ',00H
Griglia1 DB '     1  2  3  4  5  6  7  8  9 10 11 12 13 14 15 16  ',00H
Griglia2 DB '                                                     ',00H
Griglia3 DB '  Per terminare il programma  conferma  con Invio    ',00H
Testo3   DB 'Linea di partenza (in  alto):   ',00H
Testo4   DB 'Linea di  arrivo  (in basso):   ',00H

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³  AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA:   BARRA                                                         ³
;³DESCRIZIONE: Stampa un'intera riga di 80 spazi colorati.                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
BARRA:  PUSH    AX
        PUSH    CX
        MOV     CX,80
        MOV     AL,' '
Barra0: CALL    BIOchr1
        LOOP    Barra0
        POP     CX
        POP     AX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : DeskTop                                                       ³
;³DESCRIZIONE: Procedura che inizializza completamente il  piano  di  lavoro.³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
DeskTop:CALL    BIOScls       ;Pulisce lo schermo
        M_COLOR 1FH           ;¿
        M_CURSOR 0,0          ;³
        CALL    BARRA         ;³
        M_CURSOR 24,0         ;³Predispone le barre del Titolo (in alto) e del
        CALL    BARRA         ;³Menu (in basso)
       M_msgC Testo0, 0,20,1FH;³
       M_msgC Testo1,24,11,1FH;Ù

M_msgC Griglia0, 3,13,31H;¿Prime 3 righe della Griglia, con la taratura
     M_msgC Griglia1, 4,13,1EH;Ùorizzontale

MOV     CX,16         ;   ¿
        MOV     DH,5          ;   ³   16 Righe centrali della Griglia,
Desk_1: M_msgC Griglia2,DH,13,1FH ³   attualmente vuote
        INC     DH            ;   ³
        LOOP    Desk_1        ;   Ù
     M_msgC Griglia3,DH,13,31H;Riga finale della Griglia

MOV     CX,16         ;¿
        MOV     DH,5          ;³
        MOV     DL,15         ;³
Desk_2: M_CURSOR DH,DL        ;³
        MOV     AL,17         ;³
        SUB     AL,CL         ;³
        CMP     AL,9          ;³
        JNE     Desk_3        ;³Provvede alla taratura della colonna sinistra
        DEC     DL            ;³della Griglia
Desk_3: M_COLOR 1EH           ;³
        CALL    Byt2Dec       ;³
        INC     DH            ;³
        LOOP    Desk_2        ;Ù

MOV     BP,16         ;¿Predispone la Griglia di messa  a  punto della
        MOV     DL,17         ;³dimensione  del  Cursore;  la  dimensione  pu•
        M_COLOR 0FH           ;³essere  selezionata  muovendosi con  frecce di
        MOV     CX,16         ;³direzione:
Desk_4: PUSH    CX            ;³#) in senso orizzontale  le linee di scansione
        MOV     DH,5          ;³aumentano da sinistra verso destra e viceversa
        MOV     CX,BP         ;³#) in senso  verticale   le linee di scansione
Desk_5: M_CURSOR DH,DL        ;³aumentano  dal basso verso l'alto, e viceversa
        CALL    STAsp         ;³
        MOV     AL,"ú"        ;³La massima dimensione (16 linee  di scansione)
        CALL    BIOchr1       ;³si ha nel punto 1-1 (angolo in alto a sinistra
        CALL    STAsp         ;³della Griglia) e la minima nei punti  1-16 (in
        INC     DH            ;³alto a destra, solo trattino in alto)  e  16-1
        LOOP    Desk_5        ;³(in basso a sinistra, solo trattino  in basso)
        POP     CX            ;³
        DEC     BP            ;³Marca in nero le  possibili  posizioni  per il
        ADD     DL,3          ;³Cursore, nella fase di messa a punto
        LOOP    Desk_4        ;Ù
       M_msgC Testo3,18,32,1FH; Linea di partenza (in  alto): '
       M_msgC Testo4,19,32,1FH; Linea di  arrivo  (in basso): '
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : ChkPos                                                        ³
;³DESCRIZIONE: Verifica se nella posizione puntata c'Š il carattere "ú"      ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ChkPos: CALL    RamCur
        MOV     AL,ES:[DI]
        CMP     AL,"ú"
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Forma                                                         ³
;³DESCRIZIONE: Formatta il Cursore HardWare con le NUOVE dimensioni generando³
;³             i numeri di linea Iniziale e Finale a partire dalla  posizione³
;³             attualmente occupata (come al solito da DH=riga, DL=colonna). ³
;³             Usa poi la Funzione 01H (INT 10H) per fissare la dimensione, e³
;³             la Funzione 02H (INT 10H) = M_CURSOR per fissare la posizione.³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Forma:  PUSH    DX
        MOV     CS:[Rig],DH   ;¿Formatta la dimensione del cursore in funzione
        MOV     CS:[Col],DL   ;³della sua posizione attuale, DH=riga, DL=colon
                              ;³I parametri per la Dimensione sono lasciati in
        MOV     CH,DH         ;³CH=linea partenza da 0 in alto a 15 in basso
        SUB     CH,5          ;³CL=linea d'arrivo da 0 in alto a 15 in basso
        MOV     AH,00H        ;³ÚÄÄÄÄÄÄÄÂÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÂÄÄÄÄÄÄÄÄÂÄÄÄÄÄÄÄÄÄ¿
        MOV     AL,DL         ;³³Griglia³    Aspetto      ³partenza³arrivo   ³
        MOV     CL,3          ;³ÃÄÄÄÄÄÄÄÅÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÅÄÄ[alto]ÅÄ[basso]Ä´
        DIV     CL            ;³³ 1- 1  ³CARATTERE   PIENO³ CH = 0 ³ CL =15  ³
        SUB     AL,6          ;³³ 1-16  ³TRATTINO IN  ALTO³ CH = 0 ³ CL = 0  ³
        MOV     CL,15         ;³³ 16- 1 ³TRATTINO IN BASSO³ CH =15 ³ CL =15  ³
        SUB     CL,AL         ;ÙÀÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÙ
        MOV     AH,01H        ;¿Funzione BIOS che fissa la dimensione del cur-
        INT     10H           ;Ùsore linea partenza in CH, linea finale in CL

M_COLOR 1EH
        M_CURSOR 18,62        ;¿
        MOV     AL,CH         ;³
        CMP     AL,9          ;³Stampa, in Giallo su blu, il valore del numero
        JG      Form_1        ;³di linea di partenza del cursore, da AL=CH
        CALL    STAsp         ;³
Form_1: CALL    Byt2Dec       ;Ù

M_CURSOR 19,62        ;¿
        MOV     AL,CL         ;³
        CMP     AL,9          ;³Stampa, in Giallo su blu, il valore del numero
        JG      Form_2        ;³di linea di arrivo del cursore, da AL=CL
        CALL    STAsp         ;³
Form_2: CALL    Byt2Dec       ;Ù

POP     DX
        M_CURSOR DH,DL        ; Mostra il cursore nel punto giusto
        RET

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
CambiaCu proc   NEAR          ;³      AREA DEDICATA AL MAIN PROGRAM         ³³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        MOV     AX,0B800H     ;Sovrappone il segmento ES:0000 sull'area della
        MOV     ES,AX         ;RAMvideo (da B800:0000 in poi......)
        CALL    DeskTop       ;Predispone i messaggi e la Griglia

;¿Funzione BIOS che verifica  la possibilit…  da
                              ;³parte della ROM BIOS di impostare adeguatamen-
        MOV     AH,12H        ;³te le sue linee di partenza e  di  arrivo  con
        MOV     AL,01H        ;³cui  Š  costruito  il  Cursore, in accordo con
        MOV     BL,34H        ;³l'altezza del carattere usato nel  modo  testo
        INT     10H           ;³corrente; con AL=01H l'emulazione CGA del Cur-
                              ;³sore Š disabilitata  ed  Š  possibile  gestire
                              ;³ogni linea tra quelle del carattere  corrente;
                              ;³con AL=00H invece (emulazione  CGA  abilitata)
                              ;Ùnon tutte le scelte possibili sono assicurate!

MOV     DH,20         ;¿Fissa la Posizione  Iniziale del Cursore HW ai
        MOV     DL,18         ;Ùvalori 20 (DH = riga), 18 (DL = colonna)
        MOV     CH,15         ;¿Fissa la Dimensione Iniziale del Cursore HW ai
        MOV     CL,15         ;³valori 15 (CH = linea di partenza in alto)
                              ;Ù       15 (CL = linea d'arrivo in basso)

;¿Fissa la nuova Dimensione del Cursore hardware
xxx00:  CALL    Forma         ;³nel range CH (=linea di partenza) e CL (=linea
                              ;Ùfinale) e mostra il cursore nel punto giusto
xxx01:  CALL    KEYwait       ;Rimane in attesa di tasti premuti
       ;----------------------------------------------------------------------
        CMP     AL,00H        ;Si tratta di tasto funzionale
        JE      Serv_Fr
       ;----------------------------------------------------------------------
        CMP     AL,CR         ;Premuto <Invio>: viene imposto un ritorno
        JE      _OUT          ;immediato al sistema operativo
        JMP     SHORT xxx01   ;Se il tasto Š indesiderato si torna in attesa
       ;----------------------------------------------------------------------
Serv_Fr:MOV     DH,CS:[Rig]   ;¿Recupera la Posizione corente del Cursore HW
        MOV     DL,CS:[Col]   ;Ùin DH (riga), DL (colonna)

CMP     AH,FrDn       ;Codice Scansione tasto Funzionale <Freccia Gi—>
        JNE     Serv_F1
        INC     DH
        CALL    ChkPos
        JE      xxx00
        DEC     DH
        JMP     SHORT xxx00
       ;----------------------------------------------------------------------
Serv_F1:CMP     AH,FrUp       ;Codice Scansione tasto Funzionale <Freccia Su>
        JNE     Serv_F2
        DEC     DH
        CALL    ChkPos
        JE      xxx00
        INC     DH
        JMP     SHORT xxx00
       ;----------------------------------------------------------------------
Serv_F2:CMP     AH,FrSn       ;Codice Scansione tasto Funzionale <Fr.Sinistra>
        JNE     Serv_F3
        SUB     DL,3
        CALL    ChkPos
        JE      xxx00
        ADD     DL,3
        JMP     SHORT xxx00
       ;----------------------------------------------------------------------
Serv_F3:CMP     AH,FrDx       ;Codice Scansione tasto Funzionale <Fr.Destra>
        JNE     xxx01         ;Se il tasto Š indesiderato si torna in attesa
        ADD     DL,3
        CALL    ChkPos
        JE      xxx00
        SUB     DL,3
        JMP     xxx00
       ;----------------------------------------------------------------------
_OUT:   MOV     AH,12H        ;¿
        MOV     AL,00H        ;³Ripristina le dimensioni normali del Cursore
        MOV     BL,34H        ;³
        INT     10H           ;Ù
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        PUSH    AX            ;³Torna al DOS con la memoria liberata e con la³
        CALL    RIP_cur       ;³chiusura di tutti i file; cede  il  controllo³
        MOV     DH,23         ;³al processo padre (generalmente COMMAND.COM);³
        MOV     DL,0          ;³il valore posto eventualmente  in AL prima di³
        CALL    SET_cur       ;³uscire pu• essere testato in  uscita  con  la³
        POP     AX            ;³funzione 4DH o mediante la lettura della  va-³
        MOV     AH,4CH        ;³riabile DOS "ERRORLEVEL"                     ³
        INT     21H           ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
CambiaCu ENDP                 ;³Chiusura standard del codice                 ³
_prog   ENDS                  ;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        END INIZIO            ;³Chiusura del segmento di codice e conclusione³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

La lettura può essere operata anche in Ambiente Assembler (disponibile sul Sito accedendo a questa pagina); se hai già provveduto alla sua installazione scarica il sorgente del progetto direttamente nella cartella C:\Arch-Lab\Lavoro (scegliendo il pulsante di opzione "Salva" e, come destinazione, seleziona la cartella che ti ho appena suggerito).

Ricorda: se fai click sull'icona a sinistra si apre l'Ambiente Assembly e puoi entrare in Ambiente on-line.
Scegli il pulsante di opzione "Aprire il file" o "Esegui l'applicazione" e conferma con OK.
NB: alcuni gestori di protezione (per esempio SP2 di WinXP) non ti consentono questa operazione:
in questo caso scrivi c:\arch-lab\bin\sys\assembler.pif direttamente nel campo indirizzo del Browser

Nella shell DOS aperta (o a pieno schermo) puoi iniziare una sessione di lavoro digitando MACRO CambiaCu /e (con gli spazi al posto giusto !!) e conferma con Invio.

	Cursore Video			PROGETTO nÂ° 05 - 3/6
	37 di 42

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42

Cursore »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default