HD44780 Visualizzatore LCD ["Dentro il Computer" di Giobe®2000]

		Tecnologia dei Cristalli Liquidi Controller/Driver HD44780-HW Controller/Driver HD44780-SW Connettore Modulo LCD Interfaccia Parallela LPT1 Applicazioni Software Progetti Hardware Download INDICE
Display LCD

Applicazioni Software

PROGETTO nÂ° 03 - 3/11 [39 di 65]

Analisi del Problema · Analisi del Codice · Procedure importanti · Schema interfaccia · Descrizione dello schema

Modulo LCD su parallela LPT1 - Editor di 2 linee, 16 o 40 chr/linea - Controller/Driver HD44780

Analisi del Codice Sorgente [1 di 3]

L'obiettivo del progetto è quello di realizzare un Editor per il visualizzatore LCD a 2 linee ciascuna da 16 o 40 caratteri di un Modulo LCD, controllato dalla tastiera del PC e supportato da eco a video.

In sintonia con i progetti precedenti, mantiene inalterate le prerogative hardware (schema elettrico e descrizione dello schema) e quelle software legate alla programmazione (tramite le linee d'uscita della porta parallela LPT1) del controller del Modulo LCD, sempre l'integrato HD44780 della Hitachi.

Il codice assembly del programma è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella:

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM    (marzo 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME       : EditLCD1       ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
;³ AUTORE     : Giorgio OBER   ³   Tratto  da  una IDEA  di  PAOLO RALLO    ³³
;³ VERSIONE 1 : marzo 2003     ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿ ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
;³ ³°°°°°°°°°°³ ³Questa versione di "Edit_LCD"  Š  adatta  solo per  Display³³
;³ ³°VERSIONE°³ ³a 2 linee, con 16 caratteri per linea;  e possibile  per•³³
;³ ³°  BASE  °³ ³controllare anche le rimanenti 24 locazioni DDRam  e quindi³³
;³ ³°°°°°°°°°°³ ³potenzialmente editare testi anche con risoluzioni migliori³³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;³ DESCRIZIONE: Programma per il collaudo  dell'Interfaccia Software/Hardware³
;³              di un Visualizzatore LCD collegato  su porta parallela LPT1. ³
;³              Si tratta di un vero e proprio "Editor" per  Display  LCD, in³
;³              grado di accettare qualunque carattere  Ascii  e  di  gestire³
;³              i tasti di movimento (le frecce , PgUp, PgDn, Home e End)³
;³              per spostare il cursore senza scrivere, e quelli di controllo³
;³              come Invio (va a capo linea) e BackSpace (cancella indietro).³
;³              <F1> consente di  commutare il controllo da 16 a 40 caratteri³
;³              per riga, e <F2> cancella tutto il Display.                  ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ bisogna prima installare il Driver Configura_LPT1; scaricalo ³
;³ ³°°°°°°°°°°³ a:   http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ la SHELL DOS deve essere a "Pieno Schermo" (l'esecuzione  in ³
;³ ³°°°°°°°°°°³ "finestra DOS" non produce effetto sul Display LCD)          ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ In ogni caso PRIMA DI OGNI SESSIONE DOS Š necessario eseguire³
;³ ³°°°NB !!°°³ il programma Config_LPT1.EXE in ambiente Windows per attivare³
;³ ³°°°°°°°°°°³ la visibilit… dei driver installati con Configura_LPT1 !!!!! ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ -------------------------------------------------------------³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³     Collegamenti tra Porta Parallela LPT1 e MODULO Visualizzatore LCD     ³
;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
;³     (378H)out/bit7 DIRETTO - pin09/PORTA PARALLELA ÄÄpin14/LCD Dato7     ³
;³     (378H)out/bit6 DIRETTO - pin08/PORTA PARALLELA ÄÄpin13/LCD Dato6     ³
;³     (378H)out/bit5 DIRETTO - pin07/PORTA PARALLELA ÄÄpin12/LCD Dato5     ³
;³     (378H)out/bit4 DIRETTO - pin06/PORTA PARALLELA ÄÄpin11/LCD Dato4     ³
;³                                                       pin10/LCD n.c.      ³
;³                                                       pin09/LCD n.c.      ³
;³                                                       pin08/LCD n.c.      ³
;³                                                       pin07/LCD n.c.      ³
;³     (37AH)out/bit0 NEGATO  - pin01/PORTA PARALLELA ÄÄpin05/LCD R/W       ³
;³     (37AH)out/bit3 NEGATO  - pin17/PORTA PARALLELA ÄÄpin06/LCD E         ³
;³     (37AH)out/bit2 DIRETTO - pin16/PORTA PARALLELA ÄÄpin04/LCD RS        ³
;³                        GND - pin18/PORTA PARALLELA ÄÂpin03/LCD GND       ³
;³                                                     ³ pin02/LCD Vcc +5V   ³
;³                                                     Àpin01/LCD GND       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
; COSTANTI DEFINITE PER IL PROGRAMMA:
        ESC_     EQU     1BH  ;  Codice Ascii per il tasto <ESC>
        Invio    EQU     0DH  ;¿
        BackSp   EQU     08H  ;³ Codici di protocollo per la gestione
        Frec_Su  EQU     48H  ;³ del Visualizzatore LCD
        Frec_Giu EQU     50H  ;³
        Frec_Dx  EQU     4DH  ;³
        Frec_Sn  EQU     4BH  ;³
        Home     EQU     47H  ;³
        PgUp     EQU     49H  ;³ ÚÄ[NB:]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        PgDn     EQU     51H  ;³ ³esclusi <Invio> e <BackSp>           ³
        End_Fine EQU     4FH  ;³ ³sono  tutti  Tasti Funzionali,  cioŠ ³
        Del_Canc EQU     53H  ;³ ³caratterizzati da codice Ascii = 00H ³
        F1_      EQU     3BH  ;³ ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        F2_      EQU     3CH  ;Ù

; MACRO UTILIZZATE DAL PROGRAMMA:
        if1     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
         include  GIOBE.MAC   ;³
                ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

M_Cornice MACRO altez,largh,rig,col,colore,ombra,tipo,pagina
        PUSH    SI
        PUSH    CX
        PUSH    AX
        PUSH    BX
        PUSH    DX
        MOV     BH,ombra      ;BH=01=con ombreggiatura; BH=00=senza
        MOV     BL,tipo       ;BL=01=tratto doppio; BL=00=tratto semplice
        MOV     AH,altez      ;AH=altezza in caratteri
        MOV     AL,largh      ;AL=larghezza in caratteri
        MOV     DH,rig        ;DH=riga
        MOV     DL,col        ;DL=colonna
        MOV     CX,pagina     ;pagina di salvataggio
        M_COLOR colore        ;colore
        CALL    RamCorn
        POP     DX
        POP     BX
        POP     AX
        POP     CX
        POP     SI
        ENDM

M_Colora MACRO  rig,col,colore,numero
        Ram_cur rig,col
        MOV     CX,numero
        MOV     AL,colore
        CALL    CambiaAtr
        ENDM

endif

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÚÄÄÄÄ¿ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE ESTERNE³NEAR³UTILIZZATE dal PROGRAMMA (dalla LIBRERIA GIOBE.LIB~)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÀÄÄÄÄÙÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN      BIOchr1:NEAR
        EXTRN      BIObeep:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN        Delay:NEAR
        EXTRN      Byt2Asc:NEAR
        EXTRN       RAMcls:NEAR
        EXTRN       RAMpiu:NEAR
        EXTRN       RAMcur:NEAR
        EXTRN      RAMcorn:NEAR

; DICHIARAZIONI (VARIABILI) PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB        ;Attributo di colore

; DICHIARAZIONI (PROCEDURE) PER I PROGRAMMI ESTERNI:
        PUBLIC  EditLCD1

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³DEFINIZIONE DEL SEGMENTO DEL CODICE                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog

ORG     0100H
INIZIO: JMP     EditLCD1

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³AREA DESTINATA AI DATI DEL PROGRAMMA                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ATTRIB  DB  0FH
OldChr  DB  ' '
Limite  DB 0FFH               ;FFH   Limite a 16 caratteri
                              ;00H   Limite a 40 caratteri
Posiz   DB  00H
Titolo  DB  "Editor per Visualizzatore LCD con eco a Video",00H
Intest1 DB  "Il  controllo del Visualizzatore  Š garantito  direttamente da Tastiera",00H
Intest2 DB  "L'azione dei Tasti produce effetto sia sul Display che nell'eco a video",00H
Intest3 DB  "<F1> consente di  commutare il controllo  da 16 a 40 caratteri per riga",00H
Intest4 DB  "Le frecce  spostano il cursore; <Invio> lo forza all'inizio 2ø riga",00H
Intest5 DB  "<PgUp>, <PgDn>, <Home> e <End> spostano il cursore  nei  4 angoli",00H
Intest6 DB  "<BkSp> cancella indietro i testi scritti;<F2> cancella tutto il Display",00H
Intest7 DB  "Se stai lavorando con i Sistemi Operativi  Windows 2000, Win NT o WinXP",00H
Intest8 DB  "devi prima  installare e lanciare il  Driver  Configura_LPT1; scaricalo",00H
Intest9 DB  "a questo link:  http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm",00H
Displ1  DB  "Display Data Random Access Memory  (DDram)",00H
Displ2  DB  "Visualizzatore predisposto per 40 chr/riga",00H
Termina DB  "Esc per terminare",00H
CopyRgh DB  "- Copyright (c) 2003 -    Giorgio Ober/Paolo Rallo",00H

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³  AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : DeskTop                                                       ³
;³DESCRIZIONE: Procedura che inizializza completamente il  piano  di  lavoro.³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
DeskTop:CALL    RAMcls        ;Pulisce lo schermo e inizializza il segmento
                              ;dedicato alla RamVideo (ES=0B800H)
        CALL    VIA_cur
        RAMrepC 80,' ',0,0,1FH   ;¿ Barra del Titolo
        M_msgC  Titolo,0,15,1FH  ;Ù
        RAMrepC 80,' ',20,0,1FH  ;¿
        M_msgC  CopyRgh,20,29,1FH;³ Barra dei messaggi
        M_msgC  Termina,20, 2,1FH;Ù

M_msgC Intest1,2,4,0FH;¿
        M_msgC Intest2,3,4,0FH;³
        M_msgC Intest3,5,4,0FH;³ Messaggi di presentazione
        M_msgC Intest4,6,4,0FH;³
        M_msgC Intest5,7,4,0FH;³
        M_msgC Intest6,8,4,0FH;³
       M_msgC Intest7,22,4,01H;³
       M_msgC Intest8,23,4,01H;³
       M_msgC Intest9,24,4,01H;Ùÿ

M_msgC Displ1,11,21,0FH;
       M_msgC Displ2,16,21,0FH;
        M_Colora  5, 5,0EH, 2 ; <F1>   ¿
        M_Colora  6,14,0EH, 4 ;    ³
        M_Colora  6,41,0EH, 5 ; <Invio>³
        M_Colora  7, 5,0EH, 4 ; <PgUp> ³
        M_Colora  7,13,0EH, 4 ; <PgDn> ³
        M_Colora  7,21,0EH, 4 ; <Home> ³ Evidenzia alcune parole
        M_Colora  7,30,0EH, 3 ; <End>  ³
        M_Colora  8, 5,0EH, 4 ; <BkSp> ³
        M_Colora  8,46,0EH, 2 ; <F2>   ³
        M_Colora 20, 2,1EH, 3 ; <ESC>  ³
        M_Colora 20,55,1EH,12 ; .....  ³
        M_Colora 20,68,1EH,12 ; ...... ³
        M_Colora 24,20,03H,23 ; .....  ³
        M_Chr   '0',16,53, 0EH  .....  Ù
                                           ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CALL    Displ16                    ;³ Visualizzatore a 16 caratteri  ³
        RET                                ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : CambiaAtr                                                     ³
;³DESCRIZIONE: Cambia  il  colore  dei  CX  caratteri  consecutivi puntati in³
;³             ingresso da DH (riga),DL (colonna) con quello passato in AL.  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
CambiaAtr:INC   DI
Cambia_:MOV     ES:[DI],AL
        ADD     DI,2
        LOOP    Cambia_
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Cursore                                                       ³
;³DESCRIZIONE: Mette a Video il Cursore "°", provvedendo  prima a  salvare il³
;³             carattere che sar… coperto dalla sua forma                    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Cursore:PUSH    AX
        CALL    RAMcur        ;¿Assume   il   carattere   che   sar…   coperto
        MOV     AL,ES:[DI]    ;³direttamente  dalla  RamVideo,  e  ne fa copia
        MOV     CS:[OldChr],AL;Ùnella variabile locale [OldChr]
        M_Chr   '°',DH,DL,2AH ; Mostra il cursore sul Display a Video
        POP     AX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Evidenz                                                       ³
;³DESCRIZIONE: Evidenzia il carattere coperto dal Cursore, invece di coprirlo³
;³             con il suo simbolo  "°"                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Evidenz:PUSH    AX
        CALL    RAMcur        ;¿
        MOV     AL,ES:[DI+1]  ;³Assume l'attributo di colore del carattere
        OR      AL,80H        ;³che sar… coperto, direttamente in RamVideo
        MOV     ES:[DI+1],AL  ;Ù
        POP     AX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Old_Chr                                                       ³
;³DESCRIZIONE: Ripropone il carattere coperto di volta in volta dal Cursore, ³
;³             nei casi in cui Š necessario, come dopo la  pressione di Invio³
;³             o di BackSpace.                                               ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Old_Chr:PUSH    AX
        MOV     AL,CS:[OldChr];¿Assume  dalla  variabile  locale  [OldChr]  il
        CALL    RAMcur        ;³carattere coperto in precedenza dal Cursore °
        MOV     ES:[DI],AL    ;Ùe lo rimette al suo posto, in RamVideo
        POP     AX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Displ16                                                       ³
;³DESCRIZIONE: Indica che la gestione del Visualizzatore Š consentita su 16  ³
;³             caratteri per riga                                            ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;         21             36 39                     62
;         ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;         ³± Visualizza16 ±³³±     Visualizza a 40  ±³ riga 13
;         ³ÄÄÄÄÄÄ16ÄÄÄÄÄÄ³³ÄÄÄÄÄÄÄÄÄ24ÄÄÄÄÄÄÄÄÄÄÄ³ riga 14
;         ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
       ;                  01=con ombreggiaturaÄÂÄ00=senza ombreggiatura
       ;M_Cornice altez,largh,rig,col,colore,ombra,tipo,pagina
       ;                          00=tratto sempliceÄÁÄ01=tratto doppio
Displ16:M_Cornice 4,26,12,38,04H,0,0,1000H ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        RAMrepC 24,'°',13,39,08H           ;³ Visualizzatore a 40 caratteri  ³
        RAMrepC 24,'°',14,39,08H           ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿ ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³ ³            Visualizzatore a 16 caratteri  ³
        JMP     Displ_0       ;³ ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³ Fissa la Riga e la Colonna iniziale e
                              ;Ù mostra il cursore in quella posizione

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Displ40                                                       ³
;³DESCRIZIONE: Indica che la gestione del Visualizzatore Š consentita su 40  ³
;³             caratteri per riga                                            ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;         21             36 39                     62
;         ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;         ³± Visualizza16 ±³³±     Visualizza a 40  ±³ riga 13
;         ³ÄÄÄÄÄÄ16ÄÄÄÄÄÄ³³ÄÄÄÄÄÄÄÄÄ24ÄÄÄÄÄÄÄÄÄÄÄ³ riga 14
;         ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Displ40:M_Cornice 4,26,12,38,04H,0,0,1000H ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        RAMrepC 24,' ',13,39,22H           ;³ Visualizzatore a 40 caratteri  ³
        RAMrepC 24,' ',14,39,22H           ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        M_Chr   'Ä',12,36, 04H
        M_Chr   'Ä',15,36, 04H
        M_Chr   '',12,62,0CFH
        M_Chr   '',15,62,0CFH
        M_Chr   '4',16,52, 0EH
        M_Chr   '0',16,53, 0EH
Displ_0:M_Cornice 4,18,12,20,04H,0,0,1000H ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        RAMrepC 16,' ',13,21,22H           ;³ Visualizzatore a 16 caratteri  ³
        RAMrepC 16,' ',14,21,22H           ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        CMP Byte Ptr CS:[Limite],0FFH
        JE      Displ_1
        JMP     Displ_2
Displ_1:M_Chr   '',12,36,0CFH
        M_Chr   '',15,36,0CFH
        M_Chr   'Ä',12,62, 04H
        M_Chr   'Ä',15,62, 04H
        M_Chr   '1',16,52, 0EH
        M_Chr   '6',16,53, 0EH
Displ_2:MOV     DH,13         ;¿Fissa la Riga e la Colonna iniziale e
        MOV     DL,21         ;³mostra il cursore in quella posizione
        CALL    Cursore       ;Ù
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA   : Delay__                                                      ³
;³DESCRIZIONE : Il ritardo prodotto Š legato dalla velocit… del processore   ³
;³              perch‚ utilizza le un ciclo di istruzioni.. Š di circa 1 ms  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Delay__:PUSH    CX
        MOV     CX,0000H ;65536
del2_:  PUSH    AX
        PUSH    BX
        PUSH    CX
        PUSH    DX
        POP     DX
        POP     CX
        POP     BX
        POP     AX
        LOOP    del2_
        POP     CX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Delay_                                                        ³
;³DESCRIZIONE: Impone un ritardo PORTABILE di 55 millisecondi.               ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Delay_: PUSH    CX
        PUSH    AX
        MOV     CX,1
        CALL    Delay
        POP     AX
        POP     CX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Out_By8                                                     ³
;³DESCRIZIONE:   In ingresso AL deve essere predisposto con il  byte esadeci-³
;³               male da spedire al controller HD 44780,  attraverso il regi-³
;³               stro di dato (0378H) della porta parallela.                 ³
;³               Il valore presisposto in AH serve per predisporre il segnale³
;³               RS a 0 (AH=00H) se il byte da scrivere Š un codice operativo³
;³               (istruzione) o RS a 1 (AH=01H) se invece deve essere scritto³
;³               un carattere (dato).                                        ³
;³               La procedura ricostruisce la  sequenza  temporale  richiesta³
;³               sui segnali RS, R/W e ENABLE del  controller  HD  44780  del³
;³               modulo visualizzatore, assicurando le condizioni ideali  per³
;³               l'output verso il modulo LCD, con l'aiuto  del  registro  di³
;³               controllo (037AH) della porta parallela.                    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  I bit3 e bit0 della  porta  di  controllo  della  parallela ³
;³ ³ NB       ³  (037AH) sono invertiti internamente e  vanno  riportati  al ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ  loro valore naturale (di nuovo invertiti) da software !!    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  Questa procedura organizza la gestione dei dati verso    il ³
;³ ³ NB       ³  mudulo visualizzatore con INTERFACCIA A 8 BIT !!            ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ                                                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;                                        -\ /-------------------\ /----
;   SCRITTURA Carattere  (RS=1)    DATA    /   dato o istruzione /
;                 o                      -/ \-------------------/ \----
;   SCRITTURA Istruzione (RS=0)    ENABLE       /---\
;                                        ------/     \-----------------
;                                  WRITE
;                                        ------------------------------
Out_By8:PUSH    DX
        MOV     BL,AL         ; Salva il valore del byte  (dato o istruzione)
                              ;ÚÄ[ segnali ]ÄÂÄ[bit del registro 037AH]ÄÂÄbyte¿
                              ;³          ³b3/neg  b2/dir  b1  b0/neg³    ³
        MOV     AL,00001011B  ;³ E RS  x R/W ³   EN_     RS   xx    R/W_³    ³
                              ;³ 0  0  x  0  ³   1       0     1      1 ³ 0BH ³
                              ;ÀÄOUT ISTRUZÄÄÁÄÄÄÄÄÄÄVALORE in ALÄÄÄÄÄÄÄÁÄÄALÄÙ
        CMP     AH,00H        ;¿AH=00H  RS0 da scrivere codice operativo
        JE      Out_By0       ;ÙAH=01H  RS1 da scrivere carattere (dato)
                              ;ÚÄ[ segnali ]ÄÂÄ[bit del registro 037AH]ÄÂÄbyte¿
                              ;³          ³b3/neg  b2/dir  b1  b0/neg³    ³
        MOV     AL,00001111B  ;³ E RS  x R/W ³   EN_     RS   xx    R/W_³    ³
                              ;³ 0  1  x  0  ³   1       1     1      1 ³ 0FH ³
                              ;ÀÄOUT CARATTÄÄÁÄÄÄÄÄÄÄVALORE in ALÄÄÄÄÄÄÄÁÄÄALÄÙ
Out_By0:MOV     DX,037AH      ;¿Forza i segnali Enable, RS e R/W ai livelli
        OUT     DX,AL         ;³desiderati (0 , 1, 0) tramite il Registro di
                              ;ÙControllo della parallela, 037AH
        CALL    Delay__       ;¿Ritardo Tas (Address Setup Time, almeno 60 ns
                              ;Ùprima di riportare alto il segnale Enable)

PUSH    AX            ; Salva il valore di AH (dato o istruzione)
        MOV     AL,BL         ;¿Prepara per tempo il byte (dato o istruzione)
        MOV     DX,0378H      ;³sul bus dati del controller (via parallela)
        OUT     DX,AL         ;Ù

POP     AX            ; Recupera il valore di AH (dato o istruzione)
                              ;ÚÄ[ segnali ]ÄÂÄ[registro 037AH]Ä¿Forza a "1"
                              ;³          ³ b3  b2  b1  b0   ³il segnale
        AND     AL,11110111B  ;³ E RS  x R/W ³ EN_ RS  xx  R/W_ ³Enable (cioŠ
                              ;³ 1 inalterati³ 0    inalterati  ³bit3 a "0")
                              ;ÀÄOUT ISTRUZÄÄÁÄÄVALORE in ALÄÄÄÄÙ

MOV     DX,037AH      ;¿Forza i segnali Enable, RS e R/W ai livelli
        OUT     DX,AL         ;³desiderati (1 , 1, 0) tramite il Registro di
                              ;ÙControllo della parallela, 037AH
        CALL    Delay__       ;¿Ritardo Tw (Enable Pulse Width, al minimo 450
                              ;Ùns prima di riportare basso il segnale Enable)

;ÚÄ[ segnali ]ÄÂÄ[registro 037AH]Ä¿Forza a "0"
                              ;³          ³ b3  b2  b1  b0   ³il segnale
        OR      AL,00001000B  ;³ E RS  x R/W ³ EN_ RS  xx  R/W_ ³Enable (cioŠ
                              ;³ 0 inalterati³ 1    inalterati  ³bit3 a "1")
                              ;ÀÄOUT ISTRUZÄÄÁÄÄVALORE in ALÄÄÄÄÙ

;¿Forza i segnali Enable, RS e R/W ai livelli
                              ;³desiderati (0 , 1, 0) tramite il Registro di
                              ;³Controllo della parallela, 037AH; il byte
        OUT     DX,AL         ;³presente sul bus dati viene scritto sul fronte
                              ;³di discesa di E [si da per scontato che esso
                              ;³sia presente sul bus almeno 195 ns (Tds, Data
                              ;ÙSetup Time) prima che E torni a '0'
                              ;¿Ritardo Th/Tah: il dato deve essere mantenuto
                              ;³sul bus almeno altri 10 ns (Th, Data Hold Time)
                              ;³dopo che il segnale Enable Š tornato basso.
        CALL    Delay__       ;³Non appena il segnale di  abilitazione  Enable
                              ;³viene riportato a '0' devono passare almeno 20
                              ;³ns (Tah, Address Hold Time) prima di rilasciare
                              ;Ùi segnali RS e R/W;
        MOV     AL,BL         ;¿Lascia in uscita (in AL) il valore del byte
                              ;Ù(dato o istruzione) appena messo sull'LCD
        POP     DX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Out_By4                                                     ³
;³DESCRIZIONE:   In ingresso AL deve essere predisposto con il  byte esadeci-³
;³               male da spedire al controller HD 44780,  attraverso il regi-³
;³               stro di dato (0378H) della porta parallela.                 ³
;³               RS a 0 (AH=00H) se il byte da scrivere Š un codice operativo³
;³               (istruzione) o RS a 1 (AH=01H) se invece deve essere scritto³
;³               un carattere (dato).                                        ³
;³               La procedura ricostruisce la  sequenza  temporale  richiesta³
;³               sui segnali RS, R/W e ENABLE del  controller  HD  44780  del³
;³               modulo visualizzatore, assicurando le condizioni ideali  per³
;³               l'output verso il modulo LCD, con l'aiuto  del  registro  di³
;³               controllo (037AH) della porta parallela.                    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  I bit3 e bit0 della  porta  di  controllo  della  parallela ³
;³ ³ NB       ³  (037AH) sono invertiti internamente e  vanno  riportati  al ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ  loro valore naturale (di nuovo invertiti) da software !!    ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿  Questa procedura organizza la gestione dei dati verso    il ³
;³ ³ NB       ³  mudulo visualizzatore con INTERFACCIA A 4 BIT !! (di  fatto ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ  il byte da scrivere viene proposto sul bau in 2 tempi).   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Out_By4:PUSH    DX
        CALL    Out_By8       ;Scrive il nibble alto (D7-D4) del dato o istruz.
        SHL     AL,1          ;¿Sposta i 4 bit meno significativi del
        SHL     AL,1          ;³byte da scrivere al posto di quelli pi—
        SHL     AL,1          ;³significativi di AL
        SHL     AL,1          ;Ù
        CALL    Out_By8       ;Scrive il nibble basso (D3-D0) del dato o istruz.
        POP     DX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Pre_Ini                                                     ³
;³DESCRIZIONE:   Inizializza il controller HD 44780, simulando l'attivazione ³
;³               della linea di RESET;  vengono  erogati  3  bytes  a  30H ³
;³               separati da  piccoli  ritardi  pesati;  per  default  viene ³
;³               predisposta l'interfaccia a 8 bit, senza curarsi, per ora,  ³
;³               della forma del visualizzatore e della matrice del carattere³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Pre_Ini:MOV     CX,15         ;¿
Pre_0:  CALL    Delay__       ;³Ritardo iniziale di 15 ms (con Vcc=5V)
        LOOP    Pre_0         ;Ù
                              ;¿Predispone le successive chiamate di Out_By8
        MOV     AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
                              ;¿Predispone l'interfaccia a 8 bit senza curarsi
                              ;³della forma del visualizzatore e della matrice
        MOV     AL,30H        ;³del carattere; il codice operativo pu• essere
        CALL    Out_By8       ;³dunque ambiguo su tutti i 4 bit meno si-
                              ;³gnificativi, cioŠ sar… del tipo 0011 xxxx
                              ;Ù30H=0011 00xxB  interfaccia a 8 bit
        MOV     CX,5          ;¿
Pre_1:  CALL    Delay__       ;³Ulteriore ritardo di 4,1 ms
        LOOP    Pre_1         ;Ù
                              ;¿Ripete la predisposizione dell'interfaccia a 8
        MOV     AL,30H        ;³bit, ancora in modo ambiguo su tutti i 4
        CALL    Out_By8       ;³bit meno  significativi:  va  bene  ancora  il
                              ;Ùcodice operativo 30H=0011 00xxB
                              ;¿Ritardo  finale di 0,1 ms, incluso nell'esecu-
                              ;Ùzione della procedura appena eseguita
        MOV     AL,30H        ;¿Ripete  per  la terza volta la predisposizione
        CALL    Out_By8       ;³"ambigua"  dell'interfaccia a 8 bit; il codice
                              ;Ùoperativo sar… ancora 30H=0011 00xxB
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  :   Mia_Ini                                                     ³
;³DESCRIZIONE:   Predispone il controller HD 44780 per gestire il visualizza-³
;³               tore nel modo operativo desiderato, comunque con interfaccia³
;³               a 4 bit:                                                    ³
;³ Cancella Display  00000001 01H  Azzera la memoria DDRam (Clear Display)   ³
;³ Accesso Caratteri 000001IS 06H  #  I=1 (bit1) > autoincrem.indirizzo DDRam³
;³                                 #  S=0 (bit0) > display bloccato          ³
;³ Modo  del Display 00001DCB 0FH  #  D=1 (bit2) > display acceso            ³
;³                                 #  C=1 (bit1) > cursore visibile          ³
;³                                 #  B=1 (bit0) > a forma lampeggiante      ³
;³ Scorrimento Displ 0001SRxx 14H  # S/C=0(bit3) > si muove il cursore       ³
;³                                 # R/L=1(bit2) > verso destra              ³
;³ Parametri         001DNFxx 28H  #  DL=0(bit4) > interfaccia a 4 bit       ³
;³                                 #  N=1 (bit3) > visualizzatore a 2 linee  ³
;³                                 #  F=0 (bit2) > matrice carattere 5x7 pix ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Mia_Ini:                      ;¿Predispone le successive chiamate di Out_By8
        MOV     AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
                              ;¿Predispone l'interfaccia a 4 bit senza curarsi
                              ;³della forma del visualizzatore e della matrice
        MOV     AL,20H        ;³del carattere; il codice operativo pu• essere
        CALL    Out_By8       ;³dunque ambiguo su tutti i 4 bit meno si-
                              ;³gnificativi, cioŠ sar… del tipo 0010 xxxx
                              ;Ù20H=0010 00xxB  interfaccia a 4 bit
                              ;¿Fissa i dettagli dell'interfaccia a 4 bit (DL=
                              ;³bit4=0) cominciando da ora ad  usare  la  met…
        MOV     AL,28H        ;³alta del bus dati (cioŠ dando per scontato che
        CALL    Out_By4       ;³i bit da BD3 a DB0 non sono  pi— disponibili);
                              ;³si impone: visualizzatore a 2 linee (N=bit3=1)
                              ;³e matrice carattere con 5x7 pixel (F=bit2= 0);
                              ;Ùil codice operativo Š dunque 0010 10xx (=28H)
        MOV     AL,01H        ;¿Azzera la memoria DDRam (Clear Display ): il
        CALL    Out_By4       ;Ùcodice operativo necessario Š 0000 0001 (=01H)
                              ;¿Fissa il modo di gestire il display: con auto-
        MOV     AL,06H        ;³incremento dell'indirizzo DDRam e  del cursore
        CALL    Out_By4       ;³(I=bit1=1) e  con display bloccato (S=bit0=0);
                              ;Ùil codice operativo Š  dunque 0000 0110 (=06H)
                              ;¿Inizializza le caratteristiche del display per
        MOV     AL,0FH        ;³display  acceso (D=bit2=1),  cursore  visibile
        CALL    Out_By4       ;³(C=bit1=1) e  a forma lampeggiante (B=bit0=1);
                              ;Ùil codice operativo Š  dunque 0000 1111 (=0FH)
                              ;¿Inizializza lo scorrimento sul display:  fissa
        MOV     AL,14H        ;³il movimento del cursore (S/C=bit3=0) e  verso
        CALL    Out_By4       ;³destra  (R/L=bit2=1);  il  codice  operativo Š
                              ;Ùdunque 0001 01xx (=14H)
        MOV     AL,00H        ;¿Fissa il  cursore  nella  prima  posizione, in
        MOV     CS:[Posiz],AL ;³alto a sinistra, e istruisce il controller LCD
        OR      AL,80H        ;³puntando anche  la prima  locazione  della sua
        CALL    Out_By4       ;³memoria DDRam, di  indirizzo  xxxxxxx=0000000;
                              ;Ùl'istruzione Š del tipo 1xxxxxxx=10000000=80H
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : FissaAdd                                                      ³
;³DESCRIZIONE: Indirizza la locazione della DDRam (memoria Dati del Display) ³
;³             che corrispondente alla posizione di stampa corrente,  quella ³
;³             nella quale sar… visibile il cursore, sia  sul Visualizzatore ³
;³             LCD che in quello simulato a video; aggiorna anche il  valore ³
;³             contenuto nella variabile locale che memorizza la posizione.  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
FissaAdd:CALL   Cursore       ; Mostra il cursore sul Display a Video
                              ;¿Predispone la successiva chiamata di Out_By8
FissaAd_:MOV    AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
                              ;¿Annota la posizione corrente del cursore nella
        MOV     CS:[Posiz],AL ;³memoria DDRam e ricostruisce l'istruzione  per
        OR      AL,80H        ;³per il controller LCD, forzando (con la OR) il
        CALL    Out_By4       ;³bit7 a 1,  come  prevede  l'istruzione  a  ci•
                              ;³delegata; l'istruzione sar… del  tipo 1xxxxxxx
                              ;³da 80H (0,0) a A7H (0,39) sulla  prima  linea
        RET                   ;Ùda C0H (1,0) a E7H (1,39) sulla seconda linea

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Addr_LCD                                                      ³
;³DESCRIZIONE: Predispone l'indirizzo del carattere da visualizzare sull'LCD;³
;³             in pratica ci• significa  indirizzare  locazione  della  DDRam³
;³             (memoria Dati del Display) che corrispondente  alla  posizione³
;³             desiderata; poichŠ le locazioni sono 80, per indirizzarle sono³
;³             sufficienti 7 bit (2^7=128),  visto  che 6 (2^6=64)  non  sono³
;³             sufficienti.                                                  ³
;³             Dunque non tutte le 128 combinazioni sono necessarie          ³
;³             E' comunque chiaro che il controller HD44780  Š  in  grado  di³
;³             immagazzinare pi— caratteri di  quanti il visualizzatore possa³
;³             mostrare; per esempio, quelli ad 1 linea gestiscono fino  a 40³
;³             caratteri, per cui solo una met… [da 0 (00H) a 39 (27H)] delle³
;³             locazioni Š copiata sul display; la rimanente  met…  pu•  per•³
;³             essere fatta scorrere nelle medesime 40 posizioni del Display,³
;³             con le istruzioni descritte in precedenza...                  ³
;³             In conclusione:                                               ³
;³             1) con visualizzatori ad 1 linea (N=0) gli indirizzi possibili³
;³                vanno da 00H (=0, comando 80H)  a  4FH (=79, comando CFH)  ³
;³             2) con visualizzatori ad 2 linee (N=1) gli indirizzi:         ³
;³                della 1.ma vanno da 00H (=0,  add 80H) a 27H(= 39, add A7H)³
;³                della 2.da vanno da 40H (=64, add C0H) a 67H(=103, add E7H)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;         80H           8FH 90H                    A7Histruzione necessaria
;         00H           0FH 10H                    27Hindirizzo DDRam
;         ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;         ³± Visualizza16 ±³³±     Visualizza a 40  ±³ riga 13
;         ³ÄÄÄÄÄÄ16ÄÄÄÄÄÄ³³ÄÄÄÄÄÄÄÄÄ24ÄÄÄÄÄÄÄÄÄÄÄ³
;         ³± Visualizza16 ±³³±     Visualizza a 40  ±³ riga 14
;         ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;         40H           4FH 50H                    67Hindirizzo DDRam
;         C0H           CFH D0H                    E7Histruzione necessaria

