MODEtest - Rileva automaticamente il Sistema di visualizzazione corrente e aggiorna le variabili interne - Giobe®2000

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Libreria GIOBE.ASM

Home » Programma il Computer » Tutorial Assembly

Raccolta di Procedure ASM

INTRODUZIONE [1 di 54]

Individua il Sistema di Visualizzazione (Scheda Grafica e Monitor) attualmente disponibili sul Computer.

La Procedura è molto utile ed andrebbe inserita come prima istruzione in tutti i sorgenti ASM; la sua esecuzione non produce alcun effetto visibile ma è indispensabile per definire e inizializzare alcune variabili interne, dichiarate PUBLIC e rese disponibili e visibili a tutte le strutture della Libreria Giobe.ASM/LIB (vedi sotto).

La seguente Area di Testo mostra il Modulo ram08 utilizzato per inserire la Procedura nella Libreria Giobe.ASM/LIB:

MODEtest / ram08

NB: se il testo contenuto nell'Area ti sembra strano (cioè se contiene
caratteri inconsueti) non hai ancora installato il font Giobe.TTF : clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : MODEtest.ASM                                                  ³
;³MODULO     : Ram08    (LIBRERIA C:\ARCH-LAB\BIN\GIOBE.LIB)                 ³
;³AUTORE     : Giorgio OBER  ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
;³VERSIONE   : maggio 1995   ³VERSIONE TUTORIAL ASSEMBLY - www.giobe2000.it ³³
;³AGGIORNAMEN: gennaio  2003 ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;³DESCRIZIONE: Individua l'ADATTATORE  GRAFICO attualmente in  esercizio;  in³
;³             uscita lascia inizializzate le  variabili PUBLIC di sistema:  ³
;³             [Scheda]:  con un codice numerico  adatto  ad  identificate il³
;³             [Monitor]: tipo di Adattatore e il tipo di Monitor disponibili³
;³                       ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÂÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
;³                       ³    [Scheda]        ³           [Monitor]         ³³
;³                       ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÅÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´³
;³                       ³06=Adattatore VGA   ³06=Monitor a colori  VGA/MCGA³³
;³                       ³05=Adattatore MCGA  ³05=Monitor monocrom. VGA/MCGA³³
;³                       ³04=Adattatore EGA   ³04=Monitor a colori  EGA     ³³
;³                       ³03=Adattatore CGA   ³03=Monitor monocrom. EGA     ³³
;³                       ³02=Adattatore MDA   ³02=Monitor a colori  CGA     ³³
;³                       ³01=Adattatore HGC   ³01=Monitor monocrom. MDA     ³³
;³                       ³00=Nessun Adattatore³00=Nessun Monitor            ³³
;³                       ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;³             [AD_6845]: con il  corretto  valore  dell'indirizzo  BASE  del³
;³                        Controller del CRT 6845, cioŠ 03D4H  per ADATTATORI³
;³                        a colori CGA/EGA/VGA  oppure 03B4H  per  ADATTATORI³
;³                        monocromatico MDA/HGC                              ³
;³             [BUFdis]:  con il corretto valore dell'indirizzo  del SEGMENTO³
;³                        della RAM video utilizzata dalla scheda, B800:0000H³
;³                        per ADATTATORI  a colori CGA/EGA/VGA  e  B000:0000H³
;³                        per ADATTATORI monocromatici MDA/HGC               ³
;³             [MODOcrt]: con il tipo di Monitor rilevato, 00H se  Monocroma-³
;³                        tico, 01H se a colori                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        PUBLIC  Scheda    ;Numero identificatore per l'Adattatore VIDEO Attivo
        PUBLIC  Monitor   ;Numero identificatore per il Monitor Attivo
        PUBLIC  SchedaI   ;Numero identificatore per l'Adattatore VIDEO Inatt.
        PUBLIC  MonitorI  ;Numero identificatore per il Monitor Inattivo
        PUBLIC  AD_6845   ;Indirizzo BASE dei Registri del Controller del CRT
        PUBLIC  BUFdis    ;SEGMENTO RAM VIDEO utilizzato dalla Scheda
        PUBLIC  MODOcrt   ;Numero identificatore di presenza Monitor Monocrom.
        PUBLIC  MODEtest
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
                              ;--[Variabili PUBLIC]---------------------------
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Scheda    DB   06H            ;³06=Adattatore VGA              (default)     ³
       ;  DB   05H            ;³05=Adattatore MCGA                           ³
       ;  DB   04H            ;³04=Adattatore EGA                            ³
       ;  DB   03H            ;³03=Adattatore CGA                            ³
       ;  DB   02H            ;³02=Adattatore MDA                            ³
       ;  DB   01H            ;³01=Adattatore HGC/Adattatore HGC+            ³
       ;  DB   00H            ;³00=Nessun Adattatore                         ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Monitor   DB   06H            ;³06=Monitor a colori  VGA/MCGA  (default)     ³
       ;  DB   05H            ;³05=Monitor monocrom. VGA/MCGA                ³
       ;  DB   04H            ;³04=Monitor a colori  EGA                     ³
       ;  DB   03H            ;³03=Monitor monocrom. EGA                     ³
       ;  DB   02H            ;³02=Monitor a colori  CGA                     ³
       ;  DB   01H            ;³01=Monitor monocrom. MDA/HGC                 ³
       ;  DB   00H            ;³00=Nessun Monitor                            ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Indirizzo di SEGMENTO della RAM video utiliz-³
                              ;³zata dalla scheda rilevata:                  ³
