HD44780 Visualizzatore LCD ["Dentro il Computer" di Giobe®2000]

		Tecnologia dei Cristalli Liquidi Controller/Driver HD44780-HW Controller/Driver HD44780-SW Connettore Modulo LCD Interfaccia Parallela LPT1 Applicazioni Software Progetti Hardware Download INDICE
Display LCD

Applicazioni Software

PROGETTO nÂ° 01 - 3/13 [20 di 65]

Analisi del Problema · Analisi del Codice · Procedure importanti · Schema interfaccia · Descrizione dello schema

Modulo LCD su parallela LPT1 - Gestione di 2 linee, 16 chr/linea - Controller/Driver HD44780

Analisi del Codice Sorgente [1 di 2]

L'obiettivo del progetto è quello di programmare il controller del Modulo LCD, nel nostro caso l'integrato HD44780 della Hitachi.

Il risultato è facilmente ottenibile con l'aiuto delle linee d'uscita della porta parallela.

Lo schema elettrico di tale interfaccia elimina ogni residuo dubbio ed è descritto nell'ultima pagina di questa sezione.

Il codice assembly del programma è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella:

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM    (marzo 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME       : Gest_LCD                                                     ³
;³ AUTORE     : Giorgio OBER                                                 ³
;³ VERSIONE   : marzo 2003                                                   ³
;³ DESCRIZIONE: Programma per il collaudo  dell'Interfaccia Software/Hardware³
;³              di un Visualizzatore LCD collegato  su porta parallela LPT1. ³
;³              Il programma si limita ad erogare un semplice messaggio su un³
;³              Visualizzatore LCD a 16 caratteri per riga, con 2 righe.     ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ bisogna prima installare il Driver Configura_LPT1; scaricalo ³
;³ ³°°°°°°°°°°³ a:   http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ la SHELL DOS deve essere a "Pieno Schermo" (l'esecuzione  in ³
;³ ³°°°°°°°°°°³ "finestra DOS" non produce effetto sul Display LCD)          ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ In ogni caso PRIMA DI OGNI SESSIONE DOS Š necessario eseguire³
;³ ³°°°NB !!°°³ il programma Config_LPT1.EXE in ambiente Windows per attivare³
;³ ³°°°°°°°°°°³ la visibilit… dei driver installati con Configura_LPT1 !!!!! ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ -------------------------------------------------------------³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³     Collegamenti tra Porta Parallela LPT1 e MODULO Visualizzatore LCD     ³
;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
;³     (378H)out/bit7 DIRETTO - pin09/PORTA PARALLELA ÄÄpin14/LCD Dato7     ³
;³     (378H)out/bit6 DIRETTO - pin08/PORTA PARALLELA ÄÄpin13/LCD Dato6     ³
;³     (378H)out/bit5 DIRETTO - pin07/PORTA PARALLELA ÄÄpin12/LCD Dato5     ³
;³     (378H)out/bit4 DIRETTO - pin06/PORTA PARALLELA ÄÄpin11/LCD Dato4     ³
;³                                                       pin10/LCD n.c.      ³
;³                                                       pin09/LCD n.c.      ³
;³                                                       pin08/LCD n.c.      ³
;³                                                       pin07/LCD n.c.      ³
;³     (37AH)out/bit0 NEGATO  - pin01/PORTA PARALLELA ÄÄpin05/LCD R/W       ³
;³     (37AH)out/bit3 NEGATO  - pin17/PORTA PARALLELA ÄÄpin06/LCD E         ³
;³     (37AH)out/bit2 DIRETTO - pin16/PORTA PARALLELA ÄÄpin04/LCD RS        ³
;³                        GND - pin18/PORTA PARALLELA ÄÂpin03/LCD GND       ³
;³                                                     ³ pin02/LCD Vcc +5V   ³
;³                                                     Àpin01/LCD GND       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
; COSTANTI DEFINITE PER IL PROGRAMMA:
        ESC_    EQU    27     ;codice del tasto <ESC>

; MACRO UTILIZZATE DAL PROGRAMMA:
        if1
         include  GIOBE.MAC
M_Colora MACRO  rig,col,colore,numero
        Ram_cur rig,col
        MOV     CX,numero
        MOV     AL,colore
        CALL    CambiaAtr
        ENDM
        endif

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÚÄÄÄÄ¿ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE ESTERNE³NEAR³UTILIZZATE dal PROGRAMMA (dalla LIBRERIA GIOBE.LIB~)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÀÄÄÄÄÙÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN      BIOchr1:NEAR
        EXTRN      BIObeep:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN      Byt2Asc:NEAR
        EXTRN       RAMcls:NEAR
        EXTRN       RAMpiu:NEAR
        EXTRN       RAMcur:NEAR
        EXTRN      RAMcorn:NEAR

; DICHIARAZIONI (VARIABILI) PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB        ;Attributo di colore

; DICHIARAZIONI (PROCEDURE) PER I PROGRAMMI ESTERNI:
        PUBLIC  Gest_LCD

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³DEFINIZIONE DEL SEGMENTO DEL CODICE                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog

ORG     0100H
INIZIO: JMP     Gest_LCD

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³AREA DESTINATA AI DATI DEL PROGRAMMA                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ATTRIB  DB 00H
Posiz   DB  00H
Titolo  DB  "Collaudo e gestione di un Modulo Display LCD",00H
Avviso1 DB  "Se stai lavorando con i Sistemi Operativi  Windows 2000, Win NT o WinXP",00H
Avviso2 DB  "devi prima  installare e lanciare il  Driver  Configura_LPT1; scaricalo",00H
Avviso3 DB  "a questo link:  http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm",00H
Termina DB  "Esc per terminare",00H
CopyRgh DB  "Copyright (c) 2003 - Giorgio Ober",00H
TxtLCD  DB "   Giobe2000    "
        DB "   Benvenuti!   ",00H

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³  AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : DeskTop                                                       ³
;³DESCRIZIONE: Procedura che inizializza completamente il  piano  di  lavoro.³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
DeskTop:CALL    RAMcls        ;Pulisce lo schermo e inizializza il segmento
                              ;dedicato alla RamVideo (ES=0B800H)
        CALL    VIA_cur
        RAMrepC 80,' ',0,0,1FH   ;¿ Barra del Titolo
        M_msgC  Titolo,0,15,1FH  ;Ù
       M_msgC Avviso1, 4,4,0FH;¿
       M_msgC Avviso2, 5,4,0FH;³ Messaggi Avviso
       M_msgC Avviso3, 6,4,0FH;Ùÿ
        RAMrepC 80,' ',24,0,1FH  ;¿
        M_msgC  CopyRgh,24,45,1FH;³ Barra dei messaggi
        M_msgC  Termina,24, 2,1FH;Ù
        M_Colora 24, 2,1EH, 3 ;¿ <ESC>   Evidenzia alcune parole
        M_Colora 24,66,1EH,12 ;Ù .....
        M_Colora  5,42,0EH,22 ;Ù .....
        M_Colora  6,20,0EH,23 ; .....

MOV     BH,00H        ;BH=01=con ombreggiatura; BH=00=senza
        MOV     BL,00H        ;BL=01=tratto doppio; BL=00=tratto semplice
        MOV     AH,4          ;AH=altezza in caratteri
        MOV     AL,18         ;AL=larghezza in caratteri
        MOV     DH,12         ;DH=riga
        MOV     DL,32         ;DL=colonna
        MOV     CX,1000H      ;pagina di salvataggio
        M_COLOR 04H           ;colore
                              ;   33             48
        CALL    RamCorn       ;  ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
     RAMrepC 16,' ',13,33,22H ;  ³± Visualizza16 ±³ riga 13
     RAMrepC 16,' ',14,33,22H ;  ³ÄÄÄÄÄÄ16ÄÄÄÄÄÄ³
                              ;  ³± Visualizza16 ±³ riga 14
        RET                   ;  ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : CambiaAtr                                                     ³
;³DESCRIZIONE: Cambia  il  colore  dei  CX  caratteri  consecutivi puntati in³
;³             ingresso da DH (riga),DL (colonna) con quello passato in AL.  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
CambiaAtr:INC   DI
Cambia_:MOV     ES:[DI],AL
        ADD     DI,2
        LOOP    Cambia_
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME        : Delay                                                       ³
;³ DESCRIZIONE : Il ritardo prodotto Š legato dalla velocit… del processore  ³
;³               perch‚ utilizza le un ciclo di istruzioni.. Š di circa 1 ms ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Delay:  PUSH    CX
        MOV     CX,0000H ;65536
del2_:  PUSH    AX           ;¿
        PUSH    BX           ;³
        PUSH    CX           ;³PoichŠ non Š possibile  generare  ritardi
        PUSH    DX           ;³"portabili" cos piccoli, regola il tempo
        POP     DX           ;³inserendo o togliendo una o pi— coppie di
        POP     CX           ;³PUSH/POP
        POP     BX           ;³
        POP     AX           ;Ù
        LOOP    del2_
        POP     CX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Sta_Chr                                                       ³
;³DESCRIZIONE: Servizio per visualizzazione del carattere passato in ingresso³
;³             in AL; esso Š posto a video nella posizione di stampa corrente³
;³             sul Visualizzatore e trasmesso al controller LCD; la posizione³
;³             di stampa viene aggiornata per puntare a quella del  carattere³
;³             successivo.                                                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;                                33             48
;                               ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;                               ³± Visualizza16 ±³ riga 13
;                               ³± Visualizza16 ±³ riga 14
;                               ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Sta_Chr:PUSH    AX
        M_Chr   AL,DH,DL,2AH  ; Stampa il carattere sul Display a Video
        INC     DL            ; Incrementa la colonna
        CMP     DL,49         ;¿se NON si supera l'ultima  colonna della  riga
        JNE     Serv_C1       ;³video corrente  si  prosegue  stampando  sulla
                              ;Ùstessa riga corrente
        MOV     DL,33         ;¿Altrimenti si forza il cursore  a  capo  della
        INC     DH            ;³linea opposta a quella che si sta lasciando..
        CMP     DH,15         ;³(rileva  automaticamente se  quella  superiore
        JNZ     Serv_C1       ;³o se quella inferiore)
        MOV     DH,13         ;Ù

Serv_C1:POP     AX            ;¿Predispone la  successiva  chiamata di Out_By4
        MOV     AH,01H        ;³per provvedere alla scrittura  di un carattere
                              ;ÙcioŠ a portare il segnale RS=1, carattere
        CALL    Out_By4       ;¿Trasmette al controller LCD il carattere in AL
        CALL    Addr_LCD      ;³(RS=1) e aggiorna la posizione del cursore per
        RET                   ;Ùpuntare il carattere successivo

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Addr_LCD                                                      ³
;³DESCRIZIONE: Predispone l'indirizzo del carattere da visualizzare sull'LCD;³
;³             in pratica ci• significa  indirizzare  locazione  della  DDRam³
;³             (memoria Dati del Display) che corrispondente  alla  posizione³
;³             desiderata; poichŠ le locazioni sono 80, per indirizzarle sono³
;³             sufficienti 7 bit (2^7=128),  visto  che 6 (2^6=64)  non  sono³
;³             sufficienti.                                                  ³
;³             Dunque non tutte le 128 combinazioni sono necessarie          ³
;³             E' comunque chiaro che il controller HD44780  Š  in  grado  di³
;³             immagazzinare pi— caratteri di  quanti il visualizzatore possa³
;³             mostrare; per esempio, quelli ad 1 linea gestiscono fino  a 40³
;³             caratteri, per cui solo una met… [da 0 (00H) a 39 (27H)] delle³
;³             locazioni Š copiata sul display; la rimanente  met…  pu•  per•³
;³             essere fatta scorrere nelle medesime 40 posizioni del Display,³
;³             con le istruzioni descritte in precedenza...                  ³
;³             In conclusione:                                               ³
;³             1) con visualizzatori ad 1 linea (N=0) gli indirizzi possibili³
;³                vanno da 00H (=0, comando 80H)  a  4FH (=79, comando CFH)  ³
;³             2) con visualizzatori ad 2 linee (N=1) gli indirizzi:         ³
;³                della 1.ma vanno da 00H (=0,  add 80H) a 27H(= 39, add A7H)³
;³                della 2.da vanno da 40H (=64, add C0H) a 67H(=103, add E7H)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;                         80H           8FH istruzione necessaria
;                         00H           0FH indirizzo DDRam
;                         ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;                         ³± Visualizza16 ±³ riga 13
;                         ³± Visualizza16 ±³ riga 14
;                         ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;                         40H           4FH indirizzo DDRam
;                         C0H           CFH istruzione necessaria