Addr_LCD:MOV    AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        INC     AL            ; Incrementa l'indirizzo della locazione DDRam
        CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JE      Addr_L2              ;  00H   Limite a 40 caratteri
        ;----[Gestione a 40 caratteri]----------------------------------------
        CMP     AL,28H        ;¿Se la posizione Š in fondo alla prima linea si
        JE      Addr_L0       ;Ùforza il cursore a capo della linea successiva
        CMP     AL,68H        ;¿
        JNE     Addr_L1       ;³Se la posizione Š in fondo alla seconda  linea
        MOV     AL,00H        ;³si forza il cursore a capo  della  prima linea
        JMP     SHORT Addr_L1 ;Ù
                              ;¿Fissa l'indirizzo interno della memoria  DDRam
Addr_L0:MOV     AL,40H        ;³del controller LCD per puntare l'indirizzo 40H
                              ;³corrispondente alla posizione del primo carat-
                              ;Ùtere sulla seconda linea
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
Addr_L1:CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        RET                   ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;----[Gestione a 16 caratteri]----------------------------------------
Addr_L2:CMP     AL,10H        ;¿Se la posizione Š in fondo alla prima linea si
        JE      Addr_L0       ;Ùforza il cursore a capo della linea successiva
        CMP     AL,50H        ;¿
        JNE     Addr_L1       ;³Se la posizione Š in fondo alla seconda  linea
        MOV     AL,00H        ;³si forza il cursore a capo  della  prima linea
        JMP     SHORT Addr_L1 ;Ù

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_Invio                                                    ³
;³DESCRIZIONE: La pressione del tasto "Invio" sposta la posizione di  stampa ³
;³             per puntare il carattere all'inizio della seconda riga.       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_Invio:
        CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     DL,21         ; Prepara il puntatore Video a capo linea
        MOV     AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        MOV     DH,14         ;¿Prepara il puntatore Video sulla seconda linea
        MOV     AH,40H        ;³Prepara il puntatore DDRam a inizio 2.da linea
        CMP     AL,27H        ;³Se la posizione Š sulla prima linea  si  forza
        JBE     Serv_I        ;Ùil cursore a capo della seconda linea
                              ;¿Altrimenti (posizione sulla seconda linea)  si
                              ;³forza il cursore a capo della prima linea....
        MOV     DH,13         ;³Prepara il puntatore Video sulla prima linea
        MOV     AH,00H        ;ÙPrepara il puntatore DDRam a inizio 1.ma linea
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
Serv_I: MOV     AL,AH         ;³posizione  di  stampa  corrente, quella  nella
        CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
                              ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.
        JMP     Rientra

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_BkSp                                                     ³
;³DESCRIZIONE: La pressione  del  tasto "BackSpace"  sposta  la  posizione di³
;³             stampa  indietro di una posizione,  cancellando  il  carattere³
;³             anche nella memoria DDRam del controller LCD                  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;         00H           0FH 10H                    27Hindirizzo DDRam
;         ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;         ³± Visualizza16 ±³³±     Visualizza a 40  ±³ riga 13
;         ³ÄÄÄÄÄÄ16ÄÄÄÄÄÄ³³ÄÄÄÄÄÄÄÄÄ24ÄÄÄÄÄÄÄÄÄÄÄ³
;         ³± Visualizza16 ±³³±     Visualizza a 40  ±³ riga 14
;         ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;         40H           4FH 50H                    67Hindirizzo DDRam
Serv_BkSp:
        CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        DEC     AL            ; Decrementa l'indirizzo della locazione DDRam
        CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JE      Back__3              ;  00H   Limite a 40 caratteri

