Porta Parallela - Software ["Dentro il Computer" di Giobe®2000]

		Come Funziona Indirizzi Base Area Comunicaz. Bios Registri Livello Hardware Livello BIOS Livello DOS Tecniche d'Interruzione Connettori Cavi Interfaccia Applicazioni Software Applicazioni Hardware Download INDICE
Porta Parallela

Applicazioni Software

PROGETTO nÂ° 07 - 4/5 [102 di 189]

Analisi del Problema · Analisi del Codice · Procedure importanti · Schema interfaccia

Porta Parallela - INPUT SPP di Dati a 5 bit - Contatto diretto sui pin abilitati

Analisi del Codice Sorgente

	Il compito del programma consiste nel leggere lo stato logico dei 5 pin del connettore SPP, di norma destinati all'ingresso dati.
	Il programma è in grado di rilevare contemporaneamente tutte le possibili variazioni, cosa possibile applicando una massa tutti e 5 i pin abilitati, cioè collegandoli con il pin25.
	Il codice assembly del programma è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella:

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER tipo COM (settembre 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME        : SPP1_IN.ASM                                                 ³
;³ AUTORE      : Giorgio OBER                                                ³
;³ VERSIONE    : settembre 2003                                              ³
;³ DESCRIZIONE : Test di INPUT da una PORTA PARALLELA SPP.                   ³
;³               Il programma consente la verifica della PORTA PARALLELA SPP ³
;³               in operazioni di INPUT; in condizioni normali sul connettore³
;³               sono disponibili  SOLO 5  linee di INPUT,  sui pin10, pin11,³
;³               pin12, pin13 e pin15, note nel protocollo Centronics rispet-³
;³               tivamente  con  i nomi di  ACKNOWLEDGE,  BUSY,  PAPER EMPTY,³
;³               SELECT e ERROR; il valore logico applicato Š  leggibile  nel³
;³               registro d'ingresso 0379H, "di Stato" nel protoc. Centronics³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ bisogna prima installare il Driver Configura_LPT1; scaricalo ³
;³ ³°°°°°°°°°°³ a:   http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ la SHELL DOS deve essere a "Pieno Schermo" (l'esecuzione  in ³
;³ ³°°°°°°°°°°³ "finestra DOS" non produce effetto sulla Stampante)          ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ In ogni caso PRIMA DI OGNI SESSIONE DOS Š necessario eseguire³
;³ ³°°°NB !!°°³ il programma Config_LPT1.EXE in ambiente Windows per attivare³
;³ ³°°°°°°°°°°³ la visibilit… dei driver installati con Configura_LPT1 !!!!! ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ -------------------------------------------------------------³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
; COSTANTI DEFINITE PER IL PROGRAMMA:
        PRNstat EQU  379H     ;Registro   di   STATO (INGRESSO)

; MACRO UTILIZZATE DAL PROGRAMMA:
        if1     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
         include  GIOBE.MAC ;(C:\ARCH-LAB\BIN\GIOBE.MAC);³
        endif   ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÚÄÄÄÄ¿ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE ESTERNE³NEAR³UTILIZZATE dal PROGRAMMA (dalla LIBRERIA GIOBE.LIB~)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÀÄÄÄÄÙÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN      BIOScls:NEAR
        EXTRN      BIOchr1:NEAR
        EXTRN      BIObeep:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN      byt2asc:NEAR

; DICHIARAZIONI (VARIABILI) PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB        ;Attributo di colore

; DICHIARAZIONI (PROCEDURE) PER I PROGRAMMI ESTERNI:
        PUBLIC  SPP1_IN

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³DEFINIZIONE DEL SEGMENTO DEL CODICE                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog

ORG     0100H
INIZIO: JMP     SPP1_IN

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³AREA DESTINATA AI DATI DEL PROGRAMMA                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ATTRIB  DB 0FH
preced  DB 00H
TESTO1  DB "ÚÄÄbitÄÄ¿ Ú7Â6Â5Â4Â3Â2Â1Â0¿ÚÄÄÄÄÄÄÄ¿ ",00H
TESTO2  DB "³ 0379H ³ ³ ³ ³ ³ ³ ³ ³ ³ ³³    H  ³ ",00H
TESTO3  DB "ÀÄÄÄÄÄÄÄÙ ÀÄÁÄÁÄÁÄÁÄÁÄÁÄÁÄÙÀÄÄÄÄÄÄÄÙ ",00H
TESTOE  DB "ÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ",00H
TESTOF  DB "NB: il valore di questo bit Š NEGATO",00H
TESTOG  DB "       rispetto a quello del pin11",00H
TESTO4  DB "       ÚÄÄÄÄÄÄÄpin13  (bit4)0379H          ",00H
TESTO5  DB "       ³ ÚÄÄÄÄÄpin12  (bit5)0379H          ",00H
TESTO6  DB "       ³ ³ ÚÄÄÄpin11  (bit7)0379H negato   ",00H
TESTO7  DB "       ³ ³ ³ ÚÄpin10  (bit6)0379H ÚÄÄpin1  ",00H
TESTO8  DB "   ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿    ",00H
TESTO9  DB "    \  þ þ þ þ þ þ þ þ þ þ þ þ þ þ þ  /     ",00H
TESTOA  DB "      \ þ þ þ þ þ þ þ þ þ þ þ þ þ þ /       ",00H
TESTOB  DB " GND   ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ        ",00H
TESTOC  DB " pin25ÄÄÙ   (bit3)0379H  pin15ÄÙ ÀÄÄÄpin14 ",00H
TESTOI  DB "ÚÄÄpin1",00H
TESTOL  DB "pin25ÄÄÙ",00H
TESTOM  DB "ÀÄÄÄpin14",00H
TESTON  DB "0379",00H
TESTOD  DB "Collega tra loro  il pin25  e  uno dei pin 10,11,12,13 o 15",00H
TESTOH  DB "Se sei in ambiente Windows2000/NT/XP devi installare il Driver Config_IO",00H
TESTOH1 DB "e, prima di lanciare il programma, devi lanciare Config_LPT1 (vedi sito)",00H
Titolo  DB "Test Porta Parallela SPP - Input da connettore",00H
CopyRg  DB "TUTORIAL ASSEMBLY  ---  www.Giobe2000.it  ---  Copyright 2003",00H
Menu    DB "Cambia i contatti sul connettore  -  Un  tasto  per terminare",00H

Tab_Pin DB  '',9,50,8,50; xxxx0xxxB > pin15 a massa = bit3 a 0 
        DB  '',6,25,7,25; xxx0xxxxB > pin13 a massa = bit4 a 0 
        DB  '',6,27,7,27; xx0xxxxxB > pin12 a massa = bit5 a 0
        DB  '',6,31,7,31; x0xxxxxxB > pin10 a massa = bit6 a 0

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³  AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA     :DeskTop                                                     ³
;³DESCRIZIONE   :Predispone il piano di lavoro (DeskTop): dopo aver pulito lo³
;³               schermo e dopo aver fatto sparire il cursore mostra tutti  i³
;³               messaggi di presentazione del programma.                    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
DeskTop:CALL    BIOScls
        CALL    VIA_cur       ; fa sparire il cursore
        M_CURSOR 0,0          ;¿Stampa l'intera riga 0 (la prima) con
        M_COLOR 1FH           ;³caratteri vuoti (spazi)
        CALL    BARRA         ;Ù
        M_CURSOR 23,0         ;¿Stampa l'intera riga 24 (l'ultima) con
        M_COLOR 1FH           ;³caratteri vuoti (spazi)
        CALL    BARRA         ;Ù
      M_msgC  Titolo, 0,18,1FH; Testo del titolo
        M_msgC  MENU,23,10,1FH; Testo del Menu
      M_msgC  CopyRg,24,10,04H; Testo del CopyRight
       M_msgC TESTO4, 2,18,0FH;¿"       ÚÄÄÄÄÄÄÄpin13  (bit4)0379H          "
       M_msgC TESTO5, 3,18,0FH;³"       ³ ÚÄÄÄÄÄpin12  (bit5)0379H          "
       M_msgC TESTO6, 4,18,0FH;³"       ³ ³ ÚÄÄÄpin11  (bit7negato)0379H    "
       M_msgC TESTO7, 5,18,0FH;³"       ³ ³ ³ ÚÄpin10  (bit6)0379H ÚÄÄpin1  "
       M_msgC TESTO8, 6,18,0EH;³"   ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿    "
       M_msgC TESTO9, 7,18,0EH;³"    \  þ þ þ þ þ þ þ þ þ þ þ þ þ þ þ 1/     "
       M_msgC TESTOA, 8,18,0EH;³"      \ þ þ þ þ þ þ þ þ þ þ þ þ þ þ /       "
       M_msgC TESTOB, 9,18,0EH;³" GND   ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ        "
       M_msgC TESTOC,10,18,0FH;³" pin25ÄÄÙ   (bit3)0379H  pin15ÄÙ ÀÄÄÄpin14 "
       M_msgC TESTOI, 5,53,0EH;³ ÚÄÄpin1
       M_msgC TESTOL,10,19,0EH;³ pin25ÄÄÙ
       M_msgC TESTOM,10,52,0EH;Ù ÀÄÄÄpin14
       M_msgC TESTOD,12,10,03H; "           NB: pin25 = GND (massa)
       M_msgC TESTOH,13, 3,02H; " in ambiente Win2000/NT/XP lancia il Driver "
      M_msgC TESTOH1,14, 3,02H; " in ambiente Win2000/NT/XP lancia Config_io "
       M_msgC TESTO1,16,22,0FH;¿" ÚÄÄbitÄÄ¿ Ú7Â6Â5Â4Â3Â2Â1Â0¿ÚÄÄÄÄÄÄÄ¿ "
       M_msgC TESTO2,17,22,0FH;³" ³ 0379H ³ ³ ³ ³ ³ ³ ³ ³ ³ ³³  XXH  ³ "
       M_msgC TESTO3,18,22,0FH;³" ÀÄÄÄÄÄÄÄÙ ÀÁÄÁÄÁÄÁÄÁÄÁÄÁÄÙÀÄÄÄÄÄÄÄÙ "
       M_msgC TESTON,17,24,0EH;³             ³
       M_chr '',18,33,07H    ;³             ³
       M_msgC TESTOE,19,22,07H;³" ÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ"
       M_msgC TESTOF,20,22,07H;³" NB: il valore di questo bit Š NEGATO"
       M_msgC TESTOG,21,22,07H;Ù"     rispetto  a   quello  del  pin11"
        MOV     CS:[preced],0 ;¿Se Š la prima volta esegue comunque la colora-
        CALL    Colora        ;³immagini del connettore e  del registro 0379H,
        RET                   ;Ùal variare degli eventuali input

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ PROCEDURA   : BARRA                                                       ³
;³ DESCRIZIONE : Stampa una intera riga di caratteri vuoti, ideale per       ³
;³               scrivere titoli e menu!!                                    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
BARRA:  PUSH    AX
        PUSH    CX
        MOV     CX,80
        MOV     AL,' '