Addr_LCD:MOV    AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        INC     AL            ; Incrementa l'indirizzo della locazione DDRam

CMP     AL,10H        ;¿Se la posizione Š in fondo alla prima linea si
        JE      Addr_L0       ;Ùforza il cursore a capo della linea successiva
        CMP     AL,50H        ;¿
        JNE     Addr_L1       ;³Se la posizione Š in fondo alla seconda  linea
        MOV     AL,00H        ;³si forza il cursore a capo  della  prima linea
        JMP     SHORT Addr_L1 ;³
                              ;Ù
                              ;¿Fissa l'indirizzo interno della memoria  DDRam
Addr_L0:MOV     AL,40H        ;³del controller LCD per puntare l'indirizzo 40H
                              ;³corrispondente alla posizione del primo carat-
                              ;Ùtere sulla seconda linea
                              ;¿Predispone la successiva chiamata di Out_By8
Addr_L1: MOV    AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
                              ;¿Annota la posizione corrente del cursore nella
Addr_L2:MOV     CS:[Posiz],AL ;³memoria DDRam e ricostruisce l'istruzione  per
        OR      AL,80H        ;³per il controller LCD, forzando (con la OR) il
        CALL    Out_By4       ;³bit7 a 1,  come  prevede  l'istruzione  a  ci•
        RET                   ;³delegata; l'istruzione sar… del  tipo 1xxxxxxx
                              ;³da 80H (0,0) a A7H (0,39) sulla  prima  linea
                              ;Ùda C0H (1,0) a E7H (1,39) sulla seconda linea

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Out_By8                                                     ³
;³DESCRIZIONE:   In ingresso AL deve essere predisposto con il  byte esadeci-³
;³               male da spedire al controller HD 44780,  attraverso il regi-³
;³               stro di dato (0378H) della porta parallela.                 ³
;³               Il valore presisposto in AH serve per predisporre il segnale³
;³               RS a 0 (AH=00H) se il byte da scrivere Š un codice operativo³
;³               (istruzione) o RS a 1 (AH=01H) se invece deve essere scritto³
;³               un carattere (dato).                                        ³
;³               La procedura ricostruisce la  sequenza  temporale  richiesta³
;³               sui segnali RS, R/W e ENABLE del  controller  HD  44780  del³
;³               modulo visualizzatore, assicurando le condizioni ideali  per³
;³               l'output verso il modulo LCD, con l'aiuto  del  registro  di³
;³               controllo (037AH) della porta parallela.                    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  I bit3 e bit0 della  porta  di  controllo  della  parallela ³
;³ ³ NB       ³  (037AH) sono invertiti internamente e  vanno  riportati  al ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ  loro valore naturale (di nuovo invertiti) da software !!    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  Questa procedura organizza la gestione dei dati verso    il ³
;³ ³ NB       ³  mudulo visualizzatore con INTERFACCIA A 8 BIT !!            ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ                                                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;                                        -\ /-------------------\ /----
;   SCRITTURA Carattere  (RS=1)    DATA    /   dato o istruzione /
;                 o                      -/ \-------------------/ \----
;   SCRITTURA Istruzione (RS=0)    ENABLE       /---\
;                                        ------/     \-----------------
;                                  WRITE
;                                        ------------------------------
Out_By8:PUSH    DX
        MOV     BL,AL       ; Salva il valore del byte  (dato o istruzione)
                            ;ÚÄ[ segnali ]ÄÂÄ[bit del registro 037AH]ÄÂÄbyte¿
                            ;³          ³b3/neg  b2/dir  b1  b0/neg³    ³
        MOV     AL,00001011B;³ E RS  x R/W ³   EN_     RS   xx    R/W_³    ³
                            ;³ 0  0  x  0  ³   1       0     1      1 ³ 0BH ³
                            ;ÀÄOUT ISTRUZÄÄÁÄÄÄÄÄÄÄVALORE in ALÄÄÄÄÄÄÄÁÄÄALÄÙ
        CMP     AH,00H      ;¿AH=00H  RS0 da scrivere codice operativo
        JE      Out_By0     ;ÙAH=01H  RS1 da scrivere carattere (dato)
                            ;ÚÄ[ segnali ]ÄÂÄ[bit del registro 037AH]ÄÂÄbyte¿
                            ;³          ³b3/neg  b2/dir  b1  b0/neg³    ³
        MOV     AL,00001111B;³ E RS  x R/W ³   EN_     RS   xx    R/W_³    ³
                            ;³ 0  1  x  0  ³   1       1     1      1 ³ 0FH ³
                            ;ÀÄOUT CARATTÄÄÁÄÄÄÄÄÄÄVALORE in ALÄÄÄÄÄÄÄÁÄÄALÄÙ