;----[Gestione a 40 caratteri]----------------------------------------
        CMP     AL,3FH        ;¿Se la posizione  Š  all'inizio  della  seconda
        JE      Back__0       ;Ùlinea si forza il cursore in fondo alla  prima

CMP     AL,0FFH       ;¿Se la posizione NON Š  all'inizio  della prima
        JNE     Back___       ;Ùlinea si arretra normalmente di un carattere
        MOV     DH,14         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DL,63         ;³interno della memoria DDRam del controller LCD
        MOV     AL,67H        ;³all'indirizzo 67H  per  puntare alla posizione
        JMP     SHORT Back__1 ;Ùdell'ultimo carattere sulla seconda linea
Back___:DEC     DL            ;¿
        CMP     DL,38         ;³Adatta la colonna di stampa ai 2  campi  del
        JNE     Back__2       ;³Visualizzatore a video, se necessario
        SUB     DL,2          ;³
        JMP     SHORT Back__2 ;Ù

Back__0:MOV     DH,13         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DL,63         ;³interno della memoria DDRam del controller LCD
        MOV     AL,27H        ;³all'indirizzo 27H  per  puntare alla posizione
                              ;Ùdell'ultimo carattere sulla prima linea
Back__1:DEC     DL            ;¿Se la posizione NON Š  all'inizio di una linea
                              ;Ùsi arretra normalmente di un carattere
