Palestra Livello Apprendisti - Esercizio 016 - Aspetta la digitazione di un stringa e poi la rende MAIUSCOLA

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Palestra Livello Apprendisti Livello Esperti

Home » Programma il Computer » Tutorial Assembly

Programmare in Assembly

Esercizio nÂ° A016 2/6 [81 di 157]

Analisi del Codice · Lettura Caratteri · Conversione Minus to Maius · Stampa risultato · Conclusioni

Acquisizione Caratteri - Aspetta la digitazione di un stringa e poi la rende MAIUSCOLA

Analisi del Codice

Aggiornato 12 febbraio 2007 - [nel sorgente Es016.ASM sostituito JG xxx03 con JA xxx03; ricompilare l'esercizio]

L'esercizio EsA016.ASM mette in pratica gli insegnamenti dei progetti precedenti; è l'ultimo della categoria Acquisizione di Caratteri da Tastiera e sviluppa un'idea particolarmente suggestiva: aspetta la digitazione di una stringa da tastiera e provvede a rendere maiuscoli i soli caratteri ascii letterali.

Ecco il Main Program, nella seguente casella di testo:

Esercizio

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
EsA016  proc    NEAR          ;³      AREA DEDICATA AL MAIN PROGRAM         ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿Provvede   alla   cancellazione   del   video,
        CALL    BIOScls       ;³posizionando il cursore alla riga0,  colonna0,
                              ;Ùin alto a sinistra
        CALL    VIA_cur       ; Rende il  cursore invisibile
      M_msgC Testo01,00,00,0FH;¿Mette a video il titolo, in posizione r00,c00
                              ;Ùcon colore  0FH (bianco brillante su nero)
                              ;-----------------------------------------------
                              ; PRIMA FASE : Lettura dei Caratteri da Tastiera
                              ;-----------------------------------------------
      M_msgC Testo02,02,00,0FH; Messaggio con la richiesta stringa
        M_CURSOR 03,01        ; Fissa la posizione di stampa per la stringa
        M_COLOR  0EH          ; Fissa il colore con cui stampare la stringa
                              ;¿Carica in SI l'indirizzo dell'area di  memoria
        LEA     SI,DEPO       ;³in cui salveremo, uno dopo l'altro i caratteri
                              ;Ùche stiamo per leggere dalla tastiera
xxx00:  CALL    KEYwait       ;¿Rimane in attesa della pressione  di un  tasto
                              ;Ùqualunque  (lasciando  il  suo  valore in  AL)
                              ;¿Salva il codice appena assunto da tastiera nel
        MOV     CS:[SI],AL    ;³deposito ("Depo", puntato da SI) e poi prepara
        INC     SI            ;³il   puntatore  (incrementa  SI)  per  puntare
                              ;Ùla locazione successiva
        CMP     AL,Invio      ;¿Verifica se il tasto appena premuto Š  <Invio>
        JE      xxx01         ;Ùe in questo caso pone  fine  all'acquisizione
        CALL    BIOchr1       ;¿Altrimenti pone a video il carattere appena
        JMP     SHORT xxx00   ;³assunto da tastiera e torna in attesa della
                              ;Ùpressione di altri tasti
                              ;-----------------------------------------------
                              ; SECONDA FASE : Trasformazione in Maiuscolo
                              ;-----------------------------------------------
                              ;¿Ricarica il puntatore all'area  di  memoria in
xxx01:  LEA     SI,DEPO       ;³cui sono stati salvati,  uno  dopo  l'altro, i
                              ;Ùcaratteri appena acquisiti dalla tastiera
xxx02:  MOV     AL,CS:[SI]    ; Assume dal Deposito  il  carattere  corrente
        CMP     AL,Invio      ;¿Verifica se il codice appena assunto Š <Invio>
        JE      xxx04         ;Ùe in questo caso  pone  fine  alla conversione

CMP     AL,'z'        ;¿Verifica se il carattere letto dal deposito  Š
        JA      xxx03         ;³una lettera minuscola; se Š  pi— grande di "z"
        CMP     AL,'a'        ;³(JA) o pi— piccolo di "a"(JB) non ci interessa
        JB      xxx03         ;³e si rientra nel loop per cercare  i caratteri
                              ;Ùeffettivamente minuscoli
                              ;¿Se invece si  tratta  di una lettera minuscola
                              ;³con  questa  istruzione  la  si  trasforma  in
                              ;³maiuscola ; in fatti la AND forza il bit 5
                              ;³comunque a 0 per cui, per esempio:
        AND     AL,11011111B  ;³>>> "A"=41H=01000001B diventa 01000000=41H="A"
                              ;³    cioŠ non cambia, essendo gi… MAIUSCOLA
                              ;³>>> "a"=61H=01100001B diventa 01000000=41H="A"
                              ;Ù    cioŠ cambia da minuscola a MAIUSCOLA
        MOV     CS:[SI],AL    ;¿Salva nel deposito, al posto del precedente il
                              ;Ùcodice appena reso maiuscolo
xxx03:  INC     SI            ;¿Prepara SI per puntare la locazione successiva
        JMP     SHORT xxx02   ;³e continua il processo di ricerca e conversio-
                              ;Ùne di altre eventuali lettere minuscole
                              ;-----------------------------------------------
                              ; TERZA FASE : Stampa della nuova stringa
                              ;-----------------------------------------------
                              ;¿La stringa Š stata convertita completamente...
                              ;³Queste istruzioni servono  per  sostituire  il
xxx04:  MOV     AL,00H        ;³caratterea Ascii di  <Invio>  con  quello  del
        MOV     CS:[SI],AL    ;³carattere  terminatore  00H,   necessario  per
                              ;³trasformare i caratteri del deposito  DEPO  in
                              ;Ùun messaggio gestibile dalla procedura BIOSmsg
      M_msgC Testo03,05,00,0FH; Messaggio con la presentazione del risultato
      M_msgC Depo,06,01,0EH   ; Stampa la stringa, ora adattata a Messaggio
                              ;-----------------------------------------------
      M_msgC Testo04,24,04,0FH; Mette a video la frase di commiato
        CALL    KEYwait       ;
       ;----------------------------------------------------------------------
_OUT:   PUSH    AX            ;¿Torna al DOS con la  memoria liberata e con la
        CALL    RIP_cur       ;³chiusura  di tutti i file; cede  il  controllo
        MOV     DH,23         ;³al  processo padre (generalmente COMMAND.COM);
        MOV     DL,0          ;³il valore posto eventualmente  in AL  prima di
        CALL    SET_cur       ;³uscire pu•  essere testato in  uscita  con  la
        POP     AX            ;³funzione  4DH  o  mediante  la  lettura  della
        MOV     AH,4CH        ;³variabile DOS "ERRORLEVEL" 
        INT     21H           ;Ù
EsA016  ENDP

	Palestra Apprendisti			Esercizio nÂ° A016 2/6
	81 di 157

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157

PALESTRA » Apprendisti »	Es.001 Es.002 Es.003 Es.004 Es.005 Es.006 Es.007 Es.008 Es.009 Es.010 Es.011 Es.012 Es.013 Es.014 Es.015 Es.016 Es.017 Es.018 Es.019 Es.020 Es.021 Es.022 Es.023 Es.024 Es.025 Es.026 Es.027 Es.028 Es.029 Es.030 Es.031 Es.032 Es.033
	\| Che serve per iniziare \| Prima compilazione \| Livello Esperti \|

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default