BUFdis    DW 0B800H           ;³B800:0000 per l'ADATTATORE CGA/EGA/VGA       ³
       ;  DW 0B000H           ;³B000:0000 per l'ADATTATORE MONOCROMATICO     ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Indirizzo BASE dei  registri  del  Controller³
                              ;³del VIDEO, un 6845, cioŠ                     ³
AD_6845   DW 03D4H            ;³03D4H per l'ADATTATORE CGA/EGA/VGA           ³
       ;  DW 03B4H            ;³03B4H per l'ADATTATORE MONOCROMATICO         ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
MODOcrt   DB   01H            ;³01=Monitor a colori               (default)  ³
       ;  DB   00H            ;³00=Monitor monocromatico, bianco/nero        ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
SchedaI   DB   00H            ;³Codice identificatore per Adattatore Inattivo³
MonitorI  DB   00H            ;³Codice identificatore per Monitor Inattivo   ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                   ;--[Variabili LOCALI]--------------------------------------
                   ;ÚÄÄÄÄÄÄ¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                   ;³OFFSET³³ Codice Sistema Visualizzatore  attivo/disattivo³
                   ;ÃÄÄÄÄÄÄ´ÃÄÄÄÂÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
TabCode DB 00H,00H ;³0000H ³³00H³Nessun Adatt.     +Nessun Monitor           ³
        DB 02H,01H ;³0002H ³³01H³Adattatore MDA    +Monitor monocrom. MDA    ³
        DB 03H,02H ;³0004H ³³02H³Adattatore CGA    +Monitor a colori CGA     ³
        DB 00H,00H ;³0006H ³³03H³**********  Codice Riservato ************** ³
        DB 04H,04H ;³0008H ³³04H³Adattatore EGA    +Monitor a colori EGA     ³
        DB 04H,01H ;³000AH ³³05H³Adattatore EGA    +Monitor monocrom. MDA    ³
        DB 00H,00H ;³000CH ³³06H³Codice Riservato (Adatt.PGA+Monitor a color)³
        DB 06H,05H ;³000EH ³³07H³Adattatore VGA    +Monitor monocrom.VGA/MCGA³
        DB 06H,06H ;³0010H ³³08H³Adattatore VGA    +Monitor a colori VGA/MCGA³
        DB 00H,00H ;³0012H ³³09H³**********  Codice Riservato ************** ³
        DB 05H,04H ;³0014H ³³0AH³Adattatore MCGA   +Monitor a colori EGA     ³
        DB 05H,05H ;³0016H ³³0BH³Adattatore MCGA   +Monitor monocrom.VGA/MCGA³
        DB 05H,06H ;³0018H ³³0CH³Adattatore MCGA   +Monitor a colori VGA/MCGA³
                   ;ÃÄÄÄÄÄÄ´ÃÄÄÄÁÄÄÄÂÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
                   ;³----- ³³0DHöFEH³********** codici riservati ************³
                   ;³----- ³³FFH    ³Sistama di Visualizzazione Sconosciuto  ³
                   ;ÀÄÄÄÄÄÄÙÀÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                   ;ÚÄÄÄÄÄÄ¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                   ;³OFFSET³³    Monitor  ³
                   ;ÃÄÄÄÄÄÄ´ÃÄÄÄÄÄÄÄÄÄÄÄÄÄ´