Back__2:PUSH    AX            ;¿
        CALL    FissaAd_      ;³Cancella il carattere attualmente presente sui
        MOV     AL,' '        ;³2 Visualizzatori (quello a  Video  e l'LCD),
        CALL    RAMcur        ;³Il primo direttamente a Livello RamVideo  e il
        MOV     ES:[DI],AL    ;³secondo predisponendo la  chiamata  successiva
        MOV     AH,01H        ;³di Out_By4 per provvedere alla scrittura di un
        CALL    Out_By4       ;³carattere (cioŠ per a portare il segnale RS=1)
        POP     AX            ;Ùal fine di trasmettere lo spazio al controller
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
        CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;----[Gestione a 16 caratteri]----------------------------------------
Back__3:CMP     AL,3FH        ;¿Se la posizione  Š  all'inizio  della  seconda
        JNE     Back__4       ;Ùlinea si forza il cursore in fondo alla  prima

MOV     DL,37         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DH,13         ;³interno della memoria DDRam del controller LCD
        MOV     AL,0FH        ;³all'indirizzo 0FH  per  puntare alla posizione
        JMP     SHORT Back__1 ;Ùdell'ultimo carattere sulla prima linea

Back__4:CMP     AL,0FFH       ;¿Se la posizione NON Š  all'inizio  della prima
        JNE     Back__1       ;Ùlinea si arretra normalmente di un carattere

MOV     DL,37         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DH,14         ;³interno della memoria DDRam del controller LCD
        MOV     AL,4FH        ;³all'indirizzo 4FH  per  puntare alla posizione
        JMP     SHORT Back__1 ;Ùdell'ultimo carattere sulla seconda linea

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_F1                                                       ³
;³DESCRIZIONE: Commuta il controllo  da 16 a 40 caratteri per riga           ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_F1:CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JNE     Srv_F1                ;  00H   Limite a 40 caratteri

MOV Byte Ptr CS:[Limite],00H ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CALL    Displ40              ;³ 00H   Visualizzatore a 40 caratteri ³
        JMP     SHORT Srv_F_         ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

Srv_F1: MOV Byte Ptr CS:[Limite],0FFH;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CALL    Displ16              ;³ 0FFH  Visualizzatore a 16 caratteri ³
        JMP     SHORT Srv_F_         ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_F2                                                       ³
;³DESCRIZIONE: Cancella i caratteri nel Display a Video e fissa il cursore e ³
;³             anche quelli sul Visualizzatore LCD                           ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_F2:CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JE      Srv_F2               ;  00H   Limite a 40 caratteri
                                     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CALL    Displ40              ;³ 00H   Visualizzatore a 40 caratteri ³
        JMP     SHORT Srv_F_         ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                                     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Srv_F2: CALL    Displ16              ;³ 0FFH  Visualizzatore a 16 caratteri ³
                                     ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Srv_F_: PUSH    AX            ;¿Predispone la successiva chiamata di Out_By8
        MOV     AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
        MOV     AL,01H        ;¿Azzera la memoria DDRam (Clear Display ): il
        CALL    Out_By4       ;Ùcodice operativo necessario Š 0000 0001 (=01H)
        MOV     CS:[Posiz],AH ;¿Fissa il  cursore  nella  prima  posizione, in
        POP     AX            ;Ùalto a sinistra, e istruisce il controller LCD
        JMP     Rientra

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_Chr                                                      ³
;³DESCRIZIONE: Servizio per la pressione  di  un  qualunque  tasto  Ascii; il³
;³             corrispondente  carattere,  trovato in  ingresso in  AL, viene³
;³             posto a  video  nel  campo  del  Visualizzatore e trasmesso al³
;³             controller LCD; la posizione di  stampa  viene  aggiornata per³
;³             puntare la posizione del carattere successivo, in funzione del³
;³             tipo di Visualizzatore, attualmemente in uso.                 ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_Chr:PUSH   AX
        M_Chr   AL,DH,DL,2AH  ; Stampa il carattere sul Display a Video
        INC     DL            ; Incrementa la colonna
        CMP     DL,63         ;¿Nel caso di Gestione a 40 caratteri  si  forza
        JE      Serv_C0       ;Ùil cursore a capo linea
        CMP     DL,37         ;¿Con Gestione a 40 caratteri (Limite=00H)
        JNE     Serv_C1       ;Ùsi forza il cursore a capo linea

CMP Byte Ptr CS:[Limite],00H;¿
        JNE     Serv_C0       ;³Con Gestione a 40 caratteri
        MOV     DL,39         ;³si forza il cursore nel secondo campo
        JMP     SHORT Serv_C1 ;Ù
Serv_C0:MOV     DL,21         ;¿Con Gestione a 16 caratteri
        INC     DH            ;³Fissa  il  cursore  a  capo  dell'altra  linea
        CMP     DH,15         ;³(rileva  automaticamente se  quella  superiore
        JNZ     Serv_C1       ;³o se quella inferiore)
        MOV     DH,13         ;Ù
Serv_C1:POP     AX
                              ;¿Predispone la  successiva  chiamata di Out_By8
        MOV     AH,01H        ;³per provvedere alla scrittura  di un carattere
                              ;ÙcioŠ a portare il segnale RS=1, carattere
        CALL    Out_By4       ;¿Trasmette al controller LCD il carattere in AL
        CALL    Addr_LCD      ;³(RS=1) e aggiorna la posizione del cursore per
                              ;Ùpuntare il carattere successivo
        JMP     Rientra

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_Sn                                                       ³
;³DESCRIZIONE: La pressione  della Freccia a Sinistra sposta la  posizione di³
;³             stampa  indietro di una posizione                             ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_Sn:CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        DEC     AL            ; Decrementa l'indirizzo della locazione DDRam
        CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JE      FrSn__3              ;  00H   Limite a 40 caratteri

;----[Gestione a 40 caratteri]----------------------------------------
        CMP     AL,3FH        ;¿Se la posizione  Š  all'inizio  della  seconda
        JE      FrSn__0       ;Ùlinea si forza il cursore in fondo alla  prima

CMP     AL,0FFH       ;¿Se la posizione NON Š  all'inizio  della prima
        JNE     FrSn___       ;Ùlinea si arretra normalmente di un carattere
        MOV     DH,14         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DL,63         ;³interno della memoria DDRam del controller LCD
        MOV     AL,67H        ;³all'indirizzo 67H  per  puntare alla posizione
        JMP     SHORT FrSn__1 ;Ùdell'ultimo carattere sulla seconda linea
FrSn___:DEC     DL            ;¿
        CMP     DL,38         ;³Adatta la colonna di stampa ai 2  campi  del
        JNE     FrSn__2       ;³Visualizzatore a video, se necessario
        SUB     DL,2          ;³
        JMP     SHORT FrSn__2 ;Ù

FrSn__0:MOV     DH,13         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DL,63         ;³interno della memoria DDRam del controller LCD
        MOV     AL,27H        ;³all'indirizzo 27H  per  puntare alla posizione
                              ;Ùdell'ultimo carattere sulla prima linea
FrSn__1:DEC     DL            ;¿Se la posizione NON Š  all'inizio di una linea
                              ;Ùsi arretra normalmente di un carattere
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
FrSn__2:CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;----[Gestione a 16 caratteri]----------------------------------------
FrSn__3:CMP     AL,3FH        ;¿Se la posizione  Š  all'inizio  della  seconda
        JNE     FrSn__4       ;Ùlinea si forza il cursore in fondo alla  prima

FrSn__4:CMP     AL,0FFH       ;¿Se la posizione NON Š  all'inizio  della prima
        JNE     FrSn__1       ;Ùlinea si arretra normalmente di un carattere

MOV     DL,37         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DH,14         ;³interno della memoria DDRam del controller LCD
        MOV     AL,4FH        ;³all'indirizzo 4FH  per  puntare alla posizione
        JMP     SHORT FrSn__1 ;Ùdell'ultimo carattere sulla seconda linea

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_Dx                                                       ³
;³DESCRIZIONE: La pressione  della Freccia  a  Destra sposta la  posizione di³
;³             stampa  in avanti di una posizione                            ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_Dx:CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        INC     AL            ; Decrementa l'indirizzo della locazione DDRam
        CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JE      FrDx__3              ;  00H   Limite a 40 caratteri

;----[Gestione a 40 caratteri]----------------------------------------
        CMP     AL,68H        ;¿Se la posizione  Š  alla fine   della  seconda
        JE      FrDx__0       ;Ùlinea si forza il cursore in cima alla prima

CMP     AL,28H        ;¿Se la posizione NON Š  alla fine   della prima
        JNE     FrDx___       ;Ùlinea si avanza  normalmente di un carattere
        MOV     DH,14         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DL,20         ;³interno della memoria DDRam del controller LCD
        MOV     AL,40H        ;³all'indirizzo 40H  per  puntare alla posizione
        JMP     SHORT FrDx__1 ;Ùdel primo carattere sulla seconda linea
FrDx___:INC     DL            ;¿
        CMP     DL,37         ;³Adatta la colonna di stampa ai 2  campi  del
        JNE     FrDx__2       ;³Visualizzatore a video, se necessario
        ADD     DL,2          ;³
        JMP     SHORT FrDx__2 ;Ù

FrDx__0:MOV     DH,13         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DL,20         ;³interno della memoria DDRam del controller LCD
        MOV     AL,00H        ;³all'indirizzo 00H  per  puntare alla posizione
                              ;Ùdel primo carattere sulla prima linea
FrDx__1:INC     DL            ;¿Se la posizione NON Š  all'inizio di una linea
                              ;Ùsi avanza normalmente di un carattere
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
FrDx__2:CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;----[Gestione a 16 caratteri]----------------------------------------
FrDx__3:CMP     AL,50H        ;¿Se la posizione  Š  alla fine   della  seconda
        JNE     FrDx__4       ;Ùlinea si forza il cursore in cima alla  prima

MOV     DL,20         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DH,13         ;³interno della memoria DDRam del controller LCD
        MOV     AL,00H        ;³all'indirizzo 00H  per  puntare alla posizione
        JMP     SHORT FrDx__1 ;Ùdel primo carattere sulla prima linea

FrDx__4:CMP     AL,10H        ;¿Se la posizione NON Š  all'inizio  della prima
        JNE     FrDx__1       ;Ùlinea si avanza normalmente di un carattere

MOV     DL,20         ;¿Prepara  il  puntatore  Video  e   l'indirizzo
        MOV     DH,14         ;³interno della memoria DDRam del controller LCD
        MOV     AL,40H        ;³all'indirizzo 40H  per  puntare alla posizione
        JMP     SHORT FrDx__1 ;Ùdel primo carattere sulla seconda linea

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_Up                                                       ³
;³DESCRIZIONE: La pressione della Freccia  in  Alto   sposta  la posizione di³
;³             stampa sulla  stessa colonna  nella  riga superiore; se gi… si³
;³             trova in posizione superiore l'azione del tasto non ha effetto³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_Up:MOV     AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        CMP     AL,40H        ;¿Se la posizione Š sulla prima  linea  l'azione
        JB      FrUp__1       ;Ùdella pressione del tasto non ha effetto

CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     DH,13         ;¿
        MOV     DL,21         ;³Se la posizione Š sulla seconda linea forza il
        SUB     AL,40H        ;³cursore nella stessa colonna della linea sopra
        ADD     DL,AL         ;Ù

FrUp_Dn:CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JE      FrUp__0              ;  00H   Limite a 40 caratteri
        ADD     DL,2          ;Nella Gestione a 40 caratteri saltiamo le cornici

;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
FrUp__0:CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
FrUp__1:JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Serv_Dn                                                       ³
;³DESCRIZIONE: La pressione della Freccia  in  Basso  sposta  la posizione di³
;³             stampa sulla  stessa colonna  nella  riga inferiore; se gi… si³
;³             trova in posizione inferiore l'azione del tasto non ha effetto³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_Dn:MOV     AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        CMP     AL,40H        ;¿Se la posizione Š sulla seconda linea l'azione
        JGE     FrUp__1       ;Ùdella pressione del tasto non ha effetto

CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     DH,14         ;¿
        MOV     DL,21         ;³Se la posizione Š sulla  prima  linea forza il
        ADD     DL,AL         ;³cursore nella stessa colonna della linea sotto
        ADD     AL,40H        ;Ù
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
        JMP     SHORT FrUp_Dn ;³quale  sar…  visibile  il  cursore,  sia   sul
                              ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : PgUp                                                          ³
;³DESCRIZIONE: La pressione di PgUp sposta la posizione di stampa nell'angolo³
;³             in alto a destra, sulla riga superiore.                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_PU:CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     DH,13         ; Prepara il puntatore Video sulla linea in alto
        CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JNE     PgUp__0              ;  00H   Limite a 40 caratteri

MOV     DL,36         ;¿Prepara il  puntatore  Video  sul carattere in
        MOV     AL,0FH        ;³alto a destra, sulla   prima   linea;  prepara
        JMP     SHORT PgUp__1 ;Ùanche il puntatore DDRam  nello  stesso  punto

PgUp__0:MOV     DL,62         ;¿Prepara il  puntatore  Video  sul carattere in
        MOV     AL,27H        ;³alto a  destra,  sulla  prima  linea;  prepara
                              ;Ùanche il puntatore DDRam  nello  stesso  punto
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
PgUp__1:CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : PgDn                                                          ³
;³DESCRIZIONE: La pressione di PgDn sposta la posizione di stampa nell'angolo³
;³             in basso a destra, sulla riga inferiore.                      ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_PD:CALL    Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     DH,14         ; Prepara il puntatore Video sulla linea in basso
        CMP Byte Ptr CS:[Limite],0FFH;  FFH   Limite a 16 caratteri
        JNE     PgDn__0              ;  00H   Limite a 40 caratteri

MOV     DL,36         ;¿Prepara il  puntatore  Video  sul carattere in
        MOV     AL,4FH        ;³basso a  destra,  sulla seconda linea; prepara
        JMP     SHORT PgDn__1 ;Ùanche il puntatore DDRam  nello  stesso  punto

PgDn__0:MOV     DL,62         ;¿Prepara il  puntatore  Video  sul carattere in
        MOV     AL,67H        ;³basso a  destra,  sulla seconda linea; prepara
                              ;Ùanche il puntatore DDRam  nello  stesso  punto
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
PgDn__1:CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Home                                                          ³
;³DESCRIZIONE: La pressione di PgUp sposta la posizione di stampa nell'angolo³
;³             in alto a sinistra, sulla riga superiore.                     ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_Hom:CALL   Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     DH,13         ;¿Prepara il  puntatore  Video  sul carattere in
        MOV     DL,21         ;³alto a sinistra, sulla  prima  linea;  prepara
        MOV     AL,00H        ;Ùanche il puntatore DDRam  nello  stesso  punto
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
        CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : End                                                           ³
;³DESCRIZIONE: La pressione di PgDn sposta la posizione di stampa nell'angolo³
;³             in basso a sinistra, sulla riga inferiore.                    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Serv_End:CALL   Old_Chr       ;¿Annulla  la  visualizzazione  del  cursore nel
                              ;Ùpunto previsito per la stampa corrente
        MOV     DH,14         ;¿Prepara il  puntatore  Video  sul carattere in
        MOV     DL,21         ;³basso a sinistra, sulla seconda linea; prepara
        MOV     AL,40H        ;Ùanche il puntatore DDRam  nello  stesso  punto
                              ;¿Indirizza  la  locazione  della DDRam (memoria
                              ;³Dati  del  Display)  che  corrispondente  alla
                              ;³posizione  di  stampa  corrente, quella  nella
        CALL    FissaAdd      ;³quale  sar…  visibile  il  cursore,  sia   sul
        JMP     Rientra       ;³Visualizzatore LCD  che in  quello simulato  a
                              ;³video;aggiorna anche il valore contenuto nella
                              ;Ùvariabile locale che memorizza la posizione.

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
EditLCD1 proc   NEAR          ;³      AREA DEDICATA AL MAIN PROGRAM         ³³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
 MOV Byte Ptr CS:[Limite],0FFH;FFH   Limite a 16 caratteri
                              ;00H   Limite a 40 caratteri

CALL    DESKTOP       ;Inizializza completamente il piano  di  lavoro
                              ;¿Inizializza il controller HD 44780, simulando
                              ;³l'attivazione della linea di RESET;  vengono
        CALL    Pre_Ini       ;³erogati 3 bytes a 30H separati da piccoli
                              ;³ritardi "pesati"; per default viene predisposta
                              ;Ùl'interfaccia a 8 bit
                              ;¿Predispone il controller HD 44780 per gestire
                              ;³il visualizzatore nel modo operativo desiderato
        CALL    Mia_Ini       ;³interfaccia a 4 bit, visualizzatore a 2 linee,
                              ;³matrice del carattere con 5x7 pixel, display
                              ;³acceso, cursore visibile a forma lampeggiante,
                              ;³azzeramento della memoria DDRam, autoincremento
                              ;Ùdell'indirizzo, display bloccato

Rientra:CALL    KEYwait       ;Aspetta decisioni

CMP     AL,00H        ;¿Si tratta di tasto Funzionale...
        JE      KeyFunz       ;ÙVa servito a parte
        CMP     AL,Invio      ;¿
        JNE     Rein_0        ;³Servizio per la pressione di <Invio>
        JMP     Serv_Invio    ;Ù
Rein_0: CMP     AL,BackSp     ;¿
        JNE     Rein_1        ;³Servizio per la pressione di <BackSpace>
        JMP     Serv_BkSp     ;Ù
Rein_1: CMP     AL,ESC_       ;¿Servizio per la pressione di <Spazio>
        JE      OUT_          ;Ù
                              ;¿Servizio per la pressione di un  comune  tasto
        JMP     Serv_Chr      ;³Ascii: il carattere corrispondente viene posto
                              ;Ùa video e trasmesso al visualizzatore
KeyFunz:CMP     AH,F1_        ;¿
        JNE     KeyFun0       ;³Servizio per la pressione di <F1>
        JMP     Serv_F1       ;Ù
KeyFun0:CMP     AH,F2_        ;¿
        JNE     KeyFun1       ;³Servizio per la pressione di <F2>
        JMP     Serv_F2       ;Ù
KeyFun1:CMP     AH,Frec_Su    ;¿
        JNE     KeyFun2       ;³Servizio Scorrimento cursore: Freccia 
        JMP     Serv_Up       ;Ù
KeyFun2:CMP     AH,Frec_Giu   ;¿
        JNE     KeyFuntre       ;³Servizio Scorrimento cursore: Freccia 
        JMP     Serv_Dn       ;Ù
KeyFuntre:CMP     AH,Frec_Dx    ;¿
        JNE     KeyFun4       ;³Servizio Scorrimento cursore: Freccia 
        JMP     Serv_Dx       ;Ù
KeyFun4:CMP     AH,Frec_Sn    ;¿
        JNE     KeyFun5       ;³Servizio Scorrimento cursore: Freccia 
        JMP     Serv_Sn       ;Ù
KeyFun5:CMP     AH,End_Fine   ;¿
        JNE     KeyFun6       ;³Servizio Scorrimento cursore: End (=Fine)
        JMP     Serv_End      ;Ù
KeyFun6:CMP     AH,Home       ;¿
        JNE     KeyFun7       ;³Servizio Scorrimento cursore: Home
        JMP     Serv_Hom      ;Ù
KeyFun7:CMP     AH,PgDn       ;¿
        JNE     KeyFun8       ;³Servizio Scorrimento cursore: PgDn
        JMP     Serv_PD       ;Ù
KeyFun8:CMP     AH,PgUp       ;¿
        JNE     Rientra       ;³Servizio Scorrimento cursore: PgUp
        JMP     Serv_PU       ;Ù
                              ;¿Predispone le  successive  chiamate di Out_By8
OUT_:   MOV     AH,00H        ;³per provvedere  alla scrittura  di  un comando
                              ;ÙcioŠ  a  portare  il segnale RS=0, istruzione.
        MOV     AL,01H        ;¿Azzera la  memoria  DDRam (Clear Display ): il
        CALL    Out_By4       ;Ùcodice operativo necessario Š 0000 0001 (=01H)
                              ;¿Inizializza le caratteristiche del display per
        MOV     AL,08H        ;³display  spento (D=bit2=0), cursore invisibile
        CALL    Out_By4       ;³(C=bit1=0) e  a forma a trattino   (B=bit0=0);
                              ;Ùil codice operativo Š  dunque 0000 1000 (=08H)

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
_OUT:   PUSH    AX            ;³Torna al DOS con la memoria liberata e con la³
        CALL    RIP_cur       ;³chiusura di tutti i file; cede  il  controllo³
        MOV     DH,23         ;³al processo padre (generalmente COMMAND.COM);³
        MOV     DL,0          ;³il valore posto eventualmente  in AL prima di³
        CALL    SET_cur       ;³uscire pu• essere testato in  uscita  con  la³
        POP     AX            ;³funzione 4DH o mediante la lettura della  va-³
        MOV     AH,4CH        ;³riabile DOS "ERRORLEVEL"                     ³
        INT     21H           ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
EditLCD1 ENDP                 ;³Chiusura standard del codice                 ³
_prog   ENDS                  ;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        END INIZIO            ;³Chiusura del segmento di codice e conclusione³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

La lettura può essere operata anche in Ambiente Assembler (disponibile sul Sito accedendo a questa pagina); se hai già provveduto alla sua installazione scarica il sorgente del progetto direttamente nella cartella C:\Arch-Lab\Lavoro (scegliendo il pulsante di opzione "Salva" e, come destinazione, seleziona la cartella che ti ho appena suggerito).

Ricorda: se fai click sull'icona a sinistra si apre l'Ambiente Assembly e puoi entrare in Ambiente on-line.
Scegli il pulsante di opzione "Aprire il file" o "Esegui l'applicazione" e conferma con OK.
NB: alcuni gestori di protezione (per esempio SP2 di WinXP) non ti consentono questa operazione:
in questo caso scrivi c:\arch-lab\bin\sys\assembler.pif direttamente nel campo indirizzo del Browser

Nella shell DOS aperta (o a pieno schermo) puoi iniziare una sessione di lavoro digitando MACRO EditLcd1 /e (con gli spazi al posto giusto !!) e conferma con Invio.

	Display LCD			PROGETTO nÂ° 03 - 3/11
	39 di 65

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65

Display LCD »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default