Out_By0:MOV     DX,037AH     ;¿Forza i segnali Enable, RS e R/W ai livelli
        OUT     DX,AL        ;³desiderati (0 , 1, 0) tramite il Registro di
                             ;ÙControllo della parallela, 037AH
        CALL    Delay        ;¿Ritardo Tas (Address Setup Time, almeno 60 ns
                             ;Ùprima di riportare alto il segnale Enable)

PUSH    AX           ; Salva il valore di AH (dato o istruzione)
        MOV     AL,BL        ;¿Prepara per tempo il byte (dato o istruzione)
        MOV     DX,0378H     ;³sul bus dati del controller (via parallela)
        OUT     DX,AL        ;Ù

POP     AX           ; Recupera il valore di AH (dato o istruzione)
                             ;ÚÄ[ segnali ]ÄÂÄ[registro 037AH]Ä¿Forza a "1"
                             ;³          ³ b3  b2  b1  b0   ³il segnale
        AND     AL,11110111B ;³ E RS  x R/W ³ EN_ RS  xx  R/W_ ³Enable (cioŠ
                             ;³ 1 inalterati³ 0    inalterati  ³bit3 a "0")
                             ;ÀÄOUT ISTRUZÄÄÁÄÄVALORE in ALÄÄÄÄÙ

