HD44780 Visualizzatore LCD ["Dentro il Computer" di Giobe®2000]

		Tecnologia dei Cristalli Liquidi Controller/Driver HD44780-HW Controller/Driver HD44780-SW Connettore Modulo LCD Interfaccia Parallela LPT1 Applicazioni Software Progetti Hardware Download INDICE
Display LCD

Applicazioni Software

PROGETTO nÂ° 01 - 10/13 [27 di 65]

Analisi del Problema · Analisi del Codice · Procedure importanti · Schema interfaccia · Descrizione dello schema

Modulo LCD su parallela LPT1 - Gestione di 2 linee, 16 chr/linea - Controller/Driver HD44780

Analisi delle procedure importanti [6 di 7]

Scrittura del Dato nella memoria del controller

L'ultima procedura importante del progetto si occupa di scrivere il carattere sul visualizzatore del Modulo LCD e di farne eco sul monitor.

Per questo si avvale della Procedura Sta_chr che:

	pone a video il carattere nella posizione di stampa corrente
	aggiorna la posizione di stampa successiva, mantenendola nei limiti del riquadro previsto
	con l'istruzione MOV AH,01H conferma alla Out_By4 la necessità di trattare il byte da scrivere come dato (RS=1)
	trasmette il carattere (CALL Out_By4) anche al controller HD44780 del Modulo LCD
	aggiorna la posizione (indirizzo) di scrittura in memoria DDram, con l'aiuto della SottoProcedura Addr_LCD (che vediamo sotto):

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³SERVIZIO   : Sta_Chr                                                       ³
;³DESCRIZIONE: Servizio per visualizzazione del carattere passato in ingresso³
;³             in AL; esso Š posto a video nella posizione di stampa corrente³
;³             sul Visualizzatore e trasmesso al controller LCD; la posizione³
;³             di stampa viene aggiornata per puntare a quella del  carattere³
;³             successivo.                                                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Sta_Chr:PUSH    AX
        M_Chr   AL,DH,DL,2AH  ; Stampa il carattere sul Display a Video
        INC     DL            ; Incrementa la colonna
        CMP     DL,49         ;¿se NON si supera l'ultima  colonna della  riga
        JNE     Serv_C1       ;³video corrente  si  prosegue  stampando  sulla
                              ;Ùstessa riga corrente
        MOV     DL,33         ;¿Altrimenti si forza il cursore  a  capo  della
        INC     DH            ;³linea opposta a quella che si sta lasciando..
        CMP     DH,15         ;³(rileva  automaticamente se  quella  superiore
        JNZ     Serv_C1       ;³o se quella inferiore)
        MOV     DH,13         ;Ù

Serv_C1:POP     AX            ;¿Predispone la  successiva  chiamata di Out_By4
        MOV     AH,01H        ;³per provvedere alla scrittura  di un carattere
                              ;ÙcioŠ a portare il segnale RS=1, carattere
        CALL    Out_By4       ;¿Trasmette al controller LCD il carattere in AL
        CALL    Addr_LCD      ;³(RS=1) e aggiorna la posizione del cursore per
        RET                   ;Ùpuntare il carattere successivo

	La SottoProcedura Addr_LCD ha un compito semplice ma fondamentale; sulla base del valore corrente della variabile locale [Posiz], calcola il nuovo indirizzo DDram (memoria Dati del Display) e ricostruisce da esso l'istruzione per forzare la scrittura proprio in quella locazione del controller.
	La logica che governa il calcolo deriva dal fatto che (come descritto in questa pagina) l'indirizzo di un carattere in DDRam varia in funzione della dimensione del visualizzatore presente sul Modulo, o più precisamente in funzione del loro numero di linee e del numero di caratteri per linea:

