Porta Parallela ["Dentro il Computer" di Giobe®2000]

Pagina aggiornata il 07/09/2009 [5556 giorni fa]


		Come Funziona... Indirizzi Base Area Comunicaz. Bios Registri Livello Hardware Livello BIOS Livello DOS Tecniche d'Interruzione Connettori Cavi Interfaccia Applicazioni Software Applicazioni Hardware Download INDICE

Porta Parallela

Applicazioni Software

PROGETTO n° 01 - 4/9 [52 di 189]

Analisi del Problema · Analisi del Codice · Procedure importanti · Schema interfaccia · Descrizione dello schema

Porta Parallela - INPUT di Dati a 8 bit - Uso di un Multiplexer 74LS157

Analisi del Codice Sorgente [1 di 2]

L'obiettivo del progetto è quello di rendere possibile l'acquisizione di un dato a 8 bit.

Il risultato è facilmente ottenibile con l'aiuto di un banale hardware aggiuntivo, un multiplexer 74LS157, collegato direttamente alle linee d'ingresso della porta parallela.

Lo schema elettrico di tale interfaccia elimina ogni residuo dubbio ed è descritto nell'ultima pagina di questa sezione.

Il codice assembly del programma è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella:

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM   (aprile 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME        : Printer2.ASM                                                ³
;³ AUTORE      : Giorgio OBER                                                ³
;³ VERSIONE    : aprile 2003                                                 ³
;³ DESCRIZIONE : Controllo di una PORTA PARALLELA a basso livello, al fine di³
;³               acquisire lo stato di 8 sensori.                            ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ bisogna prima installare il Driver Configura_LPT1; scaricalo ³
;³ ³°°°°°°°°°°³ a:   http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ la SHELL DOS deve essere a "Pieno Schermo" (l'esecuzione  in ³
;³ ³°°°°°°°°°°³ "finestra DOS" non produce effetto sulla Stampante)          ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ In ogni caso PRIMA DI OGNI SESSIONE DOS Š necessario eseguire³
;³ ³°°°NB !!°°³ il programma Config_LPT1.EXE in ambiente Windows per attivare³
;³ ³°°°°°°°°°°³ la visibilit… dei driver installati con Configura_LPT1 !!!!! ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ -------------------------------------------------------------³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ Il programma consente la verifica dell'uso improprio della PORTA PARALLELA³
;³ per operazioni di INPUT; Š noto che in condizioni normali  sul  connettore³
;³ d'uscita del computer sono disponibili 12 linee di OUT [8 per i bit di DA-³
;³ TO (pin 2ö9) e le linee di STROBE (pin 1),AUTOFEED (pin 14), INIT (pin 16)³
;³ e SELECT IN (pin 17)] e 5 linee di IN [ACKNOWLEDGE (pin 10), BUSY (pin 11)³
;³ PAPER EMPTY (pin 12), SELECT (pin 13) e ERROR (pin 15)];   con  un  banale³
;³ HardWare aggiuntivo collegato direttamente in uscita alla PORTA PARALLELA,³
;³ (un 74LS157, quadruplo multiplexer da 2 a una) Š possibile quindi gesti-³
;³ re la lettura di otto interruttori (o sensori) utilizzando una delle linee³
;³ di OUT (per esempio STROBE, pin1) per convogliare in sequenza  le 2 met…³
;³ su 4 delle 5 linee di IN disponibili; lo  schema  elettrico  di³
;³ tale interfaccia elimina ogni residuo dubbio. Da notare che sul connettore³
;³ rimane  comunque disponibile LA NORMALE PORTA di OUT, governabile  con  un³
;³ qualunque protocollo di HANDSHAKE, implementato  dalle  rimanenti  4³
;³ linee (3 di OUT e una di IN).                                           ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
; COSTANTI DEFINITE PER IL PROGRAMMA:
        PRNdato EQU  378H     ;Registro   dei   DATI ( USCITA )
        PRNstat EQU  379H     ;Registro   di   STATO (INGRESSO)
        PRNcomd EQU  37AH     ;Registro di CONTROLLO ( USCITA )

; MACRO UTILIZZATE DAL PROGRAMMA:
        if1     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
         include  GIOBE.MAC ;(C:\ARCH-LAB\BIN\GIOBE.MAC);³
        endif   ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÚÄÄÄÄ¿ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE ESTERNE³NEAR³UTILIZZATE dal PROGRAMMA (dalla LIBRERIA GIOBE.LIB~)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÀÄÄÄÄÙÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN        STAsp:NEAR
        EXTRN        Acapo:NEAR
        EXTRN      BIOScls:NEAR
        EXTRN      BIOchr1:NEAR
        EXTRN      BIObeep:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN      Byt2Asc:NEAR
        EXTRN       RAMcls:NEAR
        EXTRN       RAMchr:NEAR
        EXTRN       RAMcur:NEAR
        EXTRN       RAMmes:NEAR
        EXTRN       RIEMPI:NEAR
        EXTRN       RAMpiu:NEAR

; DICHIARAZIONI PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB
        PUBLIC  Printer2

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³DEFINIZIONE DEL SEGMENTO DEL CODICE                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog

