CambiaCol - Gestisce automaticamente i sistema di visualizzazione imponendo colori adatti - Giobe®2000

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Libreria GIOBE.ASM

Home » Programma il Computer » Tutorial Assembly

Raccolta di Procedure ASM

CambiaCol [50 di 54]

Adatta il colore in funzione della Scheda Grafica e del Monitor disponibili sul Computer.

	La Procedura è chiamata automaticamente ogni volta che si utilizza la Macro M_COLOR per dare colore a testi o caratteri; essa interviene sul valore (appunto il byte d'attributo) predisposto nella variabile locale, detta ATTRIB e definita dal programma che utilizza questa struttura.
	Questo intervento rende utilizzabili i nostri eseguibili su qualunque Sistema di Visualizzazione, come su alcuni vetusti portatili VGA a scala di grigi che, non potendoli interpretare a colori, possono talvolta rendere difficile la leggibilità del contenuto delle pagine proposte a video.

La seguente Area di Testo mostra il Modulo ram07 utilizzato per inserire la Procedura nella Libreria Giobe.ASM/LIB:

CambiaCol / ram07

NB: se il testo contenuto nell'Area ti sembra strano (cioè se contiene
caratteri inconsueti) non hai ancora installato il font Giobe.TTF : clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : CambiaCol.ASM                                                 ³
;³MODULO     : RAM07    (LIBRERIA C:\ARCH-LAB\BIN\GIOBE.LIB)                 ³
;³AUTORE     : Giorgio OBER                                                  ³
;³VERSIONE   : ottobre 1995                                                  ³
;³AGGIORNAMEN: gennaio  2003                                                 ³
;³DESCRIZIONE: Adatta il codice d'ATTRIBUTO fornito in ingresso nella  varia-³
;³             bile CS:[ATTRIB] (NON presente nella LIBRERIA GIOBE e di norma³
;³             definita nei programmi UTENTE e da essi dichiarata PUBLIC)  in³
;³             funzione della Scheda Grafica e del  Monitor  disponibili  sul³
;³             Computer; la decisione viene presa a partire dal valore  delle³
;³             variabili CS:[Scheda] e CS:[MODOcrt] (entrambe presenti in LI-³
;³             BRERIA GIOBE, definite dalla Procedura MODEtest (MODULO Ram08)³
;³             e da essa dichiarate PUBLIC).                                 ³
;³                                                                           ³
;³             Se la scheda NON Š monocromatica, MDA/HGC (cioŠ se  il  valore³
;³             di CS:[Scheda] Š maggiore di 03H) l'Attributo di colore  viene³
;³             lasciato INALTERATO (cos che questa procedura non produce ef-³
;³             fetto); in caso contrario (ma anche se si stanno usando  Moni-³
;³             tor VGA/EGA monocromatici, cioŠ se il valore di CS:[MODOcrt] Š³
;³             uguale a 00H) se l'Attributo di colore aveva sfondo NERO verr…³
;³             comunque sostituito dal codice 07H, corrispondente a BIANCO su³
;³             NERO; se invece l'Attributo di colore aveva un qualunque altro³
;³             sfondo, NON NERO, verr… sostituito  dal  codice  70H,  NERO su³
;³             BIANCO; in ogni caso vengono mantenute le caratteristiche  as-³
;³             sicurate dai 2 bit di LAMPEGGIO (FLASH) e ALTA INTENSITA`.  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    ATTRIB:BYTE
        EXTRN   ModoCrt:BYTE
        EXTRN    Scheda:BYTE
        PUBLIC  CambiaCol
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog
CambiaCol proc  NEAR
                              ;¿*******************ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Se la scheda NON Š ³06=Adattatore VGA        ³
                              ;³MONOCROMATICA   si ³05=Adattatore MCGA       ³
  CMP Byte Ptr CS:[Scheda],03H;³lascia  inalterato ³04=Adattatore EGA        ³
        JNC     Camb03        ;³il COLORE ricevuto ³03=Adattatore CGA        ³
                              ;³in ingresso  nella ³02=Adattatore MDA        ³
                              ;³variabile [ATTRIB] ³01=Adattatore HGC/HGC+   ³
                              ;Ù*******************ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Camb00: PUSH    AX            ;¿Si prepara in AH il codice  binario  f000b000
        MOV     AH,CS:[ATTRIB];³con evidenziati i soli bit di LAMPEGGIO e  di
        MOV     AL,AH         ;³ALTA INTENSITA` (BRIGHT) a partire dal valore
        AND     AH,88H        ;Ùfornito in ingresso in [ATTRIB]= AL =fxxxbyyy
        TEST    AL,70H        ;¿Si controlla se il codice colore in [ATTRIB] Š
        JZ      Camb01        ;Ùrelativo a colori con SFONDO NERO
        MOV     AL,70H        ;¿Se il codice colore Š  relativo  ad  Attributi
        AND     AH,80H        ;³con SFONDO NON NERO lo si  trasforma  comunque
        OR      AH,AL         ;³in INVERSE VIDEO (NERO su SFONDO BIANCO), man-
        JMP     SHORT Camb02  ;³tenendo la sola  eventuale  caratteristica  di
                              ;ÙLAMPEGGIO
