Porta Seriale - Applicazioni Software ["Dentro il Computer" di Giobe®2000]

		Come Funziona SR232 Indirizzi Base Area Comunicaz. Bios Registri Livello Hardware Livello BIOS Livello DOS Tecniche d'Interruzione Connettori Cavi Applicazioni Software Applicazioni Hardware Download INDICE
Porta Seriale

Procedure Seriali

INIserial avanzata 5/5 [182 di 404]

- Inizializzazione della Comunicazione Seriale

2.2 Procedura INIserial: Versione sofisticata [5 di 5]

	In tutti i progetti destinati alla gestione di una porta seriale conviene utilizzare la versione sofisticata della procedura INIserial, appena descritta.
	Il suo codice assembly è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella: essa è adatta per una ricetrasmissione gestita in polling su COM1, predisposta per lavorare alla velocità di 9600 baud con protocollo hardware impostato su 8 bit di dato, 2 di stop, nessuna parità:

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : INIserial                                                     ³
;³DESCRIZIONE: Seleziona automaticamente la porta seriale COM predisposta dal³
;³             valore della costante "COM_num" (per default EQU 01H= COM1), e³
;³             se la porta seriale desiderata  NON  Š  presente  nel sistema,³
;³             lascia in uscita in SI il valore 0000H;  altrimenti lascia  in³
;³             SI l'indirizzo Base dell'UART sotto controllo ([port_8]= 03F8H³
;³             o 02F8H o 03E8H o 02E8H) e rende facilmente reperibili TUTTI i³
;³            Registri della serie virtualizzandoli con altrettante variabili³
;³             ÚÄÄÄÄÄÄÂÄÄÄÄÄÂÄÄÄÄÄÂÄÄÄÄÄÂÄÄÄÄÄÂÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
;³             ³******³ COM1³ COM2³ COM3³ COM4³Descrizione                  ³³
;³             ÃÄÄÄÄÄÄÅÄÄÄÄÄÅÄÄÄÄÄÅÄÄÄÄÄÅÄÄÄÄÄÅÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´³
;³             ³port_8³03F8H³02F8H³03E8H³02E8H³Scritt/Lett DATO -LSBdivisore³³
;³             ³port_9³03F9H³02F9H³03E9H³02E9H³Abilitaz Interruz-MSBdivisore³³
;³             ³port_A³03FAH³02FAH³03EAH³02EAH³Identif  interruzioni        ³³
;³             ³port_B³03FBH³02FBH³03EBH³02EBH³Registro controllo LINEA     ³³
;³             ³port_C³03FCH³02FCH³03ECH³02ECH³Registro controllo MODEM     ³³
;³             ³port_D³03FDH³02FDH³03EDH³02EDH³Registro stato LINEA         ³³
;³             ³port_E³03FEH³02FEH³03EEH³02EEH³Registro stato  del  MODEM   ³³
;³             ÀÄÄÄÄÄÄÁÄÄÄÄÄÁÄÄÄÄÄÁÄÄÄÄÄÁÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;³             Inizializza inoltre:                                          ³
;³             a) la velocit… di ricetrasmissione caricando il divisore a  16³
;³                bit, predisposto dalla costante "Baude" (default EQU 000CH=³
;³                9600 baud) nei Registri [port_9]=MSB e [port_8]=LSBdivisore³
;³             b) il valore dei parametri desiderati per il protocollo HW, in³
;³                in accordo con le scelte suggerite  dalla costante "Protoc"³
;³                (default EQU 07H= 8 bit di dato e 2 di stop,nessuna parit…)³
;³             c) il valore del Registro di abilitazione  delle Interruzioni,³
;³                [port_9] Š fissato a 00H: in questo modo nessun  evento se-³
;³                riale produrr… richiesta d'interruzione sulla linea dedica-³
;³                ta IRQ3 o IRQ4 e non sar… necessario predisporre la relati-³
;³                va procedura di servizio (rispettivamente INT0BH o INT0CH) ³
;³             d) il valore del Registro di controllo MODEM, [port_C], Š fis-³
;³                sato a 03H: in questo modo sono attivi i  segnali di tipici³
;³                del MODEM, "Data Terminal Ready" e "Request To Send"       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
depPOR  DB  COM_num ; Numero della porta COM da controllare  (1, 2, 3  o  4)
depVEL  DW  Baude   ; Valore n del divisore  di  Baud  RATE  necessario  per
                    ; stabilire la velocità di Ricetrasmissione = 115200Hz/n