MOV     DX,037AH     ;¿Forza i segnali Enable, RS e R/W ai livelli
        OUT     DX,AL        ;³desiderati (1 , 1, 0) tramite il Registro di
                             ;ÙControllo della parallela, 037AH
        CALL    Delay        ;¿Ritardo Tw (Enable Pulse Width, al minimo 450
                             ;Ùns prima di riportare basso il segnale Enable)

;ÚÄ[ segnali ]ÄÂÄ[registro 037AH]Ä¿Forza a "0"
                             ;³          ³ b3  b2  b1  b0   ³il segnale
        OR      AL,00001000B ;³ E RS  x R/W ³ EN_ RS  xx  R/W_ ³Enable (cioŠ
                             ;³ 0 inalterati³ 1    inalterati  ³bit3 a "1")
                             ;ÀÄOUT ISTRUZÄÄÁÄÄVALORE in ALÄÄÄÄÙ

;¿Forza i segnali Enable, RS e R/W ai livelli
                             ;³desiderati (0 , 1, 0) tramite il Registro di
                             ;³Controllo della parallela, 037AH; il byte
        OUT     DX,AL        ;³presente sul bus dati viene scritto sul fronte
                             ;³di discesa di E [si da per scontato che esso
                             ;³sia presente sul bus almeno 195 ns (Tds, Data
                             ;ÙSetup Time) prima che E torni a '0'
                             ;¿Ritardo Th/Tah: il dato deve essere mantenuto
                             ;³sul bus almeno altri 10 ns (Th, Data Hold Time)
                             ;³dopo che il segnale Enable Š tornato basso.
        CALL    Delay        ;³Non appena il segnale di  abilitazione  Enable
                             ;³viene riportato a '0' devono passare almeno 20
                             ;³ns (Tah, Address Hold Time) prima di rilasciare
                             ;Ùi segnali RS e R/W;
        MOV     AL,BL        ;¿Lascia in uscita (in AL) il valore del byte
                             ;Ù(dato o istruzione) appena messo sull'LCD
        POP     DX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Out_By4                                                     ³
;³DESCRIZIONE:   In ingresso AL deve essere predisposto con il  byte esadeci-³
;³               male da spedire al controller HD 44780,  attraverso il regi-³
;³               stro di dato (0378H) della porta parallela.                 ³
;³               RS a 0 (AH=00H) se il byte da scrivere Š un codice operativo³
;³               (istruzione) o RS a 1 (AH=01H) se invece deve essere scritto³
;³               un carattere (dato).                                        ³
;³               La procedura ricostruisce la  sequenza  temporale  richiesta³
;³               sui segnali RS, R/W e ENABLE del  controller  HD  44780  del³
;³               modulo visualizzatore, assicurando le condizioni ideali  per³
;³               l'output verso il modulo LCD, con l'aiuto  del  registro  di³
;³               controllo (037AH) della porta parallela.                    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  I bit3 e bit0 della  porta  di  controllo  della  parallela ³
;³ ³ NB       ³  (037AH) sono invertiti internamente e  vanno  riportati  al ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ  loro valore naturale (di nuovo invertiti) da software !!    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  Questa procedura organizza la gestione dei dati verso    il ³
;³ ³ NB       ³  mudulo visualizzatore con INTERFACCIA A 4 BIT !! (di  fatto ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ  il byte da scrivere viene proposto sul bau in 2 tempi).   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Out_By4:CALL    Out_By8     ;Scrive il nibble alto (D7-D4) del dato o istruz.
        SHL     AL,1        ;¿Sposta i 4 bit meno significativi del
        SHL     AL,1        ;³byte da scrivere al posto di quelli pi—
        SHL     AL,1        ;³significativi di AL
        SHL     AL,1        ;Ù
        CALL    Out_By8     ;Scrive il nibble basso (D3-D0) del dato o istruz.
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Pre_Ini                                                     ³
;³DESCRIZIONE:   Inizializza il controller HD 44780, simulando l'attivazione ³
;³               della linea di RESET;  vengono  erogati  3  bytes  a  30H ³
;³               separati da  piccoli  ritardi  pesati;  per  default  viene ³
;³               predisposta l'interfaccia a 8 bit, senza curarsi, per ora,  ³
;³               della forma del visualizzatore e della matrice del carattere³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Pre_Ini:MOV     CX,15         ;¿
Pre_0:  CALL    Delay         ;³Ritardo iniziale di 15 ms (con Vcc=5V)
        LOOP    Pre_0         ;Ù
                              ;¿Predispone le successive chiamate di Out_By8
        MOV     AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
                              ;¿Predispone l'interfaccia a 8 bit senza curarsi
                              ;³della forma del visualizzatore e della matrice
        MOV     AL,30H        ;³del carattere; il codice operativo pu• essere
        CALL    Out_By8       ;³dunque ambiguo su tutti i 4 bit meno si-
                              ;³gnificativi, cioŠ sar… del tipo 0011 xxxx
                              ;Ù30H=0011 00xxB  interfaccia a 8 bit
        MOV     CX,5          ;¿
Pre_1:  CALL    Delay         ;³Ulteriore ritardo di 4,1 ms
        LOOP    Pre_1         ;Ù
                              ;¿Ripete la predisposizione dell'interfaccia a 8
        MOV     AL,30H        ;³bit, ancora in modo ambiguo su tutti i 4
        CALL    Out_By8       ;³bit meno  significativi:  va  bene  ancora  il
                              ;Ùcodice operativo 30H=0011 00xxB
                              ;¿Ritardo  finale di 0,1 ms, incluso nell'esecu-
                              ;Ùzione della procedura appena eseguita
        MOV     AL,30H        ;¿Ripete  per  la terza volta la predisposizione
        CALL    Out_By8       ;³"ambigua"  dell'interfaccia a 8 bit; il codice
                              ;Ùoperativo sar… ancora 30H=0011 00xxB
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Mia_Ini                                                     ³
;³DESCRIZIONE:   Predispone il controller HD 44780 per gestire il visualizza-³
;³               tore nel modo operativo desiderato, comunque con interfaccia³
;³               a 4 bit:                                                    ³
;³ Cancella Display  00000001 01H  Azzera la memoria DDRam (Clear Display)   ³
;³ Accesso Caratteri 000001IS 06H  #  I=1 (bit1) > autoincrem.indirizzo DDRam³
;³                                 #  S=0 (bit0) > display bloccato          ³
;³ Modo  del Display 00001DCB 0CH  #  D=1 (bit2) > display acceso            ³
;³                                 #  C=0 (bit1) > cursore invisibile        ³
;³                                 #  B=0 (bit0) > cursore a forma fissa     ³
;³ Scorrimento Displ 0001SRxx 14H  # S/C=0(bit3) > si muove il cursore       ³
;³                                 # R/L=1(bit2) > verso destra              ³
;³ Parametri         001DNFxx 28H  #  DL=0(bit4) > interfaccia a 4 bit       ³
;³                                 #  N=1 (bit3) > visualizzatore a 2 linee  ³
;³                                 #  F=0 (bit2) > matrice carattere 5x7 pix ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Mia_Ini:                      ;¿Predispone le successive chiamate di Out_By8
        MOV     AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
                              ;¿Predispone l'interfaccia a 4 bit senza curarsi
                              ;³della forma del visualizzatore e della matrice
        MOV     AL,20H        ;³del carattere; il codice operativo pu• essere
        CALL    Out_By8       ;³dunque ambiguo su tutti i 4 bit meno si-
                              ;³gnificativi, cioŠ sar… del tipo 0010 xxxx
                              ;Ù20H=0010 00xxB  interfaccia a 4 bit
                              ;¿Fissa i dettagli dell'interfaccia a 4 bit (DL=
                              ;³bit4=0) cominciando da ora ad  usare  la  met…
        MOV     AL,28H        ;³alta del bus dati (cioŠ dando per scontato che
        CALL    Out_By4       ;³i bit da BD3 a DB0 non sono  pi— disponibili);
                              ;³si impone: visualizzatore a 2 linee (N=bit3=1)
                              ;³e matrice carattere con 5x7 pixel (F=bit2= 0);
                              ;Ùil codice operativo Š dunque 0010 10xx (=28H)
        MOV     AL,01H        ;¿Azzera la memoria DDRam (Clear Display ): il
        CALL    Out_By4       ;Ùcodice operativo necessario Š 0000 0001 (=01H)
                              ;¿Fissa il modo di gestire il display: con auto-
        MOV     AL,06H        ;³incremento dell'indirizzo DDRam e  del cursore
        CALL    Out_By4       ;³(I=bit1=1) e  con display bloccato (S=bit0=0);
                              ;Ùil codice operativo Š  dunque 0000 0110 (=06H)
                              ;¿Inizializza le caratteristiche del display per
        MOV     AL,0CH        ;³display  acceso (D=bit2=1), cursore invisibile
        CALL    Out_By4       ;³(C=bit1=0) e a forma fissa (B=bit0=0);
                              ;Ùil codice operativo Š  dunque 0000 1100 (=0CH)
                              ;¿Inizializza lo scorrimento sul display:  fissa
        MOV     AL,14H        ;³il movimento del cursore (S/C=bit3=0) e  verso
        CALL    Out_By4       ;³destra  (R/L=bit2=1);  il  codice  operativo Š
                              ;Ùdunque 0001 01xx (=14H)
        MOV     AL,00H        ;¿Fissa il  cursore  nella  prima  posizione, in
        MOV     CS:[Posiz],AL ;³alto a sinistra, e istruisce il controller LCD
        OR      AL,80H        ;³puntando anche  la prima  locazione  della sua
        CALL    Out_By4       ;³memoria DDRam, di  indirizzo  xxxxxxx=0000000;
        RET                   ;Ùl'istruzione Š del tipo 1xxxxxxx=10000000=80H

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Giochino                                                    ³
;³DESCRIZIONE:   Esegue un effetto visivo, in attesa di terminare            ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
TabGioc DB  33,13, 80H,48,13, 8FH ;¿
        DB  34,13, 81H,47,13, 8EH ;³
        DB  35,13, 82H,46,13, 8DH ;³Tabella interna di "Giochino"
        DB  35,14,0C2H,46,14,0CDH ;³
        DB  34,14,0C1H,47,14,0CEH ;³
        DB  33,14,0C0H,48,14,0CFH ;Ù
        ;---------------------------------------------------------------------