Barra0: CALL    BIOchr1
        LOOP    Barra0
        POP     CX
        POP     AX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ PROCEDURA   : Colora                                                      ³
;³ DESCRIZIONE : Evidenzia il pin del connettore posti a massa per imporre un³
;³               input nel registro 0379H; in ingresso in AL il dato in input³
;³               01111xxxB > Nessun pin a massa                              ³
;³               x0xxxxxxB > pin10 a massa = bit6 a 0                        ³
;³               1xxxxxxxB > pin11 a massa = bit7 a 1 (negato internamente)  ³
;³               xx0xxxxxB > pin12 a massa = bit5 a 0                        ³
;³               xxx0xxxxB > pin13 a massa = bit4 a 0                        ³
;³               xxxx0xxxB > pin15 a massa = bit3 a 0                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Colora: PUSH    DX
        PUSH    CX
        PUSH    AX
                              ;¿Aggiorna il valore  corrente  della  variabile
        MOV     CS:[preced],AL;³locale per evitare  di  fare  l'analisi  se il
                              ;Ùdato acquisito Š quello di prima
        M_CURSOR 17,52        ;¿Mostra il  risultato  dell'acquisizione  sulle
        M_COLOR  0EH          ;³immagini del connettore e  del registro 0379H,
        CALL    Byt2Asc       ;Ùal variare degli eventuali input
                              ;¿Predispone in AH  la maschera che  indica (con
        MOV     AH,00000001B  ;³il suo unico "1") il  bit  del  registro 0379H
                              ;Ùche sar… sottoposto a  test
        MOV     CX,3          ;¿
        MOV     DL,47         ;³