Camb01: MOV     AL,07H        ;¿Se il codice colore Š  relativo  ad  Attributi
        OR      AH,AL         ;³con SFONDO NERO  qualunque sia  il  colore  di
Camb02: MOV     CS:[ATTRIB],AH;³Primo Piano lo si trasforma in BIANCO su NERO,
        POP     AX            ;³mantenendo inalterate  entrambe  le  eventuali
                              ;³caratteristiche   di   LAMPEGGIO  e   di  ALTA
                              ;ÙINTENSITA` (BRIGHT)
Camb03:                       ;¿Se il Monitor  NON ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Š MONOCROMATICO si ³                         ³
 CMP Byte Ptr CS:[MODOcrt],01H;³lascia  inalterato ³01=Monitor a colori      ³
        JNZ     Camb00        ;³il COLORE ricevuto ³00=Monitor monocromatico ³
        RET                   ;³in ingresso  nella ³                         ³
                              ;Ùvariabile [ATTRIB] ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
CambiaCol ENDP
_prog   ENDS
        END

	In condizioni standard (cioè con i moderni sistemi a colori basati su schede VGA) l'azione sulla variabile locale ATTRIB viene evitata e l'immagine proposta a video sarà quella predisposta dal programmatore, in accordo con il valore del *byte* (*attributo di colore) in essa predisposto con la Macro* M_COLOR.
	Ricordo che questo byte è strutturato in modo da rappresentare contemporaneamente il colore di primo piano (quello dei pixel che formano il carattere) e il colore dello sfondo (quello dei pixel rimanenti), sulla base dello schema descritto in questa pagina e in sintonia con gli accoppiamenti di colore descritti nelle figure dei Colori senza Flash e Colori con Flash.

Negli altri casi:

	se l'*attributo di colore* aveva sfondo nero verrà comunque sostituito dal codice 07H, corrispondente a bianco su nero
	se l'*attributo di colore* aveva qualunque altro sfondo verrà sostituito dal codice 70H, corrispondente a nero su bianco
	in ogni caso vengono mantenute le caratteristiche di lampeggio (flash) e alta intensità.

Non va dimenticato che, comunque, la decisione viene presa a partire dal valore delle variabili [Scheda] e [MODOcrt], entrambe definite e inizializzate dalla Procedura MODEtest da essa dichiarate PUBLIC; per rendere attiva questa preziosa risorsa è quindi necessario eseguire quest'ultima procedura.

	Libreria GiobeASM			CambiaCol
	50 di 54

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54

Giobe.ASM »

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default