TabSwic DB 02H     ;³0000H ³³CGA a colori ³0000 000x
        DB 02H     ;³0001H ³³CGA a colori ³
        DB 04H     ;³0002H ³³EGA a colori ³0000 001x ÚÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        DB 04H     ;³0003H ³³EGA a colori ³          ³CGA a colori ³0000 0xxx
        DB 01H     ;³0004H ³³MDA monocrom.³0000 010x ³EGA a colori ³0000 x0xx
        DB 01H     ;³0005H ³³MDA monocrom.³          ³MDA monocrom.³0000 xxxx
        DB 02H     ;³0006H ³³CGA a colori ³0000 011x ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        DB 02H     ;³0007H ³³CGA a colori ³
        DB 04H     ;³0008H ³³EGA a colori ³0000 100x
        DB 04H     ;³0009H ³³EGA a colori ³
        DB 01H     ;³000AH ³³MDA monocrom.³0000 101x
        DB 01H     ;³000BH ³³MDA monocrom.³
                   ;ÀÄÄÄÄÄÄÙÀÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
mono    proc   NEAR             ;ÚÄ[MDA]Ä[VGAmono/EGAmono]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
 MOV Word Ptr CS:[AD_6845],03B4H;³Predispone le variabili  interne  del  pro-³
 MOV Word Ptr CS:[BUFdis],0B000H;³gramma per  rappresentare  per  default  un³
   MOV Byte Ptr CS:[MODOcrt],00H;³SottoSistema  Video  monocromatico  MDA/HGC³
        RET                     ;³                                           ³
mono    ENDP                    ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
MODEtest proc   NEAR
        PUSH    AX
        PUSH    BX
        PUSH    CX
        PUSH    DX
        PUSH    SI
        PUSH    DI
        PUSH    ES
                                ;ÚÄ[VGA/MCGA/EGA/CGA]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
 MOV Word Ptr CS:[AD_6845],03D4H;³Predispone le variabili  interne  del  pro-³
 MOV Word Ptr CS:[BUFdis],0B800H;³gramma per  rappresentare  per  default  un³
   MOV Byte Ptr CS:[MODOcrt],01H;³SottoSistema Video non di tipo MDA/HGC cioŠ³
                                ;³CGA/EGA/VGA a colori                       ³
                                ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿Restituisce informazioni sull'adattatore video
                              ;³attualmente installato lasciando AL=1AH se so-
                              ;³no supportate le funzioni VGA; se il  computer
                              ;³dispone di 2 distinti sottosistemi il valore
        MOV     AX,1A00H      ;³di BL indica quale di essi Š attivo (cioŠ cor-
        INT     10H           ;³rentemente aggiornato dal BIOS)  e  BH  indica
                              ;³quello inattivo (BH=0 se  il  computer dispone
                              ;Ùdi un solo sottosistema)
        CMP     AL,1AH        ;¿Se non risultano  supportate funzioni  VGA  si
        JNZ     mode_3        ;Ùprovvede a verificare la presenza di EGA
        ;---------------------------------------------------------------------
        MOV     AH,00H        ;¿
        MOV    CS:[SchedaI],AH;³Se BH=0 il computer dispone di un solo  Sotto-
        MOV   CS:[MonitorI],AH;³Sistema di Visualizzazione (ovviamente Attivo)
        CMP     BH,00H        ;³
        JZ      mode_0        ;Ù
        MOV     AL,BH         ;¿Verifica del  SottoSistema  Inattivo:  in BH Š
        SHL     AX,1          ;³lasciato un codice numerico che rappresenta la
        LEA     SI,TabCode    ;³coppia di  Scheda e Monitor rilevati per esso;
        ADD     SI,AX         ;³la tabella TabCode traduce  questo  codice  in
        MOV     AX,CS:[SI]    ;³altri 2, appositamente creati per  identifi-
        MOV    CS:[SchedaI],AL;³care la coppia
        MOV   CS:[MonitorI],AH;Ù