Col_0:  MOV     DH,'1'        ;³
        TEST    AL,AH         ;³
        JNZ     Col_1         ;³Fissa praticamente a "1" l'immagine  dei 3 bit
        MOV     DH,'0'        ;³meno significativi  del registro 0379H, comun-
Col_1:  PUSH    AX            ;³que non sottoposti a testÿ(la  scelta  di  una
        M_COLOR 0EH           ;³tecnica ridondante Š per assicurare l'eventua-
        M_CURSOR 17,DL        ;³le presenza nel registri letto in AL di  even-
        MOV     AL,DH         ;³tuali bit diversi da "1" (cosa per altro molto
        CALL    Biochr1       ;³poco probabile)
        POP     AX            ;³
        ROL     AH,1          ;³
        SUB     DL,2          ;³
        LOOP Col_0            ;Ù

LEA     DI,Tab_Pin    ;*Punta la tabella delle coordinate
                              ;¿Se nessuno degli 4 pin 10, 12, 13 e 15 (corri-
        MOV     CX,4          ;³spondenti ai bit6öbit3) sono a massa l'immagi-
                              ;³ne dei 4 bit del registro 0379H viene mostrata
                              ;Ùcon "1"; altrimenti con "0"
Col_2:  TEST    AL,AH         ;¿Controlla se il pin messo a massa  corrisponde
        JNZ     Col_3         ;³alla posizione corrente, rappresentata  dall'1
                              ;Ùnel valore corrente di AH
        M_Chr   CS:[DI],CS:[DI+1],CS:[DI+2],8FH;¿ Provvede    a    evidenziare
        M_Chr   'þ',CS:[DI+3],CS:[DI+4],8EH    ;³ posizione e bit nello schema
        M_Chr  '0',17,DL,0EH                   ;³ a video
        JMP     Col_6                          ;Ù
Col_3:  PUSH    AX                             ;¿
        M_Chr   CS:[DI],CS:[DI+1],CS:[DI+2],0FH;³ Provvede a cancellare nello
        M_Chr   'þ',CS:[DI+3],CS:[DI+4],06H    ;³ schema a video le posizioni
        M_Chr   '1',17,DL,0EH                  ;³ e i bit che non interessano
        POP     AX                             ;Ù
        ADD     DI,5          ;¿
        ROL     AH,1          ;³Aggiorna il test per la prossima combinazione
        SUB     DL,2          ;Ù
        DEC     CX            ;¿Ripete il  ciclo (non Š stato possibile usare
        CMP     CX,0000H      ;³direttamente "LOOP Col_2" perchŠ il salto re-
        JZ      Col_4         ;³lativo a Col_2 Š troppo distante
        JMP     Col_2         ;Ù
Col_4:  TEST    AL,AH         ;¿Controlla se il pin 11 Š messo a massa  oppure
        JZ      Col_5         ;Ùno (Š l'unica linea negata internamente)
        M_Chr  '',6,29,8FH   ;¿
        M_Chr  'þ',7,29,8EH   ;³Se Š cos provvede ad evidenziane la posizione
        M_Chr  '1',17,DL,0EH  ;³e bit nello schema a video
        JMP     SHORT Col_6   ;Ù
Col_5:  M_Chr  '',6,29,0FH   ;¿Altrimenti  ne  cancella l'evidenziazione  sia
        M_Chr  'þ',7,29,06H   ;³schema  a  video  del connettore che in quello
        M_Chr   '0',17,DL,0EH ;Ùdel registro
Col_6:  POP     AX            ;
        POP     CX            ;
        POP     DX            ;
        RET

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
SPP1_IN proc   NEAR           ;³      AREA DEDICATA AL MAIN PROGRAM         ³³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        CALL    DESKTOP
                              ;¿ÚÄ[0379H/0279H-PORTA d'INGRESSO dello STATO]Ä¿
                              ;³³       ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂ4ÄÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿    ³
                              ;³³       ³ In³ In³ In³ In³ In³ * ³ * ³ * ³    ³
                              ;³³       ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÙ    ³
                              ;³³         ³   ³   ³   ³   ³   ÀÄÄÄÅÄÄÄÙ      ³
                              ;³³pin 11 Negato³   ³   ³   ³   non disponibili³
                              ;³³pin 10 ÄÄÄÄÄÄÙ   ³   ³   ÀÄÄÄÄ pin 15       ³
                              ;³³pin 12 ÄÄÄÄÄÄÄÄÄÄÙ   ÀÄÄÄÄÄÄÄÄ pin 13       ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Esegue la  lettura  dello  stato  logico dei 5
xxx00:  MOV     DX,PRNstat    ;³contatti  sul connettore (pin11, pin10, pin12,
        IN      AL,DX         ;³pin13 e pin15)  associati  rispettivamente  ai
                              ;³bit7, bit6, bit5, bit4 e bit3 del registro  di
                              ;Ùingresso 0379H, detto "di stato" in Centronics
        CMP     CS:[preced],AL;¿Se  non  si Š  verificata  nessuna  variazione
        JE      xxx02         ;³rispetto a prima si evita l'analisi: la propo-
                              ;Ùsta a video non cambia
                              ;¿Mostra il  risultato  dell'acquisizione  sulle
        CALL    Colora        ;³immagini del connettore e  del registro 0379H,
                              ;Ùal variare degli eventuali input
xxx02:  MOV     AH,01H        ;¿
        INT     16H           ;³Continua  fino  alla  pressione  di  un  tasto
        JZ      xxx00         ;Ù

_OUT:   PUSH    AX            ;¿Torna al DOS  con la memoria liberata e con la
        CALL    RIP_cur       ;³chiusura di tutti i file; cede il controllo al
        MOV     DH,23         ;³processo padre (generalmente COMMAND.COM);  il
        MOV     DL,0          ;³valore  posto  eventualmente  in  AL  prima di
        CALL    SET_cur       ;³uscire pu• essere  testato in  uscita  con  la
        POP     AX            ;³funzione  4DH  o  mediante  la  lettura  della
        MOV     AH,4CH        ;³variabile DOS "ERRORLEVEL"
        INT     21H           ;Ù
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
SPP1_IN ENDP                  ;³Chiusura standard del codice                 ³
_prog   ENDS                  ;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        END INIZIO            ;³Chiusura del segmento di codice e conclusione³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

La lettura può essere operata anche in Ambiente Assembler (disponibile sul Sito accedendo a questa pagina); se hai già provveduto alla sua installazione scarica il sorgente del progetto direttamente nella cartella C:\Arch-Lab\Lavoro (scegliendo il pulsante di opzione "Salva" e, come destinazione, seleziona la cartella che ti ho appena suggerito).

Ricorda: se fai click sull'icona a sinistra si apre l'Ambiente Assembly e puoi entrare in Ambiente on-line.
Scegli il pulsante di opzione "Aprire il file" o "Esegui l'applicazione" e conferma con OK.
NB: alcuni gestori di protezione (per esempio SP2 di WinXP) non ti consentono questa operazione:
in questo caso scrivi c:\arch-lab\bin\sys\assembler.pif direttamente nel campo indirizzo del Browser

Nella shell DOS aperta (o a pieno schermo) puoi iniziare una sessione di lavoro digitando MACRO SPP1_in /e (con gli spazi al posto giusto !!) e conferma con Invio.

	Porta Parallela			PROGETTO nÂ° 07 - 4/5
	102 di 189

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189

Parallela »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default