Linee & Caratteri	Posizione carattere	Indirizzo in DDRam
Linee & Caratteri	Posizione carattere	sulla linea 0	sulla linea 1
2 x 16	00 a 15	da 00H a 0FH	da 40H a 4FH
2 x 20	00 a 19	da 00H a 13H	da 40H a 53H
2 x 24	00 a 23	da 00H a 17H	da 40H a 57H
2 x 32	00 a 31	da 00H a 1FH	da 40H a 5FH
2 x 40	00 a 39	da 00H a 27H	da 40H a 67H

	Per assicurare la circolarità della scrittura, cioè per passare a capo linea al termine della riga di stampa corrente è necessario tener presente i valori finali (funzione del numero di caratteri per linea), sapendo che l'indirizzo iniziale è sempre 00H (sulla prima linea) o 40H(sulla seconda linea).
	Inoltre, in ogni caso, il codice operativo dell''istruzione necessaria per forzare la posizione corrente del cursore nel Contatore di indirizzo (AC, Address Counter): è sempre uguale a quella dell'indirizzo con bit7 a 1, cioè per esempio con 40 caratteri per linea, da 80H a A7H sulla prima linea e da C0H a E7H sulla seconda linea.

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Addr_LCD                                                      ³
;³DESCRIZIONE: Predispone l'indirizzo del carattere da visualizzare sull'LCD;³
;³             in pratica ci• significa  indirizzare  locazione  della  DDRam³
;³             (memoria Dati del Display) che corrispondente  alla  posizione³
;³             desiderata; poichŠ le locazioni sono 80, per indirizzarle sono³
;³             sufficienti 7 bit (2^7=128),  visto  che 6 (2^6=64)  non  sono³
;³             sufficienti.                                                  ³
;³             Dunque non tutte le 128 combinazioni sono necessarie          ³
;³             E' comunque chiaro che il controller HD44780  Š  in  grado  di³
;³             immagazzinare pi— caratteri di  quanti il visualizzatore possa³
;³             mostrare; per esempio, quelli ad 1 linea gestiscono fino  a 40³
;³             caratteri, per cui solo una met… [da 0 (00H) a 39 (27H)] delle³
;³             locazioni Š copiata sul display; la rimanente  met…  pu•  per•³
;³             essere fatta scorrere nelle medesime 40 posizioni del Display,³
;³             con le istruzioni descritte in precedenza...                  ³
;³             In conclusione:                                               ³
;³             1) con visualizzatori ad 1 linea (N=0) gli indirizzi possibili³
;³                vanno da 00H (=0, comando 80H)  a  4FH (=79, comando CFH)  ³
;³             2) con visualizzatori ad 2 linee (N=1) gli indirizzi:         ³
;³                della 1.ma vanno da 00H (=0,  add 80H) a 27H(= 39, add A7H)³
;³                della 2.da vanno da 40H (=64, add C0H) a 67H(=103, add E7H)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Addr_LCD:MOV    AL,CS:[Posiz] ; Assume il valore corrente dell'indirizzo DDRam
        INC     AL            ; Incrementa l'indirizzo della locazione DDRam
        CMP     AL,10H        ;¿Se la posizione Š in fondo alla prima linea si
        JE      Addr_L0       ;Ùforza il cursore a capo della linea successiva
        CMP     AL,50H        ;¿
        JNE     Addr_L1       ;³Se la posizione Š in fondo alla seconda  linea
        MOV     AL,00H        ;³si forza il cursore a capo  della  prima linea
        JMP     SHORT Addr_L1 ;³
                              ;Ù
                              ;¿Fissa l'indirizzo interno della memoria  DDRam
Addr_L0:MOV     AL,40H        ;³del controller LCD per puntare l'indirizzo 40H
                              ;³corrispondente alla posizione del primo carat-
                              ;Ùtere sulla seconda linea
                              ;¿Predispone la successiva chiamata di Out_By8
Addr_L1: MOV    AH,00H        ;³per provvedere alla scrittura di un comando
                              ;ÙcioŠ a portare il segnale RS=0, istruzione.
                              ;¿Annota la posizione corrente del cursore nella
Addr_L2:MOV     CS:[Posiz],AL ;³memoria DDRam e ricostruisce l'istruzione  per
        OR      AL,80H        ;³per il controller LCD, forzando (con la OR) il
        CALL    Out_By4       ;³bit7 a 1,  come  prevede  l'istruzione  a  ci•
        RET                   ;³delegata; l'istruzione sar… del  tipo 1xxxxxxx
                              ;³da 80H (0,0) a A7H (0,39) sulla  prima  linea
                              ;Ùda C0H (1,0) a E7H (1,39) sulla seconda linea

	Display LCD			PROGETTO nÂ° 01 - 10/13
	27 di 65

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65

Display LCD »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default