depTIP  DB  Protoc  ; Byte   ricostruito   in   accordo  con  il  desiderato
                    ; numero di bit di dato, di stop e di (eventuale) parit…
                    ;ÚÄÄÄÄÄÂÄÄÄÄÄÂÄÄÄÄÄÂÄÄÄÄÄÂÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                    ;³ COM1³ COM2³ COM3³ COM4³Descrizione                   ³
                    ;ÃÄÄÄÄÄÅÄÄÄÄÄÅÄÄÄÄÄÅÄÄÄÄÄÅÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
port_8  DW  ?       ;³03F8H³02F8H³03E8H³02E8H³Scritt/Lett DATO - LSBdivisore³
port_9  DW  ?       ;³03F9H³02F9H³03E9H³02E9H³Abilitaz Interruz- MSBdivisore³
port_A  DW  ?       ;³03FAH³02FAH³03EAH³02EAH³Identif  interruzioni         ³
port_B  DW  ?       ;³03FBH³02FBH³03EBH³02EBH³Registro controllo LINEA      ³
port_C  DW  ?       ;³03FCH³02FCH³03ECH³02ECH³Registro controllo MODEM      ³
port_D  DW  ?       ;³03FDH³02FDH³03EDH³02EDH³Registro stato LINEA          ³
port_E  DW  ?       ;³03FEH³02FEH³03EEH³02EEH³Registro stato  del  MODEM    ³
                    ;ÀÄÄÄÄÄÁÄÄÄÄÄÁÄÄÄÄÄÁÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
;ÚÄÄÄÄÄÄ[PRIMA FASE]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³      Inizializzazione dei REGISTRI della PORTA SERIALE                    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
INIserial:
        PUSH    ES            ;¿Assume in  AX  l'indirizzo  BASE  della  porta
        MOV     AX,0000H      ;³seriale suggerita  dalla   variabile [depPOR],
        MOV     ES,AX         ;³a sua volta predisposta con  il  valore  della
        MOV     SI,0400H      ;³costante "COM_num" (per default EQU 01H=COM1),
        MOV     AL,CS:[depPOR];³estraendolo dalle locazioni dell'Area di comu-
        DEC     AL            ;³nicazione BIOS: le prime sue 8 locazioni  sono
        SHL     AL,1          ;³predisposte in fase di bootstrap ai valori:
        MOV     AH,00H        ;³ ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        ADD     SI,AX         ;³ ³0000:0400H - Porta Seriale 1 (COM1)  03F8H ³
        MOV     AL,ES:[SI]    ;³ ³0000:0402H - Porta Seriale 2 (COM2)  02F8H ³
        INC     SI            ;³ ³0000:0404H - Porta Seriale 3 (COM3)  03E8H ³
        MOV     AH,ES:[SI]    ;³ ³0000:0406H - Porta Seriale 4 (COM4)  02E8H ³
        POP     ES            ;³ ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;Ùse tutte i possibili UART sono presenti...
        CMP     AX,0000H      ;¿
        JNZ     INIse_        ;³Se AX contiene 0000 la porta desiderata  NON Š
        MOV     SI,AX         ;³installata: si torna immediatamente con SI=0
        RET                   ;Ù
        ;---------------------------------------------------------------------
INIse_: MOV     CS:[port_8],AX;¿
        INC     AX            ;³Altrimenti  inizializza  le  7  variabili  che
        MOV     CS:[port_9],AX;³saranno utilizzate per individuare i  Registri
        INC     AX            ;³della porta seriale desiderata; per la COM1:
        MOV     CS:[port_A],AX;³
        INC     AX            ;³[port_8]=03F8H Registro Scrittura/Lettura DATO
        MOV     CS:[port_B],AX;³[port_9]=03F9H Abilitazione interruzioni
        INC     AX            ;³[port_A]=03FAH Identificatore interruzioni
        MOV     CS:[port_C],AX;³[port_B]=03FBH Registro di controllo LINEA
        INC     AX            ;³[port_C]=03FCH Registro di controllo MODEM
        MOV     CS:[port_D],AX;³[port_D]=03FDH Registro di stato linea seriale
        INC     AX            ;³[port_E]=03FEH Registro stato MODEM
        MOV     CS:[port_E],AX;Ù