GiroChr:PUSH    AX            ;¿    33 35        46 48
        MOV     DL,CS:[SI]    ;³    ÚÄÄÄÄÄÄÄÄÄÄÄÄ¿
        MOV     DH,CS:[SI+1]  ;³    ³±±±Giobe2000 ±±±³ riga 13
        M_Chr   AL,DH,DL,2AH  ;³    ³±±±Benvenuti!±±±³ riga 14
        PUSH    AX            ;³    ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        MOV     AL,CS:[SI+2]  ;³Procedura interna di "Giochino"
        MOV     AH,00H        ;³
        CALL    Out_By4       ;³  80H 83H      8DH 8FHistruzione necessaria
        POP     AX            ;³   ÚÄÄÄÄÄÄÄÄÄÄÄÄ¿
        MOV     AH,01H        ;³   ³±±±Giobe2000 ±±±³ riga 13
        CALL    Out_By4       ;³   ³±±±Benvenuti!±±±³ riga 14
        POP     AX            ;³   ÀÄÄÄÄÄÄÄÄÄÄÄÄÙ
        RET                   ;Ù  C0H C3H      CDH CFHistruzione necessaria
        ;---------------------------------------------------------------------
Giochino:MOV    CX,6          ;¿   Giochino.... un attesa della pressione
        LEA     SI,TabGioc    ;³   del  tasto  per  terminare............