mode_0: MOV     AL,BL         ;¿Verifica del SottoSistema Attivo: in BL Š  di-
        SHL     AX,1          ;³sponibile un codice numerico  che  rappresenta
        LEA     SI,TabCode    ;³la coppia di Scheda e Monitor rilevati per es-
        ADD     SI,AX         ;³so; viene utilizzata ancora la tabella TabCode
        MOV     AX,CS:[SI]    ;³al fine di tradurre questo codice in altri 2
        MOV     CS:[Scheda],AL;³appositamente creati per identificare la nuova
        MOV    CS:[Monitor],AH;Ùcoppia
        CMP     AL,02H        ;¿
        JZ      mode_1        ;³
        CMP     AH,01H        ;³Analizza la possibilit… si predisporre le  va-
        JZ      mode_2        ;³riabili interne per Sottosistemi MONOCROMATICI
        CMP     AH,03H        ;³
        JZ      mode_2        ;³ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CMP     AH,05H        ;³³Scheda  = AL=02H=Adattatore MDA             ³
        JZ      mode_2        ;³³Monitor = AH=01H=Monitor monocromatico  MDA ³
        JMP     mode_A        ;³³Monitor = AH=03H=Monitor monocromatico  EGA ³
mode_1: CALL    mono          ;³³Monitor = AH=05H=Monitor monocrom. VGA/MCGA ³
mode_2:                       ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
   MOV Byte Ptr CS:[MODOcrt],0;³
        JMP     mode_A        ;Ù
        ;---------------------------------------------------------------------
mode_3:                       ;ÚÄÄ[EGAcolore/EGAbw]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
  MOV Byte Ptr CS:[Scheda],04H;³SottoSistema Video Principale di tipo  EGA  e³
 MOV Byte Ptr CS:[SchedaI],00H;³Secondario di tipo non riconosciuto.         ³
                              ;³Se non Š stata localizzata una scheda VGA  si³
        MOV     BL,10H        ;³richiedono ulteriori informazioni  sull'adat-³
        MOV     AH,12H        ;³tatore EGA attualmente installato; poich‚  in³
        INT     10H           ;³BL viene restituito il numero di  blocchi  da³
                              ;³64K di memoria RAM  installata  sulla  scheda³
                              ;³EGA (es: BL=8, 512Kbytes) se BL NON viene re-³
                              ;³stituito inalterato (BL=10H) si pu• prosegui-³
                              ;³re l'analisi sulla scheda EGA                ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        CMP     BL,10H        ;¿Se BL viene restituito inalterato (BL=10H) si
        JZ      mode_6        ;Ùprovvede a verificare la presenza di CGA
        ;---------------------------------------------------------------------
                              ;ÚÄ[EGA]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³In uscita la funzione lascia BH con il  valo-³
                              ;³re 00H se il sistema Š configurato per Sotto-³
        CMP     BH,00H        ;³Sistema a COLORI e BH=01H si per un  SottoSi-³
        JZ      mode_4        ;³stema MONOCROMATICO; le variabili interne del³
        CALL    mono          ;³programma vengono predisposte per  rappresen-³
                              ;³tare il corretto SottoSistema Video EGA.     ³
mode_4: MOV     AH,00H        ;³---------------------------------------------³
        MOV     AL,CL         ;³In uscita la Funzione lascia CL  con la copia³
        LEA     SI,TabSwic    ;³del valore presente sugli switch di  configu-³
        ADD     SI,AX         ;³razione EGA, la combinazione dei  quali  rap-³
        MOV     AL,CS:[SI]    ;³presenta un possibile  Monitor;  con  l'aiuto³
        MOV    CS:[Monitor],AL;³della tabella  TabSwic  si  inizializzano  le³
        MOV   CS:[MonitorI],AH;³rispettive variabili                         ³
        JMP     SHORT mode_A  ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;*****************************;********  alternativa !!!!!! ****************