ORG     0100H
INIZIO: JMP     Printer2

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³AREA DESTINATA AI DATI DEL PROGRAMMA                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ATTRIB  DB   1FH
TESTO1  DB   "    Acquisizione di dati dalla porta parallela     ",00H
TESTO2  DB   " TUTORIAL ASSEMBLY  ---  www.Giobe2000.it",00H
TESTO3  DB   "Quit",00H

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³  AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : DeskTop                                                       ³
;³DESCRIZIONE: Procedura che inizializza completamente il  piano  di  lavoro.³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
DeskTop:CALL    RAMcls        ;Pulisce lo schermo e inizializza il segmento
                              ;dedicato alla RamVideo (ES=0B800H)
        CALL    VIA_cur       ; Rende il  cursore invisibile
        M_COLOR  71H          ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        MOV     AL,"°"        ;³                                             ³
        CALL    RIEMPI        ;³                                             ³
      RAMrepC 80," ", 0, 0,30H;³                                             ³
      RAMrepC 80," ",24, 0,30H;³                                             ³
      RAMcol  TESTO1, 0,15,3FH;³Organizza il piano di presentazione          ³
      RAMcol  TESTO2,24, 0,3FH;³                                             ³
      RAMcol  TESTO3,24,73,30H;³                                             ³
        RAM_cur 24,73         ;³                                             ³
        M_COLOR 3FH           ;³                                             ³
        MOV     AL,"Q"        ;³                                             ³
        CALL    RAMchr        ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA   : Delay__                                                      ³
;³DESCRIZIONE : Il ritardo prodotto Š legato dalla velocit… del processore   ³
;³              perch‚ utilizza le un ciclo di istruzioni.. Š di circa 1 ms  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Delay__:PUSH    CX
        MOV     CX,0000H ;65536