Gioco1: MOV     AL,'*'        ;³¿
        CALL    GiroChr       ;³³
        ADD     SI,3          ;³³
        CALL    GiroChr       ;³³
        SUB     SI,3          ;³Ù
        PUSH    CX            ;³¿
        MOV     CX,40         ;³³
Gioco2: CALL    Delay         ;³³
        LOOP    Gioco2        ;³³
        POP     CX            ;³Ù
        MOV     AL,' '        ;³¿
        CALL    GiroChr       ;³³
        ADD     SI,3          ;³³
        CALL    GiroChr       ;³³
        ADD     SI,3          ;³Ù
        PUSH    DX            ;³¿
        PUSH    CX            ;³³
        PUSH    SI            ;³³
        MOV     AH,01H        ;³³Controlla se Š premuto un tasto....
        INT     16H           ;³³... se Š cos termina il giochino
        POP     SI            ;³³
        POP     CX            ;³³
        POP     DX            ;³Ù
        JNZ     Gioco3        ;³
        LOOP    Gioco1        ;³
        JMP     Giochino      ;³
Gioco3: CALL    KEYwait       ;³¿Se non Š ESC non si esce !!
        CMP     AL,ESC_       ;³³
        JNE     Giochino      ;³Ù
        RET                   ;Ù

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
Gest_LCD proc  NEAR           ;³      AREA DEDICATA AL MAIN PROGRAM         ³³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
   MOV Byte Ptr CS:[Posiz],00H;Fissa l'indirizzo iniziale  in DDRam (il primo)
        CALL    DESKTOP       ;Inizializza  completamente il piano  di  lavoro
                              ;¿Inizializza il  controller HD 44780, simulando
                              ;³l'attivazione  della  linea di RESET;  vengono
        CALL    Pre_Ini       ;³erogati 3 bytes  a 30H separati  da  piccoli
                              ;³ritardi   "pesati";    per    default    viene
                              ;Ùpredisposta l'interfaccia a 8 bit
                              ;¿Predispone il controller HD 44780 per  gestire
                              ;³il visualizzatore nel modo operativo desiderato
        CALL    Mia_Ini       ;³interfaccia a 4 bit, visualizzatore a 2 linee,
                              ;³matrice del carattere con  5x7 pixel,  display
                              ;³acceso,  cursore  invisibile  a  forma  fissa,
                              ;³azzeramento della memoria DDRam,autoincremento
                              ;Ùdell'indirizzo, display bloccato
        MOV     DH,13         ;¿Fissa la Riga e la Colonna della posizione  di
        MOV     DL,33         ;Ùstampa iniziale
        LEA     SI,TxtLCD     ;¿