;ÚÄÄÄÄÄÄ[SECONDA FASE]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³      Inizializzazione della VELOCITA` di RICETRASMISSIONE SERIALE         ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿ÚÄ[port_B]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³ Registro di controllo della LINEA          ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Inizia la programmazione dell'UART:  per poter
        MOV     DX,CS:[port_B];³accedere ai  registri  divisori  di BaudRate Š
        MOV     AL,80H        ;³necessario  anzitutto  porre  a  "1"  il  bit7
        OUT     DX,AL         ;³di  [port_B]:   con   questa   predisposizione
                              ;³possono  ora  essere   introdotti  i  corretti
                              ;³valori per il divisore di baud rate:
                              ;³   "Baud Rate-lo",  su [port_8]  e
                              ;Ù   "Baud Rate-hi",  su [port_9]
                              ;¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³ AX= fattore di divisione [115200/costante] ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Prepara in AX (AL=LSB, AH=MSD) la costante  di
                              ;³divisione necessaria per dividere il clock  ad
                              ;³alta  frequenza (115200Hz) fornito all'UART (a
                              ;³partire dalla frequenza di norma applicata, di
                              ;³1.8432 MHz, LOCALMENTE  predivisa  per 16)  al
                              ;³fine di garantire la  desiderata  velocit…  di
                              ;³RICE-TRASMISSIONE (es: 9600 bps = 9600 baud)
                              ;³ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³Il valore del divisore a 16 bit  Š suggerito³
        MOV     AX,CS:[DepVEL];³³dalla variabile [DepVel], a sua volta predi-³
                              ;³³sposta con il valore della  costante "Baude"³
                              ;³³(default EQU 000CH=9600 baud)               ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Si ricorda che l'UART contiene  un  generatore
                              ;³programmabile di BAUD RATE in grado di tratta-
                              ;³re qualunque frequenza da 0 a 3.1 MHz; normal-
                              ;³mente la  frequenza applicata Š di  1.8432 MHz
                              ;³o, talvolta,  quella  due  terzi  pi—  grande,
                              ;³3.072 MHz), su cui viene operata immediatamen-
                              ;³te una predivisione per 16,  cosicch‚  la  co-
                              ;³stante descritta andr… a  dividere  effettiva-
                              ;³mente la frequenza di 115200 Hz, generando  la
                              ;Ùdesiderata frequenza di ricetrasmissione
                              ;¿ÚÄ[port_8]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³ Registro divisore Baud RATE (parte bassa)  ³
        MOV     DX,CS:[port_8];³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        OUT     DX,AL         ;³Se su [port_B] il bit7="1"  la  porta [port_8]
                              ;Ùserve come Registro divisore Baud RATE (low)
                              ;¿ÚÄ[port_9]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        MOV     AL,AH         ;³³ Registro divisore Baud RATE (parte alta)   ³
        MOV     DX,CS:[port_9];³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        OUT     DX,AL         ;³Se su [port_B] il bit7="1"  la  porta [port_9]
                              ;Ùserve come Registro divisore  Baud RATE (high)
                              ;ÚÄ[NB]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³se invece su [port_B] il  bit7="0"  la  prima³
                              ;³porta [port_8] serve come BUFFER  di trasmis-³
                              ;³sione (in LETTURA) o  di ricezione (in SCRIT-³
                              ;³TURA)  e la seconda porta [port_9] serve come³
                              ;³Registro di Abilitazione Interruzioni        ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄ[TERZA FASE]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³      Inizializzazione delle CARATTERISTICHE di RICETRASMISSIONE SERIALE   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿ÚÄ[port_B]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³ Registro di controllo della LINEA          ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Viene ricostruito il byte da spedire alla por-
                              ;³ta [port_B], che rappresenta le  caratteristi-
                              ;³che desiderate, cioŠ il Numero di bit per DATO
                              ;³il Numero di bit di STOP e la presenza del Bit
                              ;³di  Parit…;  poich‚  la  programmazione  della
                              ;³velocit…  di  RICETRASMISSIONE  Š   gi…  stata
                              ;³eseguita Š  necessario anche riporre a "0"  il
                              ;³bit7 di tale byte;di norma si pone a "0" anche
                              ;³il bit6 (se ="1", impostazione  di  break,  il
                              ;³dato di output seriale Š forzato  alla  condi-
                              ;³zione di SPACE (0 logico) indipendentemente da
                              ;³ci• che l'UART intende trasmettere) e  il bit5
                              ;³(se = "1" il bit di parit… viene forzato ad un
                              ;³valore costante, in funzione della  programma-
                              ;³zione dei  bit4/bit3;  altrimenti  il  bit  di
                              ;³parit… conserva il suo significato)
                              ;³ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³La combinazione di bit  corrispondente  alle³
        MOV     DX,CS:[port_B];³³nostre esigenze Š suggerita dalla  variabile³
        MOV     AL,CS:[DepTIP];³³[DepTip], a sua volta predisposta con il va-³
        OUT     DX,AL         ;³³lore della costante "Protoc" (default EQU 07³
                              ;³³= 8 bit di dato e 2 di stop, nessuna parit…)³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³        ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂÄ4ÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿
                              ;³[port_B]³ 0 ³ 0 ³ 0 ³ x ³ 0 ³ 1 ³ 1 ³ 1 ³ 07H
                              ;³        ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÙ
                              ;³ProtocolloÙ   ³   ³   ³   ³   ³   ÀÄÄÄÁÄ8 dato
                              ;³Break disab.ÄÄÙ   ³   ³   ³   ÀÄÄÄÄÄ2 bit stop
                              ;ÙParit… disab.ÄÄÄÄÄÙ   ÀÄÄÄÁÄÄÄÄÄnessuna parit…

;ÚÄÄÄÄÄÄ[QUARTA FASE]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³      Inizializzazione del REGISTRO di CONTROLLO del MODEM                 ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿ÚÄ[port_C]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³ Registro di controllo del MODEM            ³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Normalmente il Registro di MODEM va inizializ-
                              ;³zato a 03H e poi non si tocca pi—; tale predi-
                              ;³sposizione bit0 e bit1 a "1") attiva i segnali
                              ;³di controllo tipici del MODEM, "Data  Terminal
                              ;³Ready" e "Request To Send":  in questo modo il
                              ;³il computer DTE (UART) avvisa il modem DCE che
                              ;³Š regolarmente collegato alla linea di comuni-
                              ;³cazione, che Š pronto a trasmettere o ricevere
                              ;³dati (DTR) e che dispone di dati ed è pronto a
                              ;³trasmetterglieli (RTS): il bit2 OUT1 di questo
                              ;³registro (uscita  ausiliaria destinata utente)
                              ;³non Š usato, mentre il bit3 (OUT2=altra uscita
                              ;³ausiliaria destinata utente) DEVE essere posta
        MOV     DX,CS:[port_C];³a "1" solo  se  si  desidera   consentire  al-
        MOV     AL,03H        ;³l'INTERRUZIONE generata dall'UART di  raggiun-
        OUT     DX,AL         ;³gere il bus del sistema (per essere  eventual-
                              ;³mente controllata dal gestore  delle  interru-
                              ;³zioni, 8259); infine il bit4  deve essere a 0,
                              ;³in condizioni normali; se forzato a 1 la porta
                              ;³seriale (UART) si pone in uno stato molto par-
                              ;³ticolare,  LookBack  Mode,  straordinariamente
                              ;³utile per collaudare i nostri programmi ma del
                              ;³tutto inopportuno in regolare ricetrasmissione
                              ;³i bit5, bit6 e bit7 sono sempre a 0 (non usati
                              ;³da nessuna versione di UART)
                              ;³        ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂÄ4ÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿
                              ;³[port_C]³ 0 ³ 0 ³ 0 ³ 0 ³ 0 ³ 0 ³ 1 ³ 1 ³ 03H
                              ;³        ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÙ
                              ;³non usatiÄÁÄÄÄÁÄÄÄÙ   ³   ³   ³   ³   ÀDTR on
                              ;³no LookBack ModeÄÄÄÄÄÄÙ   ³   ³   ÀÄÄÄÄRTS on
                              ;ÙINT disabilitateÄÄÄÄOUT2ÄÄÙ   ÀOUT1Änon usata

;ÚÄÄÄÄÄÄ[QUINTA FASE]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³      Inizializzazione di ABILITAZIONE delle INTERRUZIONI SERIALI          ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿ÚÄ[port_9]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³³ Registro di abilitazione delle INTERRUZIONI³
                              ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;³Vengono specificati solo  gli  eventi  che  si
                              ;³desidera utilizzare per innescare il  meccani-
                              ;³smo dell'interruzione, in grado di attivare la
                              ;³linea IRQ3/IRQ4 dedicata  all'UART  coinvolto,
                              ;³avvisando cos il controllore  delle  interru-
                              ;³zioni 8259 che far… partire la relativa proce-
                              ;³dura di servizio BIOS, INT 0BH o  INT 0CH;  se
                              ;³NON SI DESIDERA far riferimento alle  tecniche
                              ;³d'interruzione tutti i bit di questo  registro
                              ;³sono lasciati a 0; altrimenti i bit significa-
        MOV     DX,CS:[port_9];³tivi sono: bit0="1" abilita  interrupt  quando
        MOV     AL,00H        ;³c'Š un DATO PRONTO in RICEZIONE; bit1="1" abi-
        OUT     DX,AL         ;³lita interrupt quando  il registro di TRASMIS-
        RET                   ;³SIONE  Š  VUOTO (DATO TRASMESSO); il  bit2="1"
                              ;³abilita interrupt se il registro di stato  non
                              ;³Š pi— a 00H (ERRORI in  RICEZIONE  o  RICEVUTA
                              ;³condizione di BREAK); il bit3="1"  abilita  un
                              ;³interrupt  per  cambiamento  dello  stato  del
                              ;³MODEM. Se su [port_B]  il  bit7="0"  la  porta
                              ;³[port_9] serve come  Registro  di Abilitazione
                              ;³delle Interruzioni: con  i  bit7öbit4  tutti a
                              ;³"0"  tutte  le  interruzioni  da  parte  della
                              ;³SERIALE sono disabilitate
                              ;³        ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂÄ4ÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿
                              ;³[port_9]³ 0 ³ 0 ³ 0 ³ 0 ³ 0 ³ 0 ³ 0 ³ 0 ³ 00H
                              ;³        ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄnoÁÄnoÁÄnoÁÄnoÙ
                              ;³non usatiÄÁÄÄÄÁÄÄÄÁÄÄÄÙ   ³   ³   ³   ³ RxD
                              ;³Variazione Stato LineaÄÄÄÄÙ   ³   ³   ÀÄpieno
                              ;ÙVariazione Registro ModemÄÄÄÄÄÙ   ÀÄTxD vuoto

	Anche questa versione di INIserial è adatta per una ricetrasmissione gestita in polling, predisposta per lavorare alla velocità di 9600 baud con protocollo hardware impostato su 8 bit di dato, 2 di stop, nessuna parità.
	Ne fanno uso i progetti TxD1Com1, RxD1Com1, RxD2Com1, RxD3Com1, RxD4Com1, dedicati alla COM1, e gli analoghi progetti TxD1Com2, RxD1Com2, RxD2Com2, RxD3Com2, RxD4Com2 dedicati alla COM2; puoi analizzare ogni dettaglio partendo dall'elenco di questa pagina.
	Per la sua versatilità nel riconoscere le porte seriali e nel organizzarne i Registri anche i 2 progetti dedicati alla ricetrasmissione gestita sotto interrupt (TxD2Com1, RxD5Com1 per la COM1 e TxD2Com2, RxD5Com2 per la COM2) includeranno comunque questa versione di INIserial tra le loro procedure, ma provvederanno in altri punti del programma ad attivare le condizioni necessarie per attivare la richiesta d'interruzione.

	Porta Seriale			INIserial avanzata 5/5
	182 di 404

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404

Seriale »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default