del2_:  PUSH    AX
        PUSH    BX
        PUSH    CX
        PUSH    DX
        POP     DX
        POP     CX
        POP     BX
        POP     AX
        LOOP    del2_
        POP     CX
        RET

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
Printer2 proc   NEAR          ;³      AREA DEDICATA AL MAIN PROGRAM         ³³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CALL    DeskTop       ;³Organizza il piano di presentazione          ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿ÚÄ[037AH/027AH - PORTA d'USCITA dei COMANDI]Ä¿
                              ;³³       ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂ4ÄÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿    ³
                              ;³³       ³ * ³ * ³ * ³ * ³Out³Out³Out³Out³    ³
                              ;³³non    ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÙ    ³
                              ;³³disponib.ÁÄÄÄÁÄÄÄÁÄÄÄÙ   ³   ³   ³   ³      ³
                              ;³³pin 17 NegatoÄÄÄÄÄÄÄÄÄÄÄÄÙ   ³   ³   pin 1  ³
                              ;³³pin 16 ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ   ³   Negato ³
                              ;³³pin 14 NegatoÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ          ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Prnt00: MOV     AL,00H        ;³Forza a "0" la linea collegata al pin1  (bit0
        MOV     DX,PRNcomd    ;³della porta d'USCITA COMANDI) a beneficio  del
        OUT     DX,AL         ;³multiplexer 74LS157;  esso  collega  quindi  i
        CALL    Delay__       ;³primi 4 interruttori (SW3öSW0) alle  linee  di
                              ;³ingresso scelte per questa  interfaccia,  cioŠ
                              ;³rispettivamente ai pin11 (bit7), pin10 (bit6),
                              ;Ùpin12 (bit5) e pin13 (bit4)

;¿ÚÄ[0379H/0279H-PORTA d'INGRESSO dello STATO]Ä¿
                              ;³³       ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂ4ÄÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿    ³
                              ;³³       ³ In³ In³ In³ In³ In³ * ³ * ³ * ³    ³
                              ;³³       ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÙ    ³
                              ;³³         ³   ³   ³   ³   ³   ÀÄÄÄÅÄÄÄÙ      ³
                              ;³³pin 11 Negato³   ³   ³   ³   non disponibili³
                              ;³³pin 10 ÄÄÄÄÄÄÙ   ³   ³   ÀÄÄÄÄ pin 15       ³
                              ;³³pin 12 ÄÄÄÄÄÄÄÄÄÄÙ   ÀÄÄÄÄÄÄÄÄ pin 13       ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Esegue praticamente la lettura dei primi 4 in-
        MOV     DX,PRNstat    ;³terruttori SW3öSW0, copiandone il  valore  ri-
        IN      AL,DX         ;³spettivamente nei bit7öbit4 di  AL  corrispon-
                              ;³denti internamente alle linee di IN scelte per
                              ;³questa  interfaccia,  cioŠ  ai  pin11  (bit7),
                              ;Ùpin10 (bit6), pin12 (bit5) e pin13 (bit4)

XOR     AL,10000000B  ;¿Formatta in BL la prima met… dell'informazione
        SHR     AL,1          ;³desiderata compattandola nella forma 0000xxxxH
        SHR     AL,1          ;³Da notare che, essendo la linea BUSY invertita
        SHR     AL,1          ;³da HW (con un inverter) dentro la  scheda  del
        SHR     AL,1          ;³computer Š NECESSARIO "raddrizzare" da SW que-
        MOV     BL,AL         ;Ùsto bit7 per evitare  l'errata interpretazione

;¿ÚÄ[037AH/027AH - PORTA d'USCITA dei COMANDI]Ä¿
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        MOV     AL,01H        ;³Forza a "1" la  linea  OUT  di  "STROBE" (bit0
        MOV     DX,PRNcomd    ;³della porta d'USCITA COMANDI) a beneficio  del
        OUT     DX,AL         ;³multiplexer 74LS157; esso collega quindi i ri-
        CALL    Delay__       ;³manenti 4 interruttori (SW7öSW4) alle linee di
                              ;³ingresso scelte per questa  interfaccia,  cioŠ
                              ;³ancora rispettivamente ai pin11 (bit7),  pin10
                              ;Ù(bit6), pin12 (bit5) e pin13 (bit4)

;¿ÚÄ[0379H/0279H-PORTA d'INGRESSO dello STATO]Ä¿
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Esegue praticamente la lettura  dei  secondi 4
        MOV     DX,PRNstat    ;³interruttori SW7öSW4, copiandone il valore an-
        IN      AL,DX         ;³cora rispettivamente nei bit7öbit4 di AL, sem-
                              ;³pre associati internamente alle linee di IN di
                              ;³questa  interfaccia,  cioŠ  ai  pin11  (bit7),
                              ;Ùpin10 (bit6), pin12 (bit5) e pin13 (bit4)
                              ;¿Formatta in AL la seconda  met…  dell'informa-
                              ;³zione desiderata nella forma xxxx0000H masche-
                              ;³randone la parte bassa; anche in  questo  caso
        XOR     AL,10000000b  ;³Š NECESSARIO "raddrizzare" da SW il bit7 asso-
        AND     AL,0F0H       ;³ciato alla linea BUSY per evitare l'errata in-
                              ;³terpretazione del dato acquisito, essendo essa
                              ;³come detto, invertita da HW (con  un inverter)
                              ;Ùdentro la scheda del computer

OR      AL,BL         ;** Ricostruisce  in AL il byte ora acquisito **

PUSH    AX            ;¿Provvede alla stampa a video del  byte  appena
        M_cursor 13,39        ;³acquisito, a verifica  del  funzionamento  del
        POP     AX            ;³pacchetto HW/SW che si occupa di questa acqui-
        CALL    Byt2Asc       ;Ùsizione di DATI
                              ;¿Funzione BIOS INT 16H che consente di  verifi-
        MOV     AH,01H        ;³care la eventuale  pressione  di  tasti  senza
        INT     16H           ;³fermarsi; Š cos possibile tornare al  DOS con
        JZ      Prnt00        ;³la pressione di un tasto qualunque, senza  in-
                              ;³terrompere il "polling" della porta d'ingresso
                              ;Ù(NB: ffZ="1" = nessuna pressione tasti (Z) )

_OUT:   PUSH    AX            ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
       RAMrepC 80," ", 0,0,0FH;³                                             ³
       RAMrepC 80," ",24,0,0FH;³Torna al DOS con la memoria liberata e con la³
        CALL    RIP_cur       ;³chiusura di tutti i file; cede  il  controllo³
        MOV     DH,23         ;³al processo padre (generalmente COMMAND.COM);³
        MOV     DL,0          ;³il valore posto eventualmente  in AL prima di³
        CALL    SET_cur       ;³uscire pu• essere testato in  uscita  con  la³
        POP     AX            ;³funzione 4DH o mediante la lettura della  va-³
        MOV     AH,4CH        ;³riabile DOS "ERRORLEVEL"                     ³
        INT     21H           ;³                                             ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Printer2 ENDP                 ;³Chiusura standard del codice                 ³
_prog   ENDS                  ;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        END INIZIO            ;³Chiusura del segmento di codice e conclusione³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

La lettura può essere operata anche in Ambiente Assembler (disponibile sul Sito accedendo a questa pagina); se hai già provveduto alla sua installazione scarica il sorgente del progetto direttamente nella cartella C:\Arch-Lab\Lavoro (scegliendo il pulsante di opzione "Salva" e, come destinazione, seleziona la cartella che ti ho appena suggerito).

Ricorda: se fai click sull'icona a sinistra si apre l'Ambiente Assembly e puoi operare in esso on-line. Scegli il pulsante di opzione "Aprire il file" o "Esegui l'applicazione" e conferma con OK.
NB: alcuni gestori di protezione (per esempio SP2 di WinXP) non ti consentono questa operazione: in questo caso scrivi c:\Arch-Lab\Assembler_Vista&XP.pif direttamente nel campo indirizzo del Browser.

Nella shell DOS aperta (in finestra o a pieno schermo) puoi iniziare una sessione di lavoro digitando MACRO In_LPT1a /e (con gli spazi al posto giusto !!) e conferma con Invio.

	Porta Parallela			PROGETTO n° 01 - 4/9
	52 di 189

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189

Parallela »

^Home

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default