XXX00:  MOV     AL,CS:[SI]    ;³Legge e mette a video la frase
        CMP     AL,00H        ;³    "      Giobe2000    "
        JE      XXX01         ;³    "     Benvenuti!    "
        CALL    Sta_Chr       ;³
        INC     SI            ;³
        JMP     SHORT XXX00   ;Ù

XXX01:  CALL    Giochino
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
_OUT:   PUSH    AX            ;³Torna al DOS con la memoria liberata e con la³
        CALL    RIP_cur       ;³chiusura di tutti i file; cede  il  controllo³
        MOV     DH,23         ;³al processo padre (generalmente COMMAND.COM);³
        MOV     DL,0          ;³il valore posto eventualmente  in AL prima di³
        CALL    SET_cur       ;³uscire pu• essere testato in  uscita  con  la³
        POP     AX            ;³funzione 4DH o mediante la lettura della  va-³
        MOV     AH,4CH        ;³riabile DOS "ERRORLEVEL"                     ³
        INT     21H           ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Gest_LCD ENDP                 ;³Chiusura standard del codice                 ³
_prog   ENDS                  ;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        END INIZIO            ;³Chiusura del segmento di codice e conclusione³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

La lettura può essere operata anche in Ambiente Assembler (disponibile sul Sito accedendo a questa pagina); se hai già provveduto alla sua installazione scarica il sorgente del progetto direttamente nella cartella C:\Arch-Lab\Lavoro (scegliendo il pulsante di opzione "Salva" e, come destinazione, seleziona la cartella che ti ho appena suggerito).

Ricorda: se fai click sull'icona a sinistra si apre l'Ambiente Assembly e puoi entrare in Ambiente on-line.
Scegli il pulsante di opzione "Aprire il file" o "Esegui l'applicazione" e conferma con OK.
NB: alcuni gestori di protezione (per esempio SP2 di WinXP) non ti consentono questa operazione:
in questo caso scrivi c:\arch-lab\bin\sys\assembler.pif direttamente nel campo indirizzo del Browser

Nella shell DOS aperta (o a pieno schermo) puoi iniziare una sessione di lavoro digitando MACRO Gest_LCD /e (con gli spazi al posto giusto !!) e conferma con Invio.

	Display LCD			PROGETTO nÂ° 01 - 3/13
	20 di 65

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65

Display LCD »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default