;                             ;ÚÄ[EGA]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;                             ;³Sovrappone il Segmento ES all'area di Comuni-³
;       MOV     AX,0000H      ;³cazione BIOS e verifica  se  la  scheda EGA Š³
;       MOV     ES,AX         ;³ATTIVA controllando la locazione  di  sistema³
; TEST Byte Ptr ES:[0487H],08H;³0000:0487H con lo stato del Controller Video;³
;       JNZ      mode_6       ;³se il bit3 di questa  parola  Š  uguale a "0"³
;MOV Byte Ptr CS:[Monitor],04H;³risulta  attivo  un  Monitor  EGA; altrimenti³
; TEST Byte Ptr ES:[0487H],01H;³(bit3="1") Š attivo un altro tipo di monitor.³
;       JZ      mode_5        ;³Se il bit1 di questa parola Š uguale a "0" la³
;MOV Byte Ptr CS:[Monitor],03H;³scheda EGA Š collegata ad un visualizzatore a³
;MOV Byte Ptr CS:[MonitorI],0H;³colori; altrimenti (bit1="1") la scheda EGA Š³
;       CALL    mono          ;³collegata ad un visualizzatore TTL momonocro-³
;mode_5:JMP     SHORT mode_A  ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        ;---------------------------------------------------------------------
mode_6:                       ;ÚÄ[CGA/MDA/HGC]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Se non Š stata localizzata una scheda EGA  si³
                              ;³prosegue verificando la presenza del Control-³
                              ;³ler del CRT  all'indirizzo 03D4H (scheda CGA)³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        MOV     DX,03D4H      ;¿Punta porta BASE del  Controller CRT a  colori
        MOV     AL,0FH        ;³Predispone la lettura del  Registro nø 0FH con
        OUT     DX,AL         ;Ùla parte bassa dell'indirizzo del cursore
        INC     DX            ;¿Punta la porta DATI del Controller CRT  e  ne
        IN      AL,DX         ;³assume il valore della parte bassa  dell'indi-
        MOV     BL,AL         ;Ùrizzo corrente del Cursore, salvandola  in  BL
        MOV     AL,55H        ;¿Prova a scrivere sul Controller del CRT, 6845,
        OUT     DX,AL         ;³lasciando trascorrere un certo tempo  per con-
        MOV     CX,256        ;³sentirgli di rispondere; alla  scadenza  legge
mode_7: LOOP    mode_7        ;³la porta DATI per vedere se  il valore casuale
        IN      AL,DX         ;Ù01010101b Š stato scritto regolarmente
        MOV     BH,AL         ;¿Salva la nuova lettura in BH  e, prima di pro-
        OUT     DX,AL         ;Ùle del Registro 0FH  del  Controller  del  CRT
                              ;ÚÄ[CGA]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CMP     BH,55H        ;³Se il valore casuale scritto sul Registro 0FH³
        JNZ     mode_8        ;³Š stato restituito significa che in  Control-³
  MOV Byte Ptr CS:[Scheda],03H;³ler Š regolarmente presente (cioŠ la scheda Š³
  MOV Byte Ptr CS:[Monitor],2H;³di tipo CGA; le variabili interne sono predi-³
 MOV Byte Ptr CS:[SchedaI],00H;³sposte per un SottoSistema  Video  Principale³
 MOV Byte Ptr CS:[MonitorI],0H;³di tipo CGA e per un Sottosistema  Secondario³
        JMP     SHORT mode_A  ;³di tipo non riconosciuto.                    ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        ;---------------------------------------------------------------------
mode_8: CALL    mono          ;ÚÄ[MDA/HGC]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
  MOV Byte Ptr CS:[Monitor],1H;³Se non Š stata localizzata una scheda CGA  si³
 MOV Byte Ptr CS:[SchedaI],00H;³da  per  scontata la  presenza del Controller³
 MOV Byte Ptr CS:[MonitorI],0H;³del CRT all'indirizzo 03B4H (scheda MDA/HGC) ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        MOV     DX,03BAH      ;¿Punta porta di Stato del Controller CRT  mono-
        IN      AL,DX         ;³cromatico e ne legge il contenuto, mettendo in
        AND     AL,10000000B  ;³evidenza il bit7 e salvandone il valore in BL;
        MOV     BL,AL         ;Ù
        MOV     CX,30000      ;¿Poich‚ questo bit (che segnala la Sincronizza-
mode_9: IN      AL,DX         ;³zione Verticale) cambia su HGC ma non  su  MDA
        AND     AL,10000000B  ;³si ripete pi— volte la sua lettura per verifi-
        CMP     BL,AL         ;³care se, durante i vari tentativi, il suo  va-
        LOOPZ   mode_9        ;Ùlore Š cambiato
                              ;ÚÄ[HGC]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Se la prova precedente ha rilevato variazioni³
  MOV Byte Ptr CS:[Scheda],01H;³del valore del bit7 del Registro di Stato del³
        JNZ     mode_A        ;³Controller del CRT l'Adattatore Š  certamente³
                              ;³di tipo MDA; le variabili interne sono predi-³
                              ;³sposte per questo SottoSistema               ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄ[MDA]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Se la prova precedente NON ha rilevato varia-³
                              ;³zioni del valore del  bit7  del  Registro  di³
  MOV Byte Ptr CS:[Scheda],02H;³Stato del Controller del  CRT  l'Adattatore Š³
                              ;³certamente di tipo MDA; le variabili  interne³
                              ;³sono   predisposte  per  questo  SottoSistema³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄ[NB!]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³Si Š volutamente trascurata la possibilit… di³
                              ;³verificare i bit6ö4 del Registro di Stato del³
mode_A: POP     ES            ;³Controller del CRT con  i  quali Š  possibile³
        POP     DI            ;³distinguere con pi— precisione  tra  Sottosi-³
        POP     SI            ;³stemi MONOCROMATICI non MDA; in dettaglio:   ³
        POP     DX            ;³      bit6öbit4  Adattatore   Monitor        ³
        POP     CX            ;³         000       HGC          MDA          ³
        POP     BX            ;³         001       HGC+         MDA          ³
        POP     AX            ;³         101       InColor      EGA colori   ³
        RET                   ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
MODEtest ENDP
_prog   ENDS
        END

L'analisi del codice (puoi scorrerlo con la barra laterale) mette in evidenza il lavoro di qualità che la procedura è in grado di assolvere, condotto con l'aiuto di sofisticate strutture dell'ambiente video.

Tra queste:

	la Sottofunzione 00 della Funzione 1AH di INT 10H, che legge i codici che descrivono i 2 Sistemi di Visualizzazione (attivo e alternativo) eventualmente presenti nel computer.
	la Sottofunzione 10 della Funzione 12H di INT 10H, che fornisce informazioni sulla configurazione di un eventuale sottosistema EGA, o VGA in emulazione EGA.
	l'azione sulla variabile di Sistema 0000:0487H dell'Area di Comunicazione BIOS, Stato del controller del Video su EGA
	l'azione sul Registro 0FH e sul Registro di Stato del Controller CRT.

Naturalmente la comprensione dei dettagli può essere acquisita solo dopo la trattazione dell'hardware della scheda video, a questo livello ancora piuttosto remota...

Vediamo invece come si chiamano le variabili interne, PUBLIC e disponibili per tutti i nostri programmi; come anticipato servono per individuare l'Adattatore grafico attualmente in esercizio e, in dettaglio, assumono questi significati:

Scheda: codice numerico adatto ad identificate il tipo di Adattatore disponibile

Monitor: codice numerico adatto ad identificate il tipo di Monitor disponibile

Scheda		Monitor
06H	Adattatore VGA (default)	06H	Monitor a colori VGA/MCGA (default)
05H	Adattatore MCGA	05H	Monitor monocrom. VGA/MCGA
04H	Adattatore EGA	04H	Monitor a colori EGA
03H	Adattatore CGA	03H	Monitor monocrom. EGA
02H	Adattatore MDA	02H	Monitor a colori CGA
01H	Adattatore HGC/Adattatore HGC+	01H	Monitor monocrom. MDA/HGC
00H	Nessun Adattatore	00H	Nessun Monitor

BUFdis: Indirizzo di Segmento della RAM video utilizzata dalla scheda rilevata

BUFdis
B800H	B800:0000 per l'Adattatore CGA/EGA/VGA (default)
B000H	B000:0000 per l'Adattatore MONOCROMATICO

AD_6845: Indirizzo BASE dei registri del Controller del VIDEO, un 6845

AD_6845
03D4H	per l'Adattatore CGA/EGA/VGA (default)
03B4H	per l'Adattatore MONOCROMATICO

MODOcrt: tipo di Monitor in uso

MODOcrt

01H

Monitor a colori (default)

00H

Monitor monocromatico, bianco/nero

SchedaI: Codice identificatore per Adattatore Inattivo

SchedaI
00H	Adattatore Inattivo (default)

MonitorI: Codice identificatore per Monitor Inattivo

MonitorI
00H	Monitor Inattivo (default)

	Libreria GiobeASM			INTRODUZIONE
	1 di 54

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54

Giobe